1 WAIT 0:PRINT "Def: A S D F G J K N M X":END 
5 X=C*T+D
6 Y=SIN X/X
7 RETURN 
10 B=30859:FOR I=0TO M:FOR J=0TO W
20 CURSOR :PRINT A$;STR$ (I+1);",";STR$ (J+1);")=":CURSOR PEEK B,PEEK (B+1)
25 IF Q=1INPUT C(I,J):GOTO 30
26 INPUT B(I,J)
30 NEXT J:NEXT I:RETURN 
50 INPUT "Dimenzija N=";N:M=N-1:RETURN 
60 CLS :CLEAR :WAIT 0:A$="a(":RETURN 
70 "S"GOSUB 60:PRINT "Sistem lin. jednacina"
75 GOSUB 50:DIM B(M,N):PRINT "Koficijenti":W=M:GOSUB 10
80 CURSOR :PRINT "Slobodni clanovi":FOR I=0TO M
90 CURSOR :PRINT "b";STR$ (I+1);"=":CURSOR PEEK B,PEEK (B+1):INPUT B(I,N):NEXT I
92 E=N:GOSUB 100
95 WAIT :CURSOR :FOR I=0TO M:PRINT "x";STR$ (I+1);"=";B(I,N)/B(I,I):NEXT I:END 
100 FOR K=0TO M:Q=K+1:IF K=MGOTO 170
110 A=ABS B(K,K):L=K
120 FOR I=QTO M:IF A>=ABS B(I,K)GOTO 140
130 A=ABS B(I,K):L=I
140 NEXT I
150 IF L=KGOTO 170
160 FOR J=0TO E:P=B(K,J):B(K,J)=B(L,J):B(L,J)=P:NEXT J
170 IF B(K,K)=0CURSOR :PRINT "Nema resenja":END 
180 FOR I=0TO M:IF I=KGOTO 195
190 FOR J=QTO E:B(I,J)=B(I,J)-B(I,K)/B(K,K)*B(K,J):NEXT J
195 NEXT I:NEXT K:RETURN 
200 "M"GOSUB 60:INPUT "1.mat.(M*L) M=";M:CURSOR 12:INPUT "L=";L
210 M=M-1:L=L-1:DIM B(M,L):W=L:GOSUB 10
220 CURSOR :INPUT "2.mat.(L*N) N=";N:N=N-1:DIM C(L,N):E=M:M=L:W=N:Q=1:A$="b(":GOSUB 10
230 M=E:WAIT :FOR K=0TO M:FOR J=0TO N:D=0:FOR I=0TO L:D=D+B(K,I)*C(I,J):NEXT I
240 CURSOR :PRINT "c(";STR$ (K+1);",";STR$ (J+1);")=";D:NEXT J:NEXT K:END 
300 "A"GOSUB 60:PRINT "Inverzija matrice"
310 GOSUB 50:E=2*M+1:DIM B(M,E):W=M:GOSUB 10
330 FOR I=0TO M:FOR J=NTO E:IF J=N+IGOTO 350
340 B(I,J)=0:GOTO 355
350 B(I,J)=1
355 NEXT J:NEXT I
360 GOSUB 100
370 WAIT :FOR I=0TO M:FOR J=1TO N
380 CURSOR :PRINT "b(";STR$ (I+1);",";STR$ J;")=";B(I,M+J)/B(I,I)
390 NEXT J:NEXT I:END 
500 "D"GOSUB 60:PRINT "Determinanta"
510 GOSUB 50:DIM B(N,N),C(N):W=M:GOSUB 10
520 R=1:FOR I=0TO M:IF B(I,I)=0GOTO 580
530 C(I)=B(I,I):FOR J=1TO M:B(I,J)=B(I,J)/C(I):NEXT J
540 E=I+1:FOR K=ETO M:C=B(K,I)
550 FOR J=1TO M:B(K,J)=B(K,J)-B(I,J)*C:NEXT J:NEXT K:NEXT I
560 D=R:FOR I=0TO M:D=D*C(I):NEXT I
570 CURSOR :PRINT "Det=";D:END 
580 E=I+1:FOR L=ETO M:IF B(L,I)=0GOTO 600
590 FOR J=0TO M:T=B(I,J):B(I,J)=B(L,J):B(L,J)=T:NEXT J:R=-R:GOTO 530
600 NEXT L:D=0:GOTO 570
610 "N":RANDOM :WAIT 0:PRINT "Numericka integracija"
620 INPUT "Donja granica  A=";A,"Gornja granica  B=";B
630 C=(B-A)/2:D=(B+A)/2
640 T=.1834346425:GOSUB 5:Q=Y:T=-T:GOSUB 5:I=(Q+Y)*.3626837834
650 T=.5255324099:GOSUB 5:Q=Y:T=-T:GOSUB 5:I=(Q+Y)*.3137066459+I
660 T=.7966664774:GOSUB 5:Q=Y:T=-T:GOSUB 5:I=(Q+Y)*.2223810345+I
670 T=.9602898565:GOSUB 5:Q=Y:T=-T:GOSUB 5:I=(Q+Y)*.1012285363+I
680 PRINT "I=";I*C:END 
700 "K"WAIT 0:PRINT "ax^2+bx+c=0":INPUT "a=";A,"b=";B,"c=";C
705 D=B*B-4*A*C:P=-B/2/A:Q=SQR(ABS D)/2/A
710 IF D=0PRINT "x=";P:END 
720 IF D>0PRINT "x1=";P+Q:PRINT "x2=";P-Q:END 
730 PRINT "Re(x)=";P:PRINT "Im(x)=";Q:END 
740 "F"WAIT 0:PRINT "Nule funkcije":INPUT "1. tacka=";A,"2. tacka=";B
745 FOR I=1TO 20
750 X=A:GOSUB 6:C=Y:X=B:GOSUB 6:K=D:D=B-(B-A)*Y/(Y-C):A=B:B=D
760 IF ABS (K-D)<1E-8PRINT "x=";D:END 
770 NEXT I:PRINT "nemogu da nadjem":END 
800 "G"RADIAN :CLS :WAIT 0:PRINT "GRAFIK y=f(x)
820 INPUT "xmin=";A,"xmax=";B
825 IF B<AGOTO 820
830 INPUT "ymin=";C,"ymax=";D
835 IF D<CGOTO 830
840 G=B-A:H=D-C:N=150/G:M=32/H:P=-A*N:Q=32+C*M
850 CLS :LINE (0,Q)-(149,Q):LINE (P,0)-(P,31)
860 K=G/150*2
870 X=A:GOSUB 6:E=X+K:R=X:T=Y
880 FOR X=ETO BSTEP K:GOSUB 6
890 Z=X*N+P:W=-Y*M+Q
900 O=R*N+P:S=-T*M+Q
910 R=X:T=Y:LINE (O,S)-(Z,W):NEXT X
920 WAIT :GPRINT 
2000 "J":CLS :WAIT 0:DEGREE :PRINT "ax^3+bx^2+cx+d=0"
2010 INPUT "a=";A,"b=";B,"c=";C,"d=";D
2020 E=B/A/3:Q=E*E*E-E*C/A/2+D/A/2:P=C/A/3-E*E:K=Q*Q+P*P*P
2030 IF K>0LET U=(-Q+SQRK)^(1/3):V=(-Q-SQRK)^(1/3):GOTO 2060
2040 R=SGN Q*SQRABS P:F=Q/R/R/R:F=(ACS F)/3:X1=-2*R*COS F-E:X2=2*R*COS (60-F)-E:X3=2*R*COS (60+F)-E
2050 PRINT "x1=";X1:PRINT "x2=";X2:PRINT "x3=";X3:END 
2060 X1=U+V-E:X2=-(U+V)/2-E:X3=SQR3*(U-V)/2
2070 PRINT "x1=";X1:PRINT "x2,3=";X2:PRINT " +-i ";X3:END 
2100 "X"CLEAR :CLS :WAIT 0:PRINT "Sistem NElinearnih jed.
2105 GOSUB 3000:N1=N+1:N2=N+2:N3=2*N:DIM F(N),X(N),U(N1,N2),V(N1,N3)
2110 PRINT "Ulazni podaci":FOR I=1TO N:PRINT "x(";I;")=":INPUT X(I):NEXT I
2115 INPUT "Vel.zone pret.:";Z
2120 GOSUB 3010:FOR K=1TO N:V(1,K)=X(K):V(1,K+N)=F(K):NEXT K
2125 FOR J=1TO N:J1=J+1:FOR K=1TO N:X(K)=V(1,K)+Z*(.5-RND 0):V(J1,K)=X(K):NEXT K
2130 GOSUB 3010:FOR K=1TO N:K1=K+N:V(J1,K1)=F(K):NEXT K:NEXT J
2135 ID=1
2140 IT=IT+1:FOR K=1TO N2:U(1,K)=1:NEXT K:FOR K=2TO N1:U(K,N2)=0:NEXT K
2145 FOR J=1TO N:J1=J+1:JN=J+N:FOR K=1TO N1:U(J1,K)=V(K,JN):NEXT K:NEXT J
2150 FOR I=1TO N:I1=I+1:K1=N1+I1:FOR Q=I1TO N1:K=K1-Q
2155 IF ABS U(K,I)<=ABS U(K-1,I)GOTO 2170
2160 FOR J=ITO N2:B=U(K,J):U(K,J)=U(K-1,J):U(K-1,J)=B:NEXT J
2170 NEXT Q
2175 FOR K=ITO N:KK=K+1:FOR J=ITO N1:J1=J+1:U(KK,J1)=U(KK,J1)-U(I,J1)*U(KK,I)/U(I,I)
2180 NEXT J:NEXT K:NEXT I
2185 U(N1,N2)=U(N1,N2)/U(N1,N1):L=N1:M=N1:FOR Q=1TO N:K=N1-Q:B=0:K1=K+1
2190 FOR J=K1TO N1:B=B+U(K,J)*U(J,N2):NEXT J:U(K,N2)=(U(K,N2)-B)/U(K,K)
2195 IF U(K,N2)<U(L,N2)LET L=K
2196 IF U(K,N2)<U(M,N2)LET M=K
2200 NEXT Q:FOR K=1TO N:X(K)=0:FOR J=1TO N1:X(K)=X(K)+U(J,N2)*V(J,K):NEXT J:NEXT K
2210 GOSUB 3010:P=0:FOR K=1TO N:IF ABS (F(K))<EPLET P=P+1
2215 NEXT K:IF P<NGOTO 2230
2220 PRINT "RESENJE":WAIT :FOR I=1TO N:PRINT "x";I;"=";X(I):NEXT I
2225 FOR I=1TO N:PRINT "f";I;"=";F(I):NEXT I:END 
2230 IF L=IDGOTO 2240
2235 L=1+INT (N1*RND 0)
2240 ID=L:FOR K=1TO N:KN=K+N:V(ID,K)=X(K):V(ID,KN)=F(K):NEXT K:GOTO 2140
3000 N=2:EP=1E-6:RETURN 
3010 F(1)=4*X(1)*X(1)+X(2)*X(2)+2*X(1)*X(2)-X(2)-2
3020 F(2)=2*X(1)*X(1)+X(2)*X(2)+3*X(1)*X(2)-3
3050 RETURN