1 BORDER 0: PAPER 0: INK 7: CLS : POKE 23658,8: POKE 23609,80
   3 REM \#020\#001**** ZX POKER ****\#020\#000
  10 CLS : PRINT #1;"\* 1985 YT2FSG Goran Stankovic"
 350 DIM N$(8): DIM C(32): DIM B$(4): DIM N(5): DIM B(5): DIM A(5): DIM D(5): DIM Z(5):: DIM X(5): DIM U(8): DIM K(5)
 360 RANDOMIZE 
 370 LET q=0: LET B$(1)="\a": LET B$(2)="\c": LET B$(3)="\b": LET B$(4)="\d"
 375 LET K(1)=7: LET K(2)=2: LET K(3)=2: LET K(4)=7
 380 LET CR=50: LET CI=50
 390 FOR I=1 TO 8: READ U(I): NEXT I: READ E
 395 GO SUB 3000
 400 CLS : PRINT AT 11,5;"Sacekaj dok promesam"
 405 PRINT #1;"\* 1985 YT2FSG Goran Stankovic"
 406 GO SUB 1450
 410 GO SUB 1120
 430 CLS : LET TI=160: GO SUB 3500: FOR I=1 TO 5
 435 PRINT AT 2,21;"JA :";CR;"$"
 436 PRINT AT 4,21;"TI :";CI;"$"
 440 PRINT AT 3,I*3-1; INK 7;N$(N(I)); INK K(B(I));B$(B(I))
 450 NEXT I
 460 PRINT AT 11,1;"KOJU MENJAS ? (1-5 0)"
 470 LET X$=INKEY$: IF X$<"0" OR X$>"5" THEN GO TO 470
 475 BEEP .1,0
 480 IF X$="0" THEN GO TO 520
 485 LET VAL=VAL X$: PRINT AT 8,VAL*3-1; INK 4;"\::\::"
 490 GO SUB 1070
 500 LET N(VAL)=N: LET B(VAL)=B
 510 GO TO 470
 520 GO SUB 1160: FOR I=1 TO 5: LET A(I)=N(I): LET D(I)=B(I): NEXT I
 525 PRINT AT 11,1;"                      "
 530 FOR I=2 TO 14 STEP 3: PRINT AT 8,I;"  ": NEXT I
 540 FOR I=1 TO 5: PRINT AT 3,I*3-1; INK 7;N$(A(I)); INK K(B(I));B$(D(I))
 550 NEXT I
 560 GO SUB 1120: FOR I=1 TO 5: LET Z(I)=N(I): LET X(I)=B(I): NEXT I
 570 FOR I=1 TO 4: FOR J=I+1 TO 5: IF X(I)<X(J) THEN GO TO 590
 580 LET S=X(I): LET X(I)=X(J): LET X(J)=S: LET S=Z(I): LET Z(I)=Z(J): LET Z(J)=S
 590 NEXT J: NEXT I
 600 IF X(1)=X(2) AND X(1)=X(3) AND X(1)=X(4) THEN GO TO 630
 610 IF X(2)=X(3) AND X(2)=X(4) AND X(1)=X(5) THEN GO TO 650
 620 GO TO 660
 630 IF X(1)=X(5) THEN GO TO 710
 640 GO SUB 1070: LET X(5)=B: LET Z(5)=N: GO TO 710
 650 GO SUB 1070: LET X(1)=B: LET Z(1)=N: GO TO 710
 660 FOR I=1 TO 5: LET Z(I)=N(I): LET X(I)=B(I): NEXT I: GO SUB 1200
 670 IF T=7 OR T=3 THEN GO TO 710
 675 LET I=0
 680 LET I=I+1: IF I=6 THEN GO TO 710
 690 IF Z(I)<0 THEN GO TO 680
 700 GO SUB 1070: LET Z(I)=N: LET X(I)=B: GO TO 680
 710 FOR I=1 TO 5: IF Z(I)<0 THEN LET Z(I)=N(I)
 720 NEXT I
 730 FOR I=1 TO 5: LET N(I)=Z(I): LET B(I)=X(I): NEXT I: GO SUB 1160: FOR I=1 TO 5: LET Z(I)=N(I): LET X(I)=B(I): NEXT I
 740 GO SUB 1320
 745 LET CD=CC: LET TR=T: LET U=U(T+1): LET U=INT (U+LN (RND/E)+3)
 750 LET U1=3: PRINT AT 7,21;"Koliko";AT 8,21;"ulazes ?";AT 9,21;"(0-3 N)": LET U2=3
 760 LET X$=INKEY$: IF X$="N" THEN GO TO 950
 765 IF X$<"0" OR X$>"3" THEN GO TO 760
 767 BEEP .2,30: PRINT AT 8,30;x$+"$"
 770 LET U1=U1+VAL X$
 780 IF U1>U THEN GO TO 870
 790 IF U1=U THEN GO TO 970
 800 LET U2=U2+1: IF U1>6 THEN LET U2=U1: GO TO 1050
 810 PRINT AT 11,21;"Prihvatam";AT 12,21;"i podizem";AT 13,21;"za 1$"
 820 PRINT AT 15,21;"Za koliko";AT 16,21;"podizes";AT 17,21;"ulog ?";AT 18,21;"(1-4 N)"
 830 LET X$=INKEY$: IF (X$<"1" OR X$>"4") AND X$<>"N" THEN GO TO 830
 835 BEEP .25,0
 840 IF X$="N" THEN GO TO 950
 850 IF X$="1" THEN LET U1=U2: GO TO 970
 860 GO TO 770
 870 PRINT AT 17,2;"NE PRIHVATAM"
 880 LET CR=CR-U2: LET CI=CI+U2
 890 PRINT AT 2,21;"JA :";CR;"$"
 900 PRINT AT 4,21;"TI :";CI;"$"
 910 IF CR<0 THEN PRINT AT 18,2; FLASH 1;"Ostao sam svorc": STOP 
 915 IF CI<0 THEN PRINT AT 7,2; FLASH 1;"Ostao si svorc": STOP 
 920 PRINT #0;"JOS JEDNU PARTIJU ? (D/K/N)"
 930 LET X$=INKEY$: IF X$="D" THEN GO TO 400
 935 IF X$="K" THEN LET Q=12.45: GO SUB 970
 940 IF X$="N" THEN PRINT AT 8,2; FLASH 1;"KUKAVICE ! ! !": STOP 
 945 GO TO 930
 950 PRINT AT 18,2;"JA SAM POBEDIO"
 960 LET CR=CR+U1: LET CI=CI-U1: GO TO 890
 970 LET TI=65: GO SUB 3500: PRINT AT 12,2;"Moje karte:"
 980 FOR I=1 TO 5: PRINT AT 15,I*3-1; INK 7;N$(Z(I)); INK K(B(I));B$(X(I)): NEXT I
 985 IF Q=12.45 THEN LET Q=0: RETURN 
 990 FOR I=1 TO 5: LET Z(I)=A(I): LET X(I)=D(I): NEXT I
