********** W element tline definition**********
*
* The following defines a two conductor w
* element transmission line model for a dual
* stripline board structure with 0.5 oz trace
* thickness, 4 mil wide trace and 60 ohm target
* characteristic impedance. The six mil separation
* between the traces produces a diff impedance of 
* 99.2 ohms.  This was calculated using the Polar
* Instruments CITS25 Field Solver. This will model one
* coupled differential signal pair.

* Define the board material
.MATERIAL diel_fr4 DIELECTRIC ER=4.1
+LOSSTANGENT=0.020
.MATERIAL copper METAL CONDUCTIVITY=5.8e+07

* Define the cross section of the trace, rectangle
* 1/2 oz copper, 4 mil wide
.SHAPE rect RECTANGLE WIDTH=4mil, HEIGHT=0.7mil

* Define the dual stripline structure, two striplines
* between two 2 oz pwr/gnd planes. Each trace is 5 mils
* from the plane and five mils from the other trace.

.LAYERSTACK dual_sl_60,
+ LAYER= (copper,2.8mil), LAYER=(diel_fr4,16.4mil),
+ LAYER= (copper,2.8mil)

.FSOPTIONS opt1 PRINTDATA=YES
+ ComputeRo=yes ComputeRs=yes ComputeGo=Yes ComputeGd=yes
+ ACCURACY = HIGH

.MODEL cond2_diff W MODELTYPE=Fieldsolver,
+LAYERSTACK=dual_sl_60, FSOPTIONS=opt1,
+RLGCFILE=cond2diff.rlgc,
+CONDUCTOR= (MATERIAL=copper, SHAPE=rect, ORIGIN= (0, 7.8mil)),
+CONDUCTOR= (MATERIAL=copper, SHAPE=rect, ORIGIN= (10mil, 7.8mil))

******  End of the W element definition
******************************************************

* Example
* define a 4 inch instance of the w element stripline
* illustrated above.

*W1 lvdsout1a lvdsout1b 0 OUTA OUTB 0 FSmodel=cond2_diff
*+N=2 l=4000mil