1 BORDER 1: PAPER 7: INK 0: CLS : POKE 23658,8: POKE 23609,80 
   3 REM \#020\#001**** ZX TANK DUEL ****\#020\#000
  10 CLS : CLEAR : PRINT #1;"\* 1984 YT2FSG Goran Stankovic"
  15 GO SUB 2000 
  20 CLS 
  50 LET p1=1: LET wl1=0: LET wd1=0
  60 LET sy=175/2000: LET sx=255/3000 
  70 GO SUB 400
  80 GO SUB 500 
 100 IF p1>0 THEN LET wl2=wl1: INPUT "Ugao=";w: LET wl1=w*2*PI /360
 105 IF p1<0 THEN LET wd2=wd1: INPUT "                    Ugao=";w : LET wd1=w*2*PI /360
 110 LET w0=w
 115 LET w=w*2*PI /360
 120 GO SUB 600
 122 IF p1>0 THEN LET y0=(p+7+dyl)/sy
 125 IF p1<0 THEN LET y0=(p+7+dyd)/sy
 130 IF p1>0 THEN LET x0=(le*8+14+dxl)/sx
 132 IF p1<0 THEN LET x0=(de*8+1-dxd)/sx
 135 IF p1>0 THEN INPUT "Brzina=";v0
 137 IF p1<0 THEN INPUT "                    Brzina=";v0
 140 IF p1>0 THEN PRINT AT 21,2; PAPER 1; INK 7;w0;"  ";v0;"  "
 142 IF p1<0 THEN PRINT AT 21,23; PAPER 1; INK 7;w0;"  ";v0;"  " 
 150 LET vx=v0*COS w
 152 LET vy=v0*SIN w
 155 IF p1<0 THEN LET vx=-vx 
 160 LET t=0: LET x1=0: LET y1=365
 170 LET g=-9.81
 180 LET y=g/2*t*t+vy*t+y0 
 195 LET vx=0.1*wi+vx
 200 LET x=vx*t+x0
 210 LET zx=x*sx: LET zy=y*sy
 215 IF zx<0 OR zx>255 OR zy<0 OR zy>175 THEN GO TO 850
 220 IF zx>le*8 AND zx<le*8+16 AND zy<p+8 THEN GO TO 1000 
 225 IF zx>de*8 AND zx<de*8+16 AND zy<p+8 THEN GO TO 1000
 230 IF POINT (zx,zy)=1 THEN GO TO 800
 235 PLOT zx,zy 
 240 PLOT INVERSE 1;x1*sx,y1*sy
 245 LET x1=x: LET y1=y
 250 LET t=t+0.5
 255 GO TO 180
 399 REM 
 400 LET p=16
 440 PRINT AT 20,0; INK 4;"\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::"
 445 PRINT AT 21,0; INK 1;"\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::\::"
 450 LET h=RND *50+25
 455 INK 4: FOR i=93 TO 121
 460 LET hx=SIN (((i-87)*4.5+180)*PI /180)*h: LET hx=ABS hx
 465 PLOT i+16,hx+p: DRAW 0,-hx 
 470 NEXT i
 480 INK 0
 495 RETURN 
 499 REM 
 500 LET le=INT (RND *12) 
 510 LET de=INT (RND *12)+18
 520 PRINT AT 19,le;CHR$ 144;CHR$ 145 
 530 PRINT AT 19,de;CHR$ 144;CHR$ 145
 540 PLOT le*8+13,p+6: DRAW 10,0
 545 PLOT de*8+2,p+6: DRAW -10,0
 550 LET wi=INT (RND *18)-9
 555 PRINT AT 0,0;"Vetar"
 560 PRINT AT 1,1;wi;"  "
 565 IF wi<0 THEN PRINT AT 2,0;"<---"
 570 IF wi>0 THEN PRINT AT 2,0;"--->" 
 580 RETURN 
 599 REM 
 600 IF p1>0 THEN LET dx=10*COS wl2: LET dy=10*SIN wl2: PLOT le*8+13,p+6: DRAW INVERSE 1;dx,dy
 610 IF p1>0 THEN LET dxl=10*COS wl1: LET dyl=10*SIN wl1: PLOT le*8+13,p+6: DRAW dxl,dyl
 620 IF p1<0 THEN LET dx=10*COS wd2: LET dy=10*SIN wd2: PLOT de*8+2,p+6: DRAW INVERSE 1;-dx,dy
 630 IF p1<0 THEN LET dxd=10*COS wd1: LET dyd=10*SIN wd1: PLOT de*8+2,p+6: DRAW -dxd,dyd
 640 RETURN 
 800 LET x2=x*sx/8: LET y2=21-y*sy/8
 810 PRINT AT y2,x2; INK 2;CHR$ 146: BEEP 0.2,-24: FOR i=0 TO 50: NEXT i
 815 PRINT AT y2,x2; INK 3;CHR$ 147: FOR i=0 TO 50: NEXT i
 820 PRINT AT y2,x2;" ": FOR i=0 TO 100: NEXT i
 850 PLOT INVERSE 1;x1*sx,y1*sy: LET p1=-p1
 860 GO TO 100
 900 LET zx=x*sx: LET zy=y*sy
 910 IF zx>le*8 AND zx<le*8+16 AND zy<p+8 THEN GO TO 1000 
 920 IF zx>de*8 AND zx<de*8+16 AND zy<p+8 THEN GO TO 1000
 930 RETURN 
 999 REM 
1000 IF p1<0 THEN PRINT AT 19,le; INK 2;CHR$ 146;CHR$ 146
1005 IF p1>0 THEN PRINT AT 19,de; INK 2;CHR$ 146;CHR$ 146
1010 BEEP 0.2,-24: FOR i=0 TO 50: NEXT i
1015 IF p1<0 THEN PRINT AT 19,le; INK 3;CHR$ 147;CHR$ 147
1020 IF p1>0 THEN PRINT AT 19,de; INK 3;CHR$ 147;CHR$ 147
1025 BEEP 0.2,-18: FOR i=0 TO 50: NEXT i
1030 IF p1<0 THEN PRINT AT 19,le;"  "
1035 IF p1>0 THEN PRINT AT 19,de;"  "
1050 PRINT #1;"  Jos jednom? (D/N)       "
1055 IF INKEY$="D" THEN GO TO 10
1060 IF INKEY$="N" THEN STOP 
1065 GO TO 1055
1070 STOP 
2000 RESTORE 2030 : LET a=USR "A"
2005 FOR i=0 TO 31
2010 READ b: POKE a+i,b
2020 NEXT i
2030 DATA 15, 31, 31, 15, 3, 255, 255, 127
2040 DATA 240, 248, 248, 240, 192, 255, 255, 254 
2050 DATA 34, 148, 89, 46, 116, 154, 41, 68
2060 DATA 137, 32, 2, 128, 1, 64, 4, 145
2100 RETURN