Phased Vertical Antennas

Milazzo, Carol F., KP4MD, "Phased Vertical Antenna Patterns", QZX, Vol 2:3, February 1984, p. 2. A Sinclair BASIC program to print radiation pattern plots for phased vertical antenna arrays.

Timex/Sinclair ZX81 BASIC Program Listing

10 PRINT "NO. OF ELEMENTS",
20 INPUT N
30 PRINT N
40 DIM A(N-1,4)
50 PRINT ,,"ELE. PHASE REL I ANG DIST0 0 1 0 0"
55 LET S=1
60 FOR I=1 TO N-1
70 PRINT I;
80 FOR J=1 TO 4
90 INPUT A
100 PRINT TAB J*7;A;
110 LET A(I,J)=A*PI/180
120 IF J<>2 THEN GOTO 135
125 LET S=S+A
130 LET A(I,J)=A
135 NEXT J
140 PRINT
150 NEXT I
160 LET S=21/S
170 CLS
180 FAST
190 LET VMAX=0
200 FOR I=0 TO 2*PI STEP PI/36
210 LET V=1
230 FOR J=1 TO N-1
240 LET V=V+A(J,2)*COS (A(J,1)+A(J,4)*COS (I-A(J,3)))
270 NEXT J
280 LET V=ABS V
290 IF V>VMAX THEN LET VMAX=V
300 PLOT S*V*SIN I+31,S*V*COS I+21
310 NEXT I
320 PRINT AT 0,0;"MAX. GAIN"
330 PRINT VMAX
340 STOP
900 SAVE "ARRAY"
950 RUN

IBM PC Basic Program Listing array.bas

0 REM Program for Phased Vertical Antenna Arrays by Carol F. Milazzo, KP4MD
10 I$(1)="Phase":I$(2)="Relative Current":I$(3)="Angle":I$(4)="Distance"
20 CLS:INPUT"No. of elements";N:DIM A(N,4):PI=3.1415926#:PRINT
30 PRINT"Element 1":PRINT"Phase: 0":PRINT"Relative Current: 1":PRINT"Angle: 0":PRINT"Distance: 0":PRINT
40 S=1:FOR I=2 TO N:PRINT "Element";I:FOR J=1 TO 4:PRINT I$(J);:INPUT A
50 A(I,J)=A*3.141593/180:IF J=2 THEN S=S+A:A(I,J)=A
60 NEXT J:PRINT:NEXT I
70 CLS:SCREEN 2:S=99/S:VMAX=0:FOR I=0 TO 2*PI STEP PI/36
80 V=1:FOR J=2 TO N:V=V+A(J,2)*COS(A(J,1)+A(J,4)*COS(I-A(J,3))):NEXT J
90 V=ABS(V):IF V>VMAX THEN VMAX=V
100 X=S*V*SIN(I)+320:Y=99-S*V*COS(I):IF I>0 THEN LINE (X,Y)-(X1,Y1)
110 X1=X:Y1=Y:NEXT I:LOCATE 1,1:PRINT"Max. Gain ";VMAX