1000 GO SUB 1320
1010 IF T>TR THEN PRINT AT 8,2;"TI SI POBEDIO": GO TO 880
1020 IF T<TR THEN GO TO 950
1030 IF CD>CC THEN GO TO 950
1035 IF CD<CC THEN PRINT AT 8,2;"TI SI POBEDIO": GO TO 880
1040 PRINT AT 11,2; FLASH 1;"NERESENO": GO TO 890
1050 PRINT "ULOG JE PRESAO 6$"
1060 GO TO 970
1070 LET N=INT (10*(C(I9)/10-INT (C(I9)/10))+.5)
1080 LET B=INT (C(I9)/10)
1090 LET I9=I9+1
1100 IF I9=33 THEN PRINT "KARTE NISU POMESANE"'"GUBITE IGRU": STOP 
1110 RETURN 
1120 FOR i=1 TO 5
1130 GO SUB 1070
1140 LET N(I)=N: LET B(I)=B
1150 NEXT I
1160 FOR I=1 TO 4: FOR J=I+1 TO 5: IF N(I)<N(J) THEN GO TO 1180
1170 LET S=N(I): LET N(I)=N(J): LET N(J)=S: LET S=B(I): LET B(I)=B(J): LET B(J)=S
1180 NEXT J
1185 NEXT i
1190 RETURN 
1200 IF X(1)=X(2) AND X(2)=X(3) AND X(3)=X(4) AND X(4)=X(5) THEN LET T=7: GO TO 1290
1205 LET T=0
1210 IF Z(2)=Z(1)+1 AND Z(3)=Z(2)+1 AND Z(4)=Z(3)+1 AND Z(5)=Z(4)+1 THEN LET T=2.5: GO TO 1290
1220 FOR Y=1 TO 4
1230 LET I=1
1240 FOR J=Y+1 TO 5
1250 IF Z(Y)<>Z(J) THEN GO TO 1280
1260 LET T=T+I
1270 LET Z(J)=-RND: LET Z(Y)=-RND: LET I=I+1
1280 NEXT J: NEXT Y
1290 LET T1=T: IF T=2.5 THEN LET T1=3
1300 IF T=4 THEN LET T1=5
1310 LET T=T1: RETURN 
1320 IF X(1)=X(2) AND X(2)=X(3) AND X(3)=X(4) AND X(4)=X(5) THEN LET T=7: RETURN 
1330 IF Z(2)=Z(1)+1 AND Z(3)=Z(2)+1 AND Z(4)=Z(3)+1 AND Z(5)=Z(4)+1 THEN LET T=3: LET CC=Z(5): RETURN 
1340 FOR I=1 TO 3: IF Z(I)=Z(I+1) THEN NEXT I: LET T=6: LET CC=Z(2): RETURN 
1345 LET I=4: NEXT I
1350 FOR I=2 TO 4: IF Z(I)=Z(I+1) THEN NEXT I: LET T=6: LET CC=Z(2): RETURN 
1355 LET I=5: NEXT I
1360 FOR I=1 TO 2: IF Z(I)=Z(I+1) THEN NEXT I: LET T=4: LET CC=Z(3): GO TO 2000
1365 LET I=3: NEXT I
1370 FOR I=2 TO 3: IF Z(I)=Z(I+1) THEN NEXT I: LET T=4: LET CC=Z(3): GO TO 2010
1375 LET I=4: NEXT I
1380 FOR I=3 TO 4: IF Z(I)=Z(I+1) THEN NEXT I: LET T=4: LET CC=Z(3): GO TO 2020
1385 LET I=5: NEXT I
1390 IF Z(4)=Z(5) THEN LET CC=Z(5): GO TO 2030
1400 IF Z(3)=Z(4) THEN LET CC=Z(3): GO TO 2040
1410 IF Z(2)=Z(3) THEN GO TO 1430
1420 IF Z(1)<>Z(2) THEN LET T=0: RETURN 
1430 LET T=1: LET CC=Z(2): RETURN 
1440 DATA 1,2,4,6,9,10,10,10,.55
1450 FOR I=1 TO 4: FOR J=1 TO 8: LET C(8*(I-1)+J)=10*I+J: NEXT J: NEXT I
1460 FOR I=1 TO 32
1470 LET P=1+INT (RND*(33-I))
1480 LET M=C(P)
1490 LET C(P)=C(33-I)
1500 LET C(33-I)=M
1510 NEXT I
1520 LET I9=1
1530 RETURN 
2000 IF Z(4)=Z(5) THEN LET T=5
2005 RETURN 
2010 IF Z(1)=Z(5) THEN LET T=5
2015 RETURN 
2020 IF Z(1)=Z(2) THEN LET T=5
2025 RETURN 
2030 IF Z(1)=Z(2) OR Z(2)=Z(3) THEN LET T=2: RETURN 
2035 LET T=1: RETURN 
2040 IF Z(1)=Z(2) THEN LET T=2: RETURN 
2045 LET T=1: RETURN 
3000 FOR I=USR "a" TO USR "a"+39: READ a: POKE i,a: NEXT I
3010 DATA 0,16,56,124,254,254,214,16
3020 DATA 0,16,56,124,254,124,56,16
3030 DATA 0,108,254,254,124,124,56,16
3040 DATA 0,56,56,16,214,254,214,16
3050 DATA 152,164,164,164,164,164,164,152
3100 FOR I=1 TO 8: READ A$: LET N$(I)=A$: NEXT I
3110 DATA "7","8","9","\e","A","B","D","K"
3120 RETURN 
3500 PLOT 11,TI: DRAW 145,0: DRAW 0,-65: DRAW -145,0: DRAW 0,65
3510 FOR I=35 TO 107 STEP 24: PLOT I,TI: DRAW 0,-65: NEXT I
3520 RETURN 
9999 CLEAR : SAVE "POKER" LINE 1