1 BORDER 1: PAPER 0: INK 7: CLS : POKE 23658,8: POKE 23609,80
   3 REM \#020\#001**** ZX WONDERER ****\#020\#000
  10 CLS : PRINT #1;"\* 1984 YT2FSG Goran Stankovic"
  20 LET Nmax=60
  30 DIM d(32,22)
 100 GO SUB 2200
 110 GO SUB 2100
 160 REM 
 170 PRINT AT y-1,x-1;CHR$  147
 175 LET a$=INKEY$
 180 IF a$="P" THEN LET dx=1: LET dy=0
 185 IF a$="O" THEN LET dx=-1: LET dy=0
 190 IF a$="A" THEN LET dy=1: LET dx=0
 200 IF a$="Q" THEN LET dy=-1: LET dx=0
 210 IF a$=CHR$ 13 THEN GO TO 1000
 215 LET ax=x+dx: IF ax<1 THEN LET dx=1: GO TO 170
 220 IF ax>32 THEN LET dx=-1: GO TO 170
 225 LET ay=y+dy: IF ay<1 THEN LET dy=1: GO TO 170
 230 IF ay>22 THEN LET dy=-1: GO TO 170
 235 PRINT AT y-1,x-1;" "
 240 GO TO 300+D(ax,ay)
 300 LET x=ax: LET y=ay: GO TO 170
 310 LET dx=-dx: LET dy=-dy: GO TO 170
 320 LET dx=-dx: LET dy=-dy: GO TO 170
 330 LET d(ax,ay)=20: INK 4: PRINT AT ay-1,ax-1;CHR$ 144: INK 7: GO TO 170
 340 INK 6: FLASH 1: PRINT AT 11,0;"Udarili ste u zvezdu i stradali!": GO TO 1380
 360 GO TO 170
 390 REM 
 400 LET n=n-1: LET d(fx,fy)=0: PRINT AT fy-1,fx-1;" "
 410 IF n>0 THEN GO TO 170
 420 FLASH 1: PRINT AT 11,8;"  B R A V O !  " 
 430 GO TO 1380
 990 REM 
1000 LET fx=x: LET fy=y
1005 LET a$=INKEY$
1010 IF a$="P" THEN LET mx=1: LET my=0: GO TO 1070
1020 IF a$="O" THEN LET mx=-1: LET my=0: GO TO 1070
1030 IF a$="A" THEN LET my=1: LET mx=0: GO TO 1070
1040 IF a$="Q" THEN LET my=-1: LET mx=0: GO TO 1070
1050 IF a$=" " THEN GO TO 170
1060 GO TO 1005
1070 IF d(fx,fy)=60 THEN LET d(fx,fy)=0: PRINT AT fy-1,fx-1;" "
1075 LET fx=fx+mx: IF fx<1 OR fx>32 THEN GO TO 170
1080 LET fy=fy+my: IF fy<1 OR fy>22 THEN GO TO 170
1090 GO TO 1100+D(fx,fy)
1100 LET d(fx,fy)=60: PRINT AT fy-1,fx-1;CHR$ 148: GO TO 1070
1110 GO TO 170
1120 GO TO 400
1130 INK 2: FLASH 1: PRINT AT 11,0;"Pogodili ste zivu metu i stradal": GO TO 1380
1140 INK 2: FLASH 1: PRINT AT 11,0;"Pogodili ste u zvezdu i stradali": GO TO 1380:
1380 FLASH 0: PRINT #1;" ": PRINT #1;"  Pogodili ste = ";Nmax-n;"  "
1385 PRINT #1;"  Jos jednom? (D/N)       "
1390 IF INKEY$="D" THEN GO TO 10
1395 IF INKEY$="N" THEN STOP 
1400 GO TO 1390
1410 STOP 
1990 REM 
2000 DATA 1,1,8,2,4,35,3,2,25,4,6,12
2100 CLS 
2105 PRINT #1;"O <  P >  Q ^  A v  Enter  Space"
2110 BRIGHT 1
2120 RESTORE 2000: FOR j=1 TO 4: READ n,c,k: FOR l=1 TO k
2130 LET x=INT (RND*32)+1: LET y=INT (RND*22)+1: IF d(x,y)<>0 THEN GO TO 2130
2140 LET d(x,y)=n*10: INK c: PRINT AT y-1,x-1;CHR$ (142+n): NEXT l: NEXT j
2150 LET x=INT (RND*32)+1: LET y=INT (RND*22)+1: IF d(x,y)<>0 THEN GO TO 2150
2160 INK 7: FOR i=53 TO 49 STEP -1: PRINT AT y-1,x-1;CHR$ (i): FOR j=1 TO 60: NEXT j: NEXT i
2165 LET dx=0: LET dy=0: LET n=Nmax
2170 RETURN 
2199 REM 
2200 RESTORE 2240: LET a=USR "A"
2225 FOR i=0 TO 39: READ b
2230 POKE a+i,b: NEXT i
2240 DATA 16,56,124,124,254,254,108,0
2250 DATA 0,108,254,254,124,124,56,16
2260 DATA 16,90,60,127,254,60,90,8
2265 DATA 24,24,60,255,255,60,24,24
2270 DATA 0,0,0,24,24,0,0,0
2280 RETURN