1 BORDER 0: PAPER 0: INK 7: CLS : POKE 23658,8: POKE 23609,80
   3 REM \#020\#001**** ZX BIORITAM ****\#020\#000
   4 REM \* 1984 YT2FSG Goran Stankovic
  20 LET A1=USR "A"
  25 FOR I=0 TO 23: READ A2
  30 POKE A1+I,A2: NEXT I
  40 DATA 24,60,126,255,255,126,24,24
  50 DATA 102,231,255,255,126,126,60,24
  70 DATA 60,126,255,231,231,255,126,60
  80 BRIGHT 1: INK 5: FLASH 1
  81 PRINT AT 6,0;"\ .\..\..\  \  \..\..\. \  \..\..\  \ .\..\..\  \  \..\..\. \..\..\..\. \  \..\..\  \ .\  \  \. "
  82 PRINT AT 7,0;"\ :\..\..\' \  \  \: \  \ :\  \  \: \ :\  \  \: \  \  \: \  \  \ :\  \  \ :\  \  \: \ :\'.\.'\: "
  84 PRINT AT 8,0;"\ :\  \  \: \  \  \: \  \ :\  \  \: \ :\''\':\  \  \  \: \  \  \ :\  \  \ :\''\''\: \ :\  \  \: "
  86 PRINT AT 9,0;"\ '\''\''\  \  \''\''\' \  \''\''\  \ '\  \  \' \  \''\''\' \  \ '\  \  \ '\  \  \' \ '\  \  \' "
  88 INK 7: FLASH 0: PRINT AT 11,2;"\* 1984 YT2FSG Goran Stankovic"
 100 INK 6: INPUT "IME :";A$: PRINT AT 0,0; INVERSE 1;A$
 110 INPUT "Datum rodjenja"'"Dan :";D'"Mesec :";M'"Godina :";G
 120 PRINT AT 0,21;D;".";M;".";G;"."
 125 LET DD=D: LET MM=M: LET GG=G
 130 GO SUB 600: LET B=X
 140 INPUT "Bioritam za"'"mesec :";M'"Godinu :";G: LET D=0
 150 GO SUB 600: LET A=X
 160 LET C=A-B
 170 GO SUB 700
 180 GO SUB 800
 190 LET E1=C-INT (C/23)*23
 200 LET E2=C-INT (C/28)*28
 210 LET E3=C-INT (C/33)*33
 215 PRINT AT 6,0;"                                "
 216 PRINT AT 7,0;"                                "
 217 PRINT AT 8,0;"                                "
 218 PRINT AT 9,0;"                                "
 219 PRINT AT 11,0;"                                "
 220 BEEP .4,-20: LET Z1=(Z-1)*8
 222 PRINT AT 10,0;"0": PRINT AT 5,0;"+": PRINT AT 15,0;"-"
 230 PLOT 12,24: DRAW Z1,0
 240 PLOT 12,92: DRAW Z1,0
 250 PLOT 12,161: DRAW Z1,0
 260 PLOT 12,24: DRAW 0,136
 270 PLOT Z1+12,24: DRAW 0,136
 280 FOR I=0 TO INT ((Z-3)/2)
 290 PLOT I*16+28,24: DRAW 0,136
 300 PLOT I*16+20,88: DRAW 0,8
 310 PLOT I*16+20,24: DRAW 0,4
 320 PLOT I*16+20,157: DRAW 0,4
 325 NEXT I
 330 PRINT AT 19,11;"1 1 1 1 1 2 2 2 2"
 340 PRINT AT 20,1;"1 3 5 7 9 1 3 5 7 9 1 3 5 7" 
 350 IF Z=29 OR Z=30 THEN PRINT AT 19,29;"2": PRINT AT 20,29;"9"
 352 IF Z=31 THEN PRINT AT 19,29;"2 3": PRINT AT 20,29;"9 1"
 360 PRINT AT 19,1; INVERSE 1; FLASH 1;M;".";G;".": FLASH 0
 370 PRINT AT 21,0;"Fizicki="; INK 4;"\a"; INK 7;" Emotivni="; INK 2;"\b"; INK 7;" Intelekt="; INK 5;"\c"; INK 7 
 400 FOR N=1 TO Z
 410 LET F=SIN ((N+E1)/23*2*PI)
 420 LET N1=10+INT (8*ABS F)*SGN (-F)
 430 LET F=SIN ((N+E2)/28*2*PI)
 440 LET N2=10+INT (8*ABS F)*SGN (-F)
 450 LET F=SIN ((N+E3)/33*2*PI)
 460 LET N3=10+INT (8*ABS F)*SGN (-F)
 470 PRINT AT N1,N; INK 4;"\a"
 480 PRINT AT N2,N; INK 2;"\b"
 490 PRINT AT N3,N; INK 5;"\c"
 500 NEXT N
 510 BEEP .75,7: BEEP .25,8: BEEP .5,7: BEEP .5,5: BEEP .5,3: BEEP .5,2: BEEP 1,0
 520 PRINT #1;"'P'-Ponovo 'Z'-COPY 'S'- STOP ": PAUSE 0
 530 IF INKEY$="P" THEN GO TO 1000
 540 IF INKEY$="Z" THEN COPY : GO TO 530
 545 IF INKEY$="S" THEN GO TO 900
 546 IF INKEY$=" " THEN GO TO 900
 550 GO TO 530
 600 IF M>=3 THEN LET Q=G: LET R=M+1: GO TO 620
 610 LET Q=G-1: LET R=13+M
 620 LET X=INT (365.25*Q)+INT (30.6*R)+D-122
 630 LET X=X-INT (Q/100)+INT (Q/400)
 640 RETURN 
 700 IF G<>4*INT (G/4) THEN LET Y=0: RETURN 
 710 IF G<>100*INT (G/100) THEN LET Y=1: RETURN 
 720 IF G<>400*INT (G/400) THEN LET Y=0: RETURN 
 730 LET Y=1: RETURN 
 800 IF (M=4)+(M=6)+(M=9)+(M=11)=1 THEN LET Z=30: RETURN 
 810 IF M=2 THEN LET Z=28+Y: RETURN 
 820 LET Z=31: RETURN 
 900 BRIGHT 0: BORDER 7: PAPER 7: INK 0: CLS : PRINT #0;"\* 1984 YT2FSG Goran Stankovic": FOR i=1 TO 1000: PAUSE 0: BORDER 0: PAPER 0: INK 7: CLS : LIST : STOP 
1000 BEEP .2,30: BEEP .3,20: CLS : PRINT AT 20,0;"Zelis li da promenis datum "'"rodjenja ? (D/N)"
1010 IF INKEY$="D" THEN CLS : GO TO 80
1020 IF INKEY$="N" THEN CLS : PRINT INVERSE 1;AT 0,0;A$: PRINT AT 0,22;DD;".";MM;".";GG;".": GO TO 140
1030 GO TO 1010
9996 
9997 REM \#020\#001*** SAVE ***\#020\#000
9998 
9999 SAVE "BIORITAM" LINE 1