BBC Microcomputer

User Guide

Addendum Slip

PLEASE READ THIS BEFORE USING THE WELCOME CASSETTE

If your machine includes Disc, Econet or Teletext Interface, your attention is drawn to page 400, describing how to change between filing systems.

It will be necessary, before loading the Welcome cassette programs (page 12) to change to the Tape Filing System (contained within the Machine Operating System Rom.).

This is done by typing:

*TAPE RETURN

before the RETURN

CHAIN "WELCOME". RETURN

command, and directly after use of BREAK or CTRL BREAK.

In some cases, very long cassette programs may not run because of the small amount of extra memory used by the Disc and Net filing systems. To overcome this, follow the

*TAPE RETURN command by:

PAGE=&E00 RETURN [see entry under keywords

for explanation of PAGE]

If at any time you wish to return to the Disc or Net filing systems, press BREAK or CTRL BREAK, then type:

*DISK RETURN

or

*NET RETURN

The BBC Microcomputer

USER

GUIDE

Written by John Coll

Edited by David Allen

British Broadcasting Corporation

The author and editor would like to thank Paul Bond, Chris Charlesworth, Computer Concepts, Fiona Hibberd, Charles Moir, Jim Murray, Richard Russell, Fenella Sturt, Robin Viet and Roger Wilson for their invaluable help in the preparation and checking of the manuscript and Norman Brownsword the designer.

This book is part of the BBC Computer Literacy Project

prepared in consultation with the

BBC Continuing Education Advisory Council.

The Editor of the project is David Allen.

© The Author and The British Broadcasting Corporation 1982

First published 1982

Published by the British Broadcasting Corporation

35 Marylebone High Street, London W1M 4AA

ISBN 0 563 16558

Contents

Introduction 5

1 Getting going 7

Giving the computer instructions – Part I

2 Commands 21

3 An introduction to variables 24

4 Writing a simple program 27

5 Recording programs on cassette 34

6 Some sample programs 38

Giving the computer instructions – Part II

7 AUTO, DELETE, REM and RENUMBER 53

8 Introducing Graphics 55

9 More on variables – string, real & integer ASCII codes, CHR$ and ASC 62

10 PRINT and formatting. Cursor control 67

11 INPUT 78

12 GET and INKEY 81

13 TIME and Random numbers 84

Structure in BASIC language

14 REPEAT... UNTIL, TRUE and FALSE 87

15 FOR... NEXT 91

16 IF... THEN... ELSE 98

17 PROCEDURES 102

18 FUNCTIONS

19 GOSUB 113

20 GOTO, ON GOTO and ON GOSUB 118

Giving the computer instructions – Part III

21 Yet more on variables – Arrays 120

22 READ, DATA and RESTORE 126

23 Integer handling 130

24 String handling 135

25 Programming the User Defined function keys 141

26 Operator precedence 144

27 Error handling 147

28 Use of teletext mode (MODE 7) 150

29 Advanced Graphics: (logical, inverse, actual colours), PLOT, GCOL, animated graphics, user definable characters 160

30 Sound 180

31 File handling 188

32 Speeding up programs and saving memory space 194

Reference section

33 BASIC keywords alphabetical summary 197

34 VDU drivers 377

35 Cassette files 390

36 Changing filing systems 400

37 Merging BASIC Programs 402

38 Using printers 404

39 Indirection operators 409

40 HIMEM, LOMEM, TOP and PAGE 414

41 Operating system, statements (*commands) 416

42 *FX calls and OSBYTE calls 418

43 Assembly Language 442

44 Analogue input and user input-output ports 467

45 Expanding the system 471

46 Error messages 474

47 Minimum abbreviations 483

48 Appendix 485

ASCII Teletext codes and shapes 486

ASCII codes and shapes (MODES 0 to 6) 488

ASCII (MODES 0 to 6) displayed character set 490

ASCII hexadecimal codes 492

Text planning sheet 493

Graphics planning sheets 494

Keyboard codes 497

Board layout 498

External connections 499

Memory maps 500

Memory map assignments 502

Circuits layouts 503

VDU code summary 507

6502 Instruction Set 508

FX call summary 510

Operating System call summary 512

INDEX 513

Introduction

Before you start using your computer check that you have received the following items in addition to this User Guide

BBC Microcomputer

Guarantee registration card

An aerial lead about 2 metres long which connects the computer to your television

The Welcome package – containing a cassette and an introductory booklet.

If you are short of any of these items then write immediately to your supplier quoting the number given to you when you placed your order. The number also appears on the despatch label.

You will also require a lead to connect your computer to an ordinary cassette tape recorder. If you ordered the appropriate lead when you placed your order, check that it has arrived. If you didn’t, take your cassette recorder, the computer and this book to a dealer and ask if he can supply a lead or make

one up for you. In many cases a standard audio lead will be suitable. The most common, useful type is a 5-pin DIN to 5-pin DIN(see page 13). Alternatively, order the appropriate lead from the supplier of your BBC Microcomputer. Unfortunately, as there are a large number of different kinds of connections, it has not been possible to supply a lead to fit every machine.

What this book can and can't do

The BBC Microcomputer is a very versatile machine. On its own, connected to your television set, it can respond to programs which you yourself type in, to produce numbers, words, lines, movement and sound on the screen. Connect a suitable cassette tape recorder and you can then save your own programs for future use or run programs which have been written by other people. The WELCOME cassette which comes with the computer contains sixteen programs specially written

for the machine. Others will be made available in increasing numbers as time goes by. These will include programs linked to hobbies, games and programs for the home and for business and educational use.

The early sections of this book will show you how to load and save programs from tape, how to write simple programs and how to create certain graphics effects on the screen. There are also some complete programs to type in yourself. However, this is not a step-by-step course in BASIC programming (for details of courses write to the address given below).

Most of what follows in the later sections forms a reference guide on how to use the various commands and keywords of the BBC BASIC language. If you are an absolute beginner then much of this will not be very easy to understand. However, as you get more experience of programming, this material will prove invaluable. To help matters, throughout the book we have used a second typeface to show what appears on your screen or what is typed in at the keyboard.

This book is not the last word on the BBC Microcomputer. Other more specialist books will appear describing the use of its more sophisticated features and how the machine can be expanded in various ways to make it increasingly useful. You will also find other 'fun' books appearing providing programs for you to type in yourself (in the same way that you can with the programs we include in this Guide). Pages on the BBC’s

Ceefax service will also be broadcast with programs for copying by hand into the machine. (It will also be possible to load these directly into the computer via the special Teletext decoder which will be made available as an extra in 1982. This facility is known as Telesoftware and is one of the most exciting possibilities opened up by the BBC Microcomputer.)

For details of courses in programming, books on the BBC system, software programs in the BBC Software List, including Telesoftware, write to:

BBC Computer Literacy Project

PO Box 7

London W3 6XJ

David Allen (Project Editor)

1 Getting going

To get your computer working you will need a television set for a screen. Most people at home will use their ordinary colour or black and white television to show the pictures that the BBC Microcomputer produces. You will also need a cassette recorder.

If you have a high quality monitor (for example in a school) then it can be connected directly to one of the sockets on the back of the computer. To connect the monitor to the computer you will need a special monitor lead.

Assuming that you want to use your normal television set, then you can connect it to the computer using the aerial lead that is supplied with the computer. One of the plugs on this lead has a long central prong which fits into the socket on the back of the computer marked UHF OUT. The other end of the lead goes into the back of your television set in place of the normal aerial lead (figure 1). Don't worry about the cassette recorder for the moment.

Next, plug your computer into the mains and switch it on. It should make a short 'beep' and the red light marked CAPS LOCK should come on. The switch on the back of the computer is marked ON/OFF. Turn the television on too and let it warm up for a moment.

Probably all you will see on the TV screen at this stage is a "snow storm". Sometimes the screen will appear to be just blank. You will have to "tune" the TV so that it can receive the transmissions from the BBC Microcomputer. When your television is tuned correctly words will appear on the screen.

Your television probably has some push-buttons which can be used to select different channels. Often button number 1 is tuned to BBC1, button number 2 to BBC2, button number 3 to ITV and so on. It is best to tune a spare channel for the computer, for example channel 8. You can then use this for the computer without interfering with the tuning of the normal channels.

Different makes of television set tune channels in different ways. For some of them, you turn the same knob that you use to select the channel. For others, there are separate controls. In either case, you should depress a spare channel button and then adjust it, or the associated control, until you get a good picture on the screen. A message similar to

BBC Computer 16K

BASIC

>

should be clear and sharp. Many types of tuning control indicate, approximately, the channel number that you are tuning to. The BBC Microcomputer transmits on channel 36. It will not be too difficult to find the right channel but you will have to tune the TV carefully to get a really clear picture.

After that, do by all means press every button in sight on the computer – you can't do it any harm at all. Usually it just keeps on saying

Mistake

whenever you press the large key marked RETURN That just means that the computer does not understand your commands. Its fault – not yours!

You will see that if you hold any key down for more than a short time the character on the key appears on the screen, then there is a short pause, then the character repeats until you take your finger off again. On the whole, when pressing keys on the keyboard you should aim to press them briefly – unless you want this repetition.

Experimenting

Now you are ready to experiment. You might like to try some of the following to see what the computer can do, but first be sure to press the key marked BREAK This will clear the screen and get the computer ready for you.

Type in the following exactly as shown;

MODE 5

and then press the RETURN key. As you will see the command MODE 5 clears the screen and just leaves the > mark on the screen, > is known as the "prompt" and it means that the computer is ready far your next command.

Pressing the RETURN key tells the computer that you have finished the line you are typing and that you want it to obey your command. Before you press the RETURN key you can correct errors by pressing the key marked DELETE.

If the computer says Mistake then press the BREAK key and try again, starting with MODE 5.

Then type in each of the following lines – but don't forget to press the RETURN key at the end of every line. Don't worry if you make a mistake – it really doesn’t matter!

DRAW 1000,100

DRAW 0,1000

GCOL 0,1

PLOT 85,0,0

If the computer says No such variable then you are probably pressing the letter O instead of the number 0.

PLOT 86,1000,1000

VDU 19,1,4,0,0,0

VDU 19,3,2,0,0,0

VDU 19,0,1,0,0,0

DRAW 200,0

DRAW 0,200

As you will have gathered the DRAW command is used to draw lines while PLOT 85 and PLOT 86 are used to plot and fill in triangles on the screen. When using the graphics the points on the screen are numbered from 0 to 1279 (left to right) and from 0 to 1023 (bottom to top). They are rather like positions on a piece of graph paper.

Words can also be plotted in colours, as you will have seen. Clear the screen by typing MODE 5 and then type the following:

COLOUR 1 this is selects a red foreground

COLOUR 2 this selects a yellow foreground

COLOUR 3 this selects a white foreground

COLOUR 129 this is selects a red foreground

COLOUR 0 this selects a yellow foreground

COLOUR 130 this selects a white foreground

the computer can create sounds as well. Try typing this in:

SOUND 1,–15,100,200

and then press RETURN

That gives a rather simple, crude sound. It is also possible to alter the quality of the sound. Try this:

ENVELOPE 2,3,2,-4,4,50,50,50,127,0,0,0, 126,0

(This should be typed in as one line even though it may spill over to the next line on the screen just as it has on this page. The computer will treat it as being 'one line' when you press RETURN.) Now carry on with:

SOUND 1,2,1,10

SOUND 2,2,100,1

SOUND 3,2,200,1

You will have to press ESCAPE to stop the effect.

Here's another one:

ENVELOPE 1,1,–26,–36,–45,255,255,255, 127,0,0,0,126,0

SOUND 1,1,1,1

There is a whole section on sound later on.

Connecting up the cassette recorder

Now get a cassette recorder connected so that you can load the demonstration programs into the computer from the cassette tape supplied in the WELCOME pack. For the moment just follow the instructions – we can sort out the "whys and wherefores" later.

You have to do two things before you can load the programs from the WELCOME tape: first get the right lead to connect your cassette recorder to the computer and secondly set the volume control on the cassette recorder to the correct position.

Leads

There are a number of different kinds of leads (figure 2). The connection to the computer is through a 7-pin DIN connector; a lead has not been supplied with the machine because there are so many connections to the many different cassette recorders in use. In many cases a standard 5-pin DIN to 5-oin DIN lead will be suitable, provided you do not want to use the motor control. If you want full motor control, take your cassette recorder to your nearest BBC Microcomputer dealer who will be able to supply a lead or make one up for you. Alternatively, take your cassette recorder and this book to a local hi-fi dealer.

Note: Although you may find the ideal cassette lead difficult to buy locally, many cassette recorders do have a standard 5-pin DIN socket and a standard 5-pin DIN to 5-pin DIN hi-fi lead will work with the BBC Microcomputer in many cases.

Volume

Having got the cassette recorder connected to the computer the only remaining thing to do is to set the playback volume on the cassette recorder to the correct level.

With the BBC Microcomputer the cassette volume control setting is not critical. However, a special procedure for setting the volume control correctly is incorporated into the first program on the tape.

Running the WELCOME programs

Press the BREAK key and type in the following, exactly as shown

CHAIN "WELCOME"

and then press the RETURN key. Next insert the WELCOME cassette into your recorder. If your cassette recorder has a tone control then set it to maximum 'treble' and leave it there. Now start the cassette recorder playing by pressing the PLAY button on the recorder. Then adjust the cassette recorder volume control slowly, until you get the message:

Your volume control is now properly

set. Please wait while the first

program is loaded

Figure 2 A range of possible cassette leads

You will need to select a lead with a 7-pin DIN or 5-pin DIN lead at one end. This plugs into the computer. The other end of the lead must have suitable plugs for your particular recorder. Note: a standard 5-pin DIN lead will work with many recorders but will not enable you to make use of the computer’s ability to start and stop the cassette recorder automatically.

on the screen. This will give the minimum volume level. You should then increase the setting a little more. If you need to, you can rewind the tape at any time. If no message appears rewind the tape and play it again, increasing the volume control setting in larger steps, or check the cassette leads are correctly plugged in.

The system is very reliable, so if you have problems it may be that your tape recorder is at fault or that you have a fault in the computer. You are advised to contact your dealer.

Note: Each computer program is recorded on the tape as a kind of screeching noise. It's not meant to be listened to, but some cassette recorders have the annoying habit of playing the tape through the loudspeaker while the tape is loading into the computer. Everything depends on what is plugs and sockets are being used. It is possible to stop this on most recorders by inserting a small (3.5mm) jack plug into the socket on the recorder marked EAR. You could insert the ear-piece supplied with the recorder if that is more convenient. On other recorders you may have to insert a DIN loudspeaker plug, with no wire connections, into the socket marked LS to turn off the noise. Don't try turning the volume control down because then the computer will not be able to "hear" the tape either. The important thing to do is to try to disable the internal loudspeaker as described above.

Make a note of the volume setting on your cassette recorder and always use that setting when playing back the WELCOME cassette. You may need to use a different setting with other tapes that you have purchased or recorded yourself.

On the WELCOME cassette the volume control setting program is repeated many times at the beginning of the tape. With practice it is possible to save time by running the tape forward by about 2 minutes (once the volume control is set) and then begin playing the tape from this point, having first entered the command CHAIN "WELCOME".

When the first WELCOME program has loaded into the computer it will clear the screen and give you instructions.

The WELCOME pack includes a booklet which describes not only how to get the programs running but also what each of the sixteen programs does.

As time goes by, a whole range of 'application programs' will be available on cassette and it will be possible to run these in exactly the same way as the WELCOME package.

The keyboard

Anyone who has used a standard typewriter will be reasonably familiar with the positions of most of the symbols on the keyboard of the BBC Microcomputer. However, there are a number of special keys which need to be mastered (see figure 3) and these are described below.

If you are a keyboard 'novice' you may find the layout daunting. Don’t worry – first of all it is not necessary to be a touch typist to work the computer; secondly, there is a program on the WELCOME cassette which will help you to practice finding the various keys, and most people find that with a little practice they become familiar with them fairly quickly.

Some keys have two symbols engraved on them – we’ll call those on the top 'upper case' and those below 'lower case' symbols.

CAPS LOCK

When the machine is switched on, the middle light should be on, telling you that the CAPS LOCK key is on. This gives capital letters and lower case symbols and is the most useful state for programming because the computer only recognises commands typed in using capital letters. By pressing the CAPS LOCK key once you can switch the light off. Now you get lower case letters and lower case symbols. Press it again and it will be on again.

SHIFT

Whether CAPS LOCK is on or off, if you press either of the SHIFT keys and hold it down while typing in a character you will get a capital letter or upper case symbol.

Holding down CTRL and SHIFT together stops the computer 'writing' to the screen. This can be useful if it is 'writing' faster than you can read.

SHIFT LOCK

Pressing this key once gives capital letters and upper case symbols until it is pressed again. It has its own on/off light.

Practice in the use of these keys is given in one of the first programs in the WELCOME pack – the one called KEYBOARD.

RETURN

This key is the most commonly used key on the keyboard. When a command or anything else is typed in, it is not usually acted upon until the RETURN key is pressed. In other words, this key informs the computer that you have finished entering a line or a reply. Until you press RETURN , you can add to or delete what you have typed in.

Cursor control keys

These enable you to move the flashing cursor around the screen when editing a program. Pressing any of them makes the computer automatically enter the "editing mode" during which two 'cursors' are shown on the screen (see page 29).

DELETE

Pressing this key will cause the last character typed in to be erased from the screen. If held down, it will then erase further characters until released.

COPY

This key, used in conjunction with the cursor control keys, enables anything on the screen to be copied – a useful feature when editing a line in program.

ESCAPE

This key is usually used to stop a program which is running, however, it can be programmed to do other things when pressed – such as to move you from one part of a program to another.

BREAK

This key stops the computer no matter what it is doing. The computer forgets almost everything that it has been set to do

Do not get into the habit of using BREAK. The ESCAPE key provides a much less violent way of escaping, from a program! (See page 142 for more details on BREAK).

CTRL

This key behaves similarly to the SHIFT in that it can be used to change the character generated by other keys. For example, pressing CTRL and G (called Control G) makes the internal speaker make a short noise. CTRL B is used to turn a printer on and CTRL C turns it off. CTRL N makes the computer stop at the bottom of each page, etc., etc. More information on control codes is given on page 378.

TAB

Another key useful in special circumstances – like word processing.

These keys can be somewhat confusing because they seem to generate the wrong characters sometimes. The problem is that there are two international standards for displayed characters (Teletext and ASCII) and the BBC Computer can display both. MODE 7 generates the Teletext display characters and MODES 0 to 6 show the ASCII characters. But don’t worry, the computer recognises the key correctly regardless of what it has to display on the screen. For completeness, here is a table showing all these characters:

Note that in MODE 7 a zero is shown as a rather pointed 0 whereas in all other modes, zeros have a slash thus – 0 - to help

to differentiate them from the letter O. The keyboard is also marked in this way.

Plug in cartridge socket

There may be a slot to the left of the main keyboard where it will be possible to insert cartridge packs containing games and other programs. This inexpensive option will enable users to play games and use other programs with the minimum of effort.

Giving the computer

instructions – Part I

2 Commands

There are two ways of getting the computer to do something:

1. Give it commands which it can act on straight away. This is what happened when you typed in the lines in section 1.

2. Give it a series of numbered instructions, often called statements, which it can store in its memory and carry out in sequence when told to do so. A stored series of instructions is called a program.

Many of the keywords in BASIC: can be used both as commands and as statements in a program.

The rest of this section is concerned with ‘command mode’.

PRINT is used to make the computer print something on the screen. Try these two examples:

PRINT "HELLO"

don’t forget to press RETURN at the end of each line.

PRINT 3+4

In the second example you have given the computer a command to print the sum of 3 and 4. The computer can very easily do addition, subtraction, multiplication and division. The addition, subtraction, multiplication and division signs are all on the right side of the keyboard. If you are interested in doing mathematical or financial work then you will need to know the symbols that the computer uses for various mathematical things. They are:

If you want to get the + or * then you will have to press the SHIFT key as well as the key you want. It's rather like a type-writer: while holding the SHIFT down, press the + sign quickly once.

Try typing in the following and check that they work, in other words see that they produce the expected answers.

PRINT 4+8

PRINT 18 – 2 * 4

PRINT 131/4

PRINT SQR(2)

The last one will print the square root of 2 which is 1.41421356. Then try

MODE 5

which will make the computer clear the screen and get it ready to draw lines as well as text. In this mode

COLOUR 129

will select a red background, and

CLS

will clear the screen to the background colour. In each case you have given the computer a command and it has obeyed it immediately. Working like this is called "working in command mode".

While in this mode you might like to learn how to use the bright red USER Defined Function keys. Each of these keys can be users to store a word or several words. For example they could be programmed so that each one selects a different colour. Try this

*KEY 2 COLOUR 2 ¦ M

The. ¦ shown above is produced by a special key. On the keyboard this key is the third key from the right on the row below the red keys. In Mode 7 this key produces ¦ on the screen.

Once you have typed that in then every time you press the key marked f2, the computer will change to COLOUR 2 which gives

yellow lettering. In a similar way you could program some of the other keys like this:

*KEY 0 COLOUR 0 ¦ M

*KEY 1 COLOUR 1 ¦ M

*KEY 3 COLOUR 3 ¦ M

Note the exact position of spaces in what you type in.

Of course red letters don't show up very well on a red background! You will have noticed the ¦M at the end of each line above. That is the code used to get a RETURN into the User Defined Function Keys.

If the picture on your television screen is either too far up or too far down the screen, you can move the whole display with the command *TV.

*TV 255 will move down one line

*TV 254 will move down two lines

*TV 1 will move up one line

*TV 2 will move up two lines

The movements come into affect next time you press BREAK or change MODE.

3 An introduction to variables

In the last section we made the computer do a number of calculations but it was never expected to remember any of the results after it had printed them out. Suppose that you have to calculate the wages for everyone in a company. After you have worked out each person's wage, it would he useful to be able to add it to all the other wages that you had worked out so far, so that in the end you would know the total wage bill. Keeping track of things that vary during a long calculation is done by using "variables".

Try typing this line into the computer

LET Z=5

And now try typing in each of the following, lines

PRINT Z+6

PRINT Z * 12

As you will have seen, once we have told the computer that "Z is 5" it understands that every time we use the letter Z in a sum it has to go and have a look to find out what the value of Z is (5 in this case) and use that number in the arithmetic that we set it to do. Now type in

LET Z=71

And then try these two lines

PRINT Z+12

PRINT Z/3

As you will gather the value of Z has changed from 5 to 7. In computer jargon "Z" is called a "numeric variable". That means that Z can be used to store any number, and you can change the value of Z any time you want to.

The computer is able to store hundreds of different variables and the variables don’t just have to be called something as simple as Z, you can call a variable by as long a name as you want. For example you could write

MYAGE=30

Notice that MYAGE was written without any spaces between the word MY and AGE. There are only four restrictions about the names that we give to variables.

1 There must be no spaces in the middle of a variable name.

2 All variable names must start with a letter, though you can stick as many numbers in as you want to later on.

3 You must not use punctuation marks (like exclamation marks and question marks) in the variable name but you can use an underline character.

4 Variable names should not begin with BASIC "keywords" like PRINT and LET. One that is particularly easy to use by mistake is the keyword TO. However it is quite permissable to start a variable name with a lower case "to" because upper and lower case names are quite different. There is a full list of keywords starting on page 483.

To get lower case characters on the screen, make, sure that the CAPS LOCK is off by depressing it so that its light goes out. In this condition you will get small letters and numbers. Hold the SHIFT key down if you want to get just a few capital letters.

Any of the following variable names would be acceptable to the computer

LET AGE=38

LET this_year=1982

LET lengthOFrod=18

LET CAR_mileage=13280

LET value5=16.1

LET weight4=0.00135

LET chicken2egg3=51.6

However the (allowing variable names are illegal.

LET Football Result=3 [there’s a space]

LET Who?=6 [there’s a question mark]

LET 4thvalue=16.3 [starts with a number]

LET TODAY=23 [starts with TO]

LET PRINT=1234.56 [PRINT is a reserved word]

You will notice that in all the examples above we have put the word LET before the variable name. That gives a clear indication of what is actually happening inside the computer, namely that the numeric: variable "this_year", in one of the examples, is being given a new value "1982". The word LET is optional and the computer will understand perfectly well if we say

this_year=1982

This shortened version is much more common.

4 A simple program

In the previous sections we have been giving the computer commands which it obeys immediately. The problem with this technique is that you have to wait until the computer has completed one command before you can give it the next one. If the computer takes a long time to work out one of the problems you have set it, then you may have to waste an awful lot of time just sitting there waiting for it. For example if you want your computer to work out the number of 5p, 10p and 50p coins that you will need to pay the wages at the end of the week the computer will take a fair time to calculate all the wages before it can sort out the coins required.

The same problem arises when you take a car into a garage to be serviced. You could for example stand by the mechanic and say "Right, first of all I want the oil changed" and then you could wait for him to change the oil. When he had completed that you could then say "Right, now I want you to replace the bulb that has blown in one of the front headlights" and then you could wait for him to do that job. And thirdly you might say "The exhaust is making, a bit of noise, so I want you to put the car up on the ramp and check the exhaust".

Inevitably you would spend a great deal of time waiting, for the mechanic to complete the job that you had set him before you could give him the next job. There is a far more efficient way of doing things; when you go into the garage you give the mechanic a whole set of instructions, for example

first of all change the oil,

secondly replace the headlamp bulb,

thirdly stop the exhaust rattling.

Once you have given your set of instructions and checked that the garage understands what they have to do, you can then walk off and have a cup of coffee and then go back expecting the job to be done. Now the same thing applies with a computer. It is far better to give it a whole set of instructions

and set it going on something while you wander off and have a cup of coffee. "Writing a computer program" is nothing more than giving a set of instructions.

If you give the computer a command like

PRINT "HOW ARE YOU"

then the computer will do that immediately. On the other hand, if you give the computer a statement

10 PRINT "HOW ARE YOU"

then the computer will regard that as instruction number 10 and it will not do it straight, away, but expect other instructions. to follow. Instruction number 10 is usually referred to as Line 10 etc. Again: if there is a line number then the statement is part of a program; if there is no line number then it is a command which the computer must obey immediately.

When you have given the computer a set of instructions and you then want it to carry them out, you type the word RUN on the keyboard. The computer will then carry out the instructions that you asked it to do one at a time and in line-number order. In other words, it will "execute the program" that you have typed in. Just to check that you have got the idea of what is going on, here is a small program that you can type in.

10 REPEAT

20 PRINT "GIVE ME A NUMBER";

30 INPUT B

40 PRINT "12 TIMES ";B;" IS ";12*B

50 UNTIL B=0

When you RUN the program line 20 will print the message

GIVE ME A NUMBER

on the screen.

Line 30 will print a question mark on the screen and wait for you to type in a number (followed by RETURN as usual). The number you type in will become the value of the variable "B".

Line 40 will first print the words 12 TIMES followed on the same line by the number you typed in, followed on the same line by the word IS followed by the result of the calculation.

The semi-colons tell the computer to print the next item on the same line as the previous one and right up against it.

Line 50 sends the computer back to line 10 unless B=0, when the program will stop.

Another way of stopping the program is to press the "panic button" which is marked ESCAPE on the keyboard. It is at the top left of the keyboard. If the computer seems to be ignoring you because it’s too busy running a program you can nearly always get its attention by pressing the ESCAPE button. When you do that it will stop running your program and print a > prompt to show that it has stopped the program and that you have command again.

When the computer shows a > it is in Command Mode. You can change your program, give it command for immediate execution, or tell it to RUN the program (in its memory) again. It doesn’t forget a program when you press ESCAPE.

If the computer is in command mode (in other words the last thing on the screen is >) then you can command it to print the program in its memory by typing

LIST

and pressing RETURN.

The computer will then give a list of the program on the screen for you to check. If you discover that you have made an error, for example that you have got something wrong in line 20, then it is easy to correct the error. There are two ways of correcting major errors:

1 Retype the whole line

2 Use the screen editor

Using the screen editor

There is a group of six keys on the right hand side of the keyboard which can be used to edit, or alter, program lines that are displayed on the screen. Four of the keys have arrows on them and are coloured a lighter brown than most of the other keys. These keys enable you to move a flashing cursor around the screen to a line that you wish to edit. As soon as you press one of these keys the computer enters a special "editing mode" where it displays two cursors. The large white block is called

the WRITE CURSOR and it shows you where anything that you enter will appear. The other small, flashing cursor – the READ CURSOR – is the one that can be moved around by the arrow keys.

Try moving the read cursor, by using the arrow keys, until it is under a letter at the start of a word and then press the COPY key several times. As you will see the COPY key copies everything that the read cursor passes under intro the new input line. Half way through copying a line you can always use

to move the read cursor to some new place on the screen before using COPY again to copy some other text to your new input line. The DELETE key can always been used to delete characters from the input line.

You can also type new characters in at any time instead of using the COPY key. When your new input line is complete just press RETURN in the usual way.

Try the following: clear the screen with the command CLS and then LIST the program. It should include the line

20 PRINT "GIVE ME A NUMBER";

If not, then type that line in so that you can edit it. Suppose that you wanted to insert the word BIG so that line 20 reads

20 PRINT "GIVE ME A BIG NUMBER";

then all you have to do is to press the up-arrow cursor key until the small flashing line is positioned under the 2 of 20. Then press the COPY key to copy the first part of line 20 to a fresh line at the bottom. When the cursor reaches the space after the A where you want to insert the word BIG, just type it in with a space in front – it will appear on the bottom line. Then COPY the rest of the line 20. the space after the A becoming the space after BIG. At the end press RETURN.

Now try changing the program already in the computer once again by doing the following things:

1. List the program by using the LIST command.

2. Practice using the cursor control and COPY keys to alter line 20 so that it reads:

20 PRINT "NOW GIVE ME A BIG NUMBER";

1. Now add these new lines. Don't forget to press RETURN after each one.

5 CLS

25 REPEAT

35 IF B<1000 THEN PRINT "I SAID A BIG NUMBER"

37 UNTIL B>1000

Note: it doesn’t matter in what order you type in new lines. The computer will automatically put them into numerical order. You will see that this is true by typing

LIST RETURN

these extra lines tell the computer to reject any number .smaller than 1000 and to go on going back to line 30 to ask for a new number until that number is greater than 1000. The symbol < means ‘is smaller than’, and > means ‘is greater than’. IF and THEN are self explanatory.

1. Now RUN the program.

>RUN

NOW GIVE ME A BIG NUMBER? 16

I SAID A BIG NUMBER

?20

I SAID A BIG NUMBER

?2000

12 TIMES 2000 IS 24000

NOW GIVE ME A BIG NUMBER?

This program will go on running until you press ESCAPE. If you look you will see that if you give the value 0 for the number, the program never reaches line 50, so it can never end unless you press the panic button!

Removing part of a program

Quite often you will want to delete a whole line or group of lines in your program. This is easy to do but don’t forget that if you type in a new line 20 (for example), it will automatically remove the old line 20 and replace it with your new one. If you just want to delete a line completely then type in just the line number and press RETURN thus:

20 RETURN

To delete a whole set of line numbers, for example, lines 50 to 70 inclusive, you can type

DELETE 50, 70

You cannot get these lines back once they are deleted – unless you copy them off the screen, so use this with care.

After you have deleted several lines – or if you have typed in lots of new lines – you often find that you have a very odd set of line numbers. The command

RENUMBER

will make the computer go through your whole program renumbering all the lines so that they are given line numbers in a tidy sequence. Here is an awful example of programming style – but it will illustrate the renumber command. Don’t bother to type it in – just look at it.

>LIST

1 REM ** GOTO GOTO GOTO

2 REM WITH ACKNOWLEDGEMENTS TO

3 REM "COMPUTERS IN SCHOOLS"

4 REM THE JOURNAL OF MUSE

15 GOTO 100

16 GOTO 95

40 N=N+1

44 END

57 IF N=18 THEN PRINT "GOTO OR NOT TO GOTO"

60 IF N>35 THEN GOTO 110

78 GOTO 40

95 PRINT "**THE GOTO SHOW**": GOTO 40

100 N=0: GOTO 16

105 PRINT "GOT TO GOTO GOTO NOW"

110 GOTO 44

115 PRINT "GOTO OR NOT TO GOTO"; GOTO 60

>RENUMBER

>LIST

10 REM ** GOTO GOTO GOTO

20 REM WITH ACKNOWLEDGEMENTS TO

30 REM "COMPUTERS IN SCHOOLS"

40 REM THE JOURNAL OF MUSE

50 GOTO 130

60 GOTO 120

70 N=N+1

80 END

90 IF N=18 THEN PRINT "GOTO OR NOT TO GOTO"

100 IF N>35 THEN GOTO 150

110 GOTO 70

120 PRINT "**THE GOTO SHOW**": GOTO 70

130 N=0: GOTO 60

140 PRINT "GOT TO GOTO GOTO NOW"

150 GOTO 80

160 PRINT "GOTO OR NOT TO GOTO"; GOTO 100

>RUN

**THE GOTO SHOW**

As you will see, the RENUMBER command has not only renumbered all the line numbers but it has accurately renumbered the references to line numbers which occur within the program itself – namely after the statements containing the keyword GOTO. (This gives the computer the instruction to go to a particular line number and carry out the instruction it finds there.)

Removing a program

If you want to write a new program you will want to remove the old program from the computer's memory. This can be done by using the command NEW, or by pressing the BREAK key. In either case, if you regret having lost your program, type OLD and press RETURN and, providing you haven't begun to type in a new program, the old one should reappear.

You can always check what’s in the memory by typing LIST.

Try experimenting with these various commands on the program you have typed in.

5 Recording programs on cassette

The WELCOME cassette supplied with your BBC Microcomputer has a number of programs stored on it. You can store a copy of any program on cassette and then load it back into the machine at some time in the future. It really is just like recording music onto a cassette – you can then play the cassette back a few days later and the music will still be there.

If you decide that you don't want to keep the computer program that you have saved on cassette then you can just record a new program over the top one in the same way that you can re-use a cassette when recording music. And in the same way that it is very easy to forget where a particular piece of music is recorded on a cassette, so it's very easy to forget where on the cassette you have stored a particular program. It is very strongly suggested that you use the tape counter to keep an index of where programs are on the cassette. Also you must leave gaps between programs. It is very easy to let one program run over the start of the next one if they are all squashed close together. If programs do overlap then you will definitely lose one of them. Be warned!

Most short programs will only move the cassette tape counter on 30 or 40 positions but play safe and spread the programs out over the length of the cassette. If you record the first program at 0000, the second at 0100, the next at 0200 and so on then they will be easy to find and they are unlikely to run over each other.

Note: don’t make the mistake of trying to record on the clear plastic tape ‘leader’ – wind the tape on by hand until the brown tape itself is exposed.

Saving a program on cassette

If you have typed a program into your microcomputer then all you have to do to save it is to

1. Insert the cassette into the recorder.

2. Set the tape counter to 0000 when the tape is fully re-wound.

3. Type

SAVE "MYPROG"

on the computer and then press the RETURN key.

1. The message RECORD then RETURN will appear.

2. Fast forward the cassette to the place where you want to record the program – this will be 100 or 200 or 300 etc. on the tape counter.

3. Press the RECORD button on the cassette and then press the

RETURN key.

If you want to give up at any time then press the ESCAPE key.

Notice that MYPROG is the name that we happened to give to the program. You can call your program by any name you like so long as it has no more than 10 characters. For example you could have typed

SAVE "FRED" or

SAVE "GAME3" or

SAVE "picture"

While the program is being saved on the cassette the name of the program and some numbers will appear to tell you that things are happening. When the computer has finished, the > prompt will re-appear and the tape will stop automatically. If you don’t have cassette motor control then you will have to stop the recorder manually after the > prompt re-appears. That’s it.

Checking a recording

If you want to check that you have successfully recorded your program on the tape then you can use the *CAT command (see page 36). If your recording failed for any reason you can always re-record it. See page 390 if you have problems.

Loading a program from cassette

Loading a program back into the computer is just like playing a

particular piece of music which has been recorded on the cassette.

1 Type

LOAD "MYPROG"

and then press the RETURN key. The message Searching will appear. Of course if your program is called something else then use the right name, for example

LOAD "GAME3"

2 Rewind the cassette to just before the start of your program (which will be at 100 or 200 etc.)

3 Check that the volume and tone control settings are correct – see page 12 if you are not sure how to find the correct settings.

4 Start playing the cassette by pressing the PLAY button on the recorder.

When the computer finds any program on the cassette it will show the name of the program on the screen. When it finds the program it is looking for it will print "Loading" to let you know that it is now loading the right program.

When the computer has finished loading the program it will print the > prompt. It will also automatically stop the tape if you have automatic motor control, if not then you will have to stop the tape manually.

The program is now in the computer. You can type RUN to make it work, as usual.

There is one more useful feature to do with loading and saving programs. Instead of typing LOAD "MYPROG" you can type CHAIN "MYPROG". This not only loads in the program MYPROG but also starts it working as soon as it has loaded. It saves you having to type RUN after the program has loaded. It is normally more convenient to use CHAIN than LOAD.

Cataloguing a tape

If you forget what programs you have on the tape then you can get a catalogue by typing

*CAT

and then playing the tape. But you’ll have to wait until the tape has run through the programs.

What the numbers mean

A typical catalogue looks like this

WELCOME 00 0084

INTRO 08 088E

INDEX 0A 0ABA

KEYBOARD 25 2545

The file-name is followed by two ‘hexadecimal’ numbers which give the "block number". Each program is recorded as a series of "blocks". See page 71 for an explanation of hexadecimal numbers.

The last number on the line gives the ‘length’ of the file.

The action of cataloguing a tape also lets the computer verify the information recorded. If there are errors in any of the data on the tape it will print a message and continue.

The ESCAPE key allows you to leave cassette operations whenever you like. If you leave from the middle a LOAD operation you will probably get a Bad Program error. Type NEW to remove this.

More information about cassette formats, loading errors and files is given on page 390.

6 Sample programs

Most of the rest of this book is concerned with introducing the various parts of the BBC BASIC language which the computer understands and other features of the machine. But first, here are a few complete programs which you can try to type in yourself. They must be typed in as accurately as possible and can then be run. If a program fails to run properly, then almost certainly you have typed a line in incorrectly – for instance, you may have typed ; when you should have typed : typed O instead of 0.

Most of the sample programs are too big to fit on the screen in one go. If you LIST a program you have typed in, for example to check that you have made no mistakes, you may find that the lines you want to look at disappear off the top of the siren. To prevent this you can specify the range of lines you want to be listed. For example

LIST 100,200

will only list those lines numbered between 100 and 200.

Alternatively you can enter "page mode" by pressing, CTRL N (hold down CTRL and press N). In this mode the listing will stop after every "page" and will continue only when you press the SHIFT key. "Paged mode" is switched off by pressing CTRL O and you should always remember to do this after you have listed the program.

Typing in programs will help you to get a feel for the keyboard and, if you save them on cassette after you have satisfied yourself that they do run properly, will enable you to start to build up a library of them.

Learning to use the computer is a little like learning to drive a car – when you first start you find that there are an enormous number of things to think about at once. Many of the things you come across from now on will be bewildering at first, But as you get further into the book and as you gain experience in

using BASIC, the various parts of the jig-saw puzzle should begin to fall into place. So don’t worry if, for instance, some of the comments about the following programs are difficult to understand at first.

Note: In the program listings which follow, extra spaces have been inserted between the line numbers (10, 20, etc) and what follows on each line. This is to improve the readability of the programs. However, although it will do no harm, there is no reason to type in any spaces after the line number. For example in the first program, called POLYGON, when entering line 250, all you need type is

250MOVE 0,0

POLYGON

This program draws polygons (many sided shapes) in random colours.

Lines 120 to 180 move to a random place on the screen which will be the centre (origin) of the next shape. Lines 210 to 290 calculate the X and Y co-ordinates of each "corner" of the polygon and store the values in two ‘arrays’ for future use. In addition the shape is filled with black triangles (lines 260 and 200) thus making it appear that the new polygon is in front of older ones. Lines 310 to 370 draw all the lines that make up the polygon.

Lines 50 to 70 set the actual colours of logical colours 1, 2 and 3 to red, blue and yellow. You can change these if you wish to use other colours.

10 REM POLYGON

20 REM JOHN A COLL

30 REM VERSION 1 / 16 NOV 81

40 MODE5

50 VDU 19,1,1,0,0,0

60 VDU 19,2,4,0,0 0

70 VDU 19,3,3,0,0,0

80 DIM X(10)

90 DIM Y<10)

100

110 FOR C=l TO 2500

120 xorigin=RND(1200)

130 yorigin=RND(1000)

140 VDU29,xorigin;yorigin;

150 radius=RND(300)+50

160 sides=RND(8)+2

170 MOVE radius,0

180 MOVE 10,10

190

200 GCOL 0,0

210 FOR SIDE=1 TO sides

220 angle=(SIDE-1)*2*PI/sides

230 X(SIDE)=radius*COS(angle)

240 Y(SIDE)=radius*SIN(angle)

250 MOVE0,0

260 PLOT 85,X(SIDE), Y(SIDE)

270 NEXT SIDE

280 MOVE0,0

290 PLOT 85,radius,0

300

310 GCOL 0,RND(3)

320 FOR SIDE=1 TO sides

330 FOR line=SIDE TO sides

340 MOVE X(SIDE), Y(SIDE)

350 DRAW X(line), Y(line)

360 NEXT line

370 NEXT SIDE

380 NEXT C

You may like to try this alternative for line 200

200 GCOL 0, RND(4)

MONTHLY

This program plots a set of "blocks" on the screen which might represent prices over a twelve month period. In its present form it will only work on a Model B Computer. With minor modifications (eg changing line 100 to MODE 5) it can be made to run on Model A. In this example the height of the bars is randomly selected at line 170. Lines 180 to 270 then draw a "solid" bar and the edges are marked in black by lines 290 to 330. Lines 340 and 350 print out one letter representing the month of the year at the bottom of each bar.

Notice that lines 60 and 70 set up two of the function keys.

Key 0 resets the computer to MODE 7 and then lists the program. Key 9 can be used to run the program.

10 REM MONTHLY

20 REM JOHN A COLL

30 REM VERSION 1 / 16 NOV 81

40 REM MODEL B

50

60 *KEY 0 "MODE7 |M LIST|M"

70 *KEY 9 "RUN |M"

80 M$="JFMAMJJASOND"

90 C=0

100 MODE 2

110 VDU 5

120 VDU 29,0;100;

130

140 FOR X=0 TO 1100 STEP 100

150 GCOL 0,C MOD 7+1

160 C=C+1

170 H=RND(400)+300

180 MOVE X,0

190 MOVE X,H

200 PLOT 85,X+100,0

210 PLOT 85,X+100,H

220 MOVE X+70,H+50

230 MOVE X,H

240 PLOT 85,X+170,H+50

250 PLOT 85,X+100,H

260 PLOT 85,X+170,50

270 PLOT 85,X+100,0

280 GCOL0,0

290 MOVEX,H

300 DRAW X+100,H

310 DRAW X+170,H+50

320 MOVE X+100,H

330 DRAW X+100,0

340 MOVE X+10,50

350 PRINT MID$(M$,C,1)

360 NEXT

370

380 GCOL 4,1

390 PRINT TAB(0,16)"----------------"

400 VDU4

410 PRINTTAB(3,0)"critical level"

The height of each bar is set randomly by the variable H. If you want to put in your own values (data), then type the following extra lines. Line 170 must also be deleted by typing 170 followed by RETURN.

50 DIM data(12)

82 FOR J=l TO 12

84 PRINT "Input data for month" MID$(M$,J,1);

86 INPUT data(J)

88 NEXT J

89 INPUT "CRITICAL LEVEL", level

155 H=data(C+1)

390 MOVE 0, level:PRINT"-------------------"

Quadrat

This program can be used to solve equations of the form

Y=Ax²+Bx+C

The "roots of the equation" are printed to two decimal places. The number of decimal places is set by line 90.

The main program between lines 110 and 170 uses three procedures – one for each of the three types of result. The main program is surrounded by

REPEAT

'

'

'

UNTIL FALSE

which has the effect of keeping the program going for ever – or until the ESCAPE key is pressed.

Line 170 PRINT''' prints three blank lines to separate one set of results from the next.

10 REM QUADRAT

20 REM JOHN A COLL BASED ON A PROGRAM

30 REM BY MAX BRAMER, OPEN UNIVERSITY

40 REM VERSION 1.0 / 16 NOV 81

50 REM SOLVES AN EQUATION OF THE FORM

60 REM A*X^2 + B*X +C

70 ON ERROR GOTO 350

80 MODE 7

90 @%=&2020A

100 REPEAT

110 PRINT "What are the three coefficients ";

120 INPUT A,B,C

130 DISCRIM=B^2-4*A*C

140 IF DISCRIM<0 THEN PROCcomplex

150 IF DISCRIM=0 THEN PROCcoincident

160 IF DISCRIM>0 THEN PROCreal

170 PRINT'''

180 UNTIL FALSE

190 END

200

210 DEF PROCcomplex

220 PRINT "Complex roots X=";-B/(2*A)

230 PRINT " +/ "; SQR(-DISCRIM) /(2*A) "i"

240 ENDPROC

250

260 DEF PROCcoincident

270 PRINT"Co-incident roots X=";B/(2*A)

280 ENDPROC

290

300 DEF PROCreal

310 X1=(-B+SQR(DISCRIM))/(2*A)

320 X2=(-B-SQR(DISCRIM))/(2*A)

330 PRINT "Real distinct roots X=";X1;" and X=";X2

340 ENDPROC

350 @%=10:REPORT:PRINT

>RUN

What are the three coefficients ?1,-1, -2

Real distinct roots X=2.00 and X=-1.00

What are the three coefficients ?3,3,3

Complex roots X=-0.50 +/- 0.87i

What are the three coefficients ?1,2,1

Co-incident roots X=1.00

What are the three coefficients ?

Escape

>

FOURPNT

This program draws a pattern (lines 80 to 140) and then changes foreground and background colours with a half second pause between each change.

10 REM FOURPNT / DRAWS A PATTERN WITH 4 POINTS

20 REM JOHN A COLL

30 REM VERSION 1 / 16 NOV 81

40 REM MODEL A

50 MODE 4

60 VDU 29,640;512;

70

80 FOR A=0 TO 500 STEP 15

90 MOVE A-500,0

100 DRAW 0,A

110 DRAW 500-A,0

120 DRAW 0,-A

130 DRAW A-500,0

140 NEXT A

150

160 FOR B=0 TO 7 :REM CHANGE THE COLOUR

170 FOR C=1 TO 3

180 T=TIME :REM WAIT A WHILE

190 REPEAT UNTIL TIME-T>50

200 VDU 19,3,C,0,0,0

210 VDU 19,0,6,0,0,0

220 NEXT C

230 NEXT B

TARTAN

This program builds up a changing pattern by overdrawing lines on the screen.

The main program between lines 90 and 140 loops for ever and calls various subroutines as necessary. The use of subroutines with implied GOTO (e.g. line 170) results in a structure which is not easy to follow! It would be better to use "structures" such as procedures (see page 86).

10 REM TARTAN

20 REM BASED ON RESEARCH MACHINES DEMO

30 REM VERSION 1.0 / 16 NOV 81

40 MODE 2: REM ALSO WORKS IN MODE 5

50 R=l: D=l: X=0

60 Y=RND(1280)

70 MOVE X,Y

80

90 REPEAT

100 ON D GOSUB 160,260,350,430

110 IF RND(1000)<10 THEN R=D-1

120 GCOL R,(D*1.7)

130 DRAW X,Y

140 UNTIL FALSE

150

160 X=X+1024-Y

170 IF X>1280 THEN 220

180 Y=1024

190 D=2

200 RETURN

210

220 Y=1024/1280-X

230 X=1280: D=4

240 RETURN

250

260 Y=Y-1280+X

270 IF Y<0 THEN 310

280 X=1280: D=3

290 RETURN

300

310 X=1280+Y

320 Y=0: D=1

330 RETURN

340

350 X=X-Y

360 IFX<0 THEN 400

370 Y=0: D=4

380 RETURN

390

400 Y=-X: X=0: D=2

410 RETURN

420

430 Y=Y+X

I40 IF Y>1024 THEN 480

450 X=0: D=1

460 RETURN

470

480 X=Y-1024

490 Y=1028: D=3

500 RETURN

PERSIAN

This program produces a pattern by drawing hundreds of lines. Random colours are selected by lines 60 and 70. Line 80 moves the "origin (middle) of the picture to the middle of the screen". It runs on Model B only.

10 REM PERSIAN

20 REM ACORN COMPUTERS

30 REM VERSION 2 / 16 NOV 81

40 MODE1

50 D%=4

60 VDU 19,2,RND(3)+1,0,0,0

70 VDU 19,3,RND(3)+4,0,0,0

80 VDU 29,640;512;

90 J1%=0

100 FOR K%=500 TO 380 STEP -40

110 REPEATJ2%=RND(3):UNTILJ2%<>J1%

120 J1%=J2%

130 GCOL 3, J1%

140 FOR I%=-K% TO K% STEP D%

150 MOVE K%,I%

160 DRAW -K%,-I%

170 MOVE I%,-K%

180 DRAW -I%,K%

190 NEXT

200 NEXT

SQR ROOT

This program calculates the square root of a number by repeating a simple operation (lines 90 and 200) until the calculated result stays steady. The program also indicates how long the calculation takes.

This program illustrates an important mathematical technique – but of course you don’t have to work out square roots this way, the (unction SQR is provided in BASIC (see page 355).

10 REM SQROOT

20 REM VERSION 1.0 / 16 NOV 81

30 REM TRADITIONAL ITERATION METHOD

40 REM TO CALCULATE THE SQUARE ROOT

50 REM OF A NUMBER TO 3 DECIMAL PLACES

60 MODE 7

70 ON ERROR GOTO 300

80 @%=%2030A

90 REPEAT

100 count=0

110 REPEAT

120 INPUT "What is your number ",N

130 UNTIL N>0

140 DELTA=N

150 ROOT=N/2

160 T=TIME

170 REPEAT

180 count=count+1

190 DELTA=(N/ROOT-ROOT)/2

200 ROOT=ROOT+DELTA

210 UNTIL ABS(DELTA) <0.001

220 T=TIME-T

230 PRINT

240 PRINT "Number ",N

250 PRINT "Root ",ROOT

260 PRINT "Iterations", count

270 PRINT "Time",T/100;" seconds"

280 PRINT''

290 UNTIL FALSE

300 @%=10:PRINT:REPORT:PRINT

>RUN

What is your number ?34

Number 34.000

Root 5.831

Iterations 5.000

Time 0.070 seconds

What is your number ?125

Number 125.000

Root 11.180

Iterations 6.000

Time 0.080 seconds

What is your number?

BRIAN

This program prints a "path in the grass".

It is a fine example of a "non-structured" use of BASIC, you might like to try and "structure" it.

90 REM BRIAN2

100 REM (C) BRIAN R SMITH 1980

110 REM ROYAL COLLEGE OF ART, LONDON

120 REM VERSION 1.0 / 16 NOV 81

130 INPUT "NUMBER OF CYCLES e.g. 1 to 5 ",T

140 INPUT "BACKGROUND SYMBOL e.g. + ",D$

150 INPUT "MOTIF (<20 CHR$.)",A$

160 INPUT "TEXT AFTER DESIGN", B$

170 CLS

180 F=1

190 READ A,G,S,C,D,N

200 H=(D-C)/N

210 X=0

220 J=1

230 X=X+S

240 Y=SIN(X)

250 Y1=1+INT((Y-C)/H+0.5)

260 I=0

270 I=I+1

280 IF I=Yl THEN 310

290 PRINT D$;

300 GOTO 420

310 Z=Z+F

320 IF Z>0 THEN 350

330 F=-F

340 GOTO 450

350 IF Z<=LEN(A$) THEN 390

360 F=-F

370 Z=Z-1

380 GOTO 310

390 S$=LEFT$(A$,Z)

400 PRINT S$;

410 I=I+Z

420 IF I<40 THEN 270

430 PRINT

440 GOTO 230

450 J=J+1

460 IF J>T THEN 490

470 Z=Z+1

480 GOTO 310

490 FOR K=1 TO 39

500 PRINT D$;

510 NEXT K

520 PRINT

530 PRINT B$

540 DATA 0,6.4,0.2,-1,1,20

>RUN

NUMBER OF CYCLES e.g.1 to 5 ?3

BACKGROUND SYMBOL e.g. + ?.

MOTIF (<20 chrs.)?Hello David !!

TEXT AFTER DESIGN?That's all foLks

SINE

This program draws a sine wave on the screen. The computer can draw dotted lines and the feature is used to fill in one part of the sine wave (line 130).

The computer can also print letters anywhere on the screen not just on a 40 by 32 grid. Lines 190 to 220 print a message in the shape of another sine curve.

10 REM SINE

20 REM JOHN A COLL

30 REM VERSION 2 / 16 NOV 81

40 REM MODEL A

50 MODE4

60 VDU5

70 GCOL 0,1

80 VDU19,1,1,0,0,0

90 MOVE 16,400

100

110 FOR X=0 TO 320

120 IF X<150 THEN MOVE 4*X+16,400

130 PLOT 21,4*X+16,300*SIN(X/48)+ 400

140 NEXT

160 GCOL 0,1

170 AS="SINE WAVES ARE FAR MORE INTERESTING . . . . ."

180

190 FOR X=1 TO 39

200 MOVE X*1280/40,300*SIN(X/6)+512

210 PRINT MID$(AS,X,1)

220 NEXT

230

240 VDU4

250 END

DOUBLE HEIGHT

Here is an example of an 'assembly’ language program embedded within a BASIC program between the two brackets [ and ] which enables you to type in double height letters on the screen.

10 REM DOUBLE HEIGHT IN TELETEXT

20 WIDTH 36: MODE7

30 VDU 28,0,23,39,0

40 write=!&20E AND &FFFF

50 DIM PROG 100

60 FOR PASS=0 TO 1

70 P%=PROG

80 [

90 OPT PASS*3

100 CMP #&D : BNE noter

110 PHA : JSR write

120 LDA #&8D : JSR write

130 LDA #&0A : JSR write

140 LDA #&08 : JSR write

150 LDA #&8D : JSR write

160 PLA : RTS

170 . noter CMP #&20 : BCS legal

180 JMP write

190 . leqal PHA : JSR write

200 LDA #&0B : JSR write

210 LDA #&08 : JSR write

220 PLA : PHA : JSR write

230 LDA #&0A : JSR write

240 PLA : RTS

250 ]

260 NEXT PASS

270 !&20E=!&20E AND &FFFF0000 OR PROG

280 END

Line 270 changes the "write character" routine indirection vector so that all output is sent to the new routine given above. This routine tests for a "return" code (line 100) and if it finds one it issues Teletext double height control codes on to the next two lines. Otherwise the routine just prints the characters on two lines one above the other so as to produce a double height character. This routine has a quite different effect in non-Teletext modes. Try it. Press BREAK after you have finished with this program.

Before we leave this section, here are a few points about entering lines into BASIC.

1. Contol characters, for example CTRL B, will only be 'reflected' in BASIC and not entered into any program lines, strings etc.

2. Spaces entered in lines will be preserved including those at the end of the line. This allows blank lines to be entered eg

10 space RETURN

to separate program sections. Some of the programs above have such blank lines. Because of this you should avoid using COPY past the true end of a line.

1. Most keywords can be abbreviated using a full stop, eg L. for LIST, SA. for SAVE. See page 483 for a list of abbreviations.

Giving the computer instructions -

Part II

This section of the User Guide introduces many more of the ‘keywords’ which are used in the writing of programs on the BBC Microcomputer.

We start with some miscellaneous, useful keywords and then go on to look at some of the graphics and colour statements. It is easy to explore the effects which these produce without any systematic knowledge of BASIC. You should experiment with each statement not only by typing in the commands or test programs which are given but by changing many of the values of the various variables to see what effects are produced. In this way you will become familiar with the use of each keyword and begin to see how it can be used in your own programs. For further information see the reference chapter on BASIC keywords.

7 AUTO, DELETE, REM, RENUMBER

BASIC provides a number of facilities to help the user to enter programs into the computer and to modify programs already there. As you will know by now, it is usual to use line numbers 10, 20, 30, 40 etc., for programs. This leaves gaps where the user can insert extra lines later on – for example, he or she might insert lines 11, 12, 13 and 14. When typing in a line of program the user types in the 'line number" first and then the rest of the line. For example,

10 PRINT "THIS 1S A PROGRAM"

The command AUTO instructs the computer to "offer" the line numbers automatically to the user. As an option you can tell the computer to start offering lines from any number. Thus AUTO 300 would make the computer produce line number 300, then 310, then 320, etc. There are other options, too, which are explained on page 213.

The command DELETE allows the user to delete a group of lines from his or her program. When you are writing a long program you quite often need to be able to delete a large chunk of it. The keyword DELETE is followed by two numbers which give the first and last lines that you wish to remove. Thus

DELETE 150,330

would delete all the lines with numbers between 150 and 330.

Single lines can be removed by typing in the line number and pressing RETURN.

REM is a very useful statement. It enables you to put remarks in your program to remind you (not the computer) what is going on. If you are developing a big program – or loading a simple program that you have not used for some time – it is

very easy to forget how it works or what it does. 'Normally people place several REMs at the start of a program to give general information and then put a REM at major points further down the program. See pages 232 or 264 for examples.

Once you have entered a program you will very often find that the line numbers are no longer in a neat sequence. As we have seen the command RENUMBER makes the computer go through the whole program changing all the line number so that they start at line 10 and increase by 10 for each successive line. Certainly, when you have finished a program it is a good idea to RENUMBER it so that it looks tidy. If you have a program in the computer try

RENUMBER

and then LIST the program to see the effect. After that try

RENUMBER 900,100

and you will see, when you list the program, that the computer has renumbered the whole program but the new variation has line numbers starting at 900 and this time increasing by steps of 100.

It is possible to put more than one statement on a line. For example, the two statements

CLS (clear the screen)

PRINT "HELLO"

can be put on one tine, so long as the individual statements are separated by colons, thus:

CLS : PRINT "HELLO"

You can put as many statements on a line as you like so long as the line has less than about 230 characters. The argument for using "multiple statement lines" is that it saves some memory space and may make the program work a little faster. But against that you will notice that it becomes much more difficult to follow the program when you list it (see page 98).

8 Introducing graphics

Modes, Colours, Graphics and Windows

The Model A BBC computer can display text and graphics in four different modes; the Model B can show eight different modes. Only one mode can be used at a time. The Teletext Mode (MODE 7) differs from all the other modes in many ways and a whole chapter has been devoted to that mode (see page 150). In particular it is not easy to draw lines or triangles in MODE 7 and the colour of the text is changed in a special way. Finally some characters are displayed on the screen differently in this mode – for example the character [ is displayed as ?.

On the Model A there are two modes in which graphics can be used (MODE 4 and MODE 5). With a Model B five graphics modes are available. The description which follows will assume that you are in MODE 5. To reach it, simple type MODE 5 and press RETURN. Note that pressing BREAK will return you to MODE 7 so avoid using BREAK - the "panic button" is marked ESCAPE. If you press this the computer will stop what it is doing and return control to you. MODE 5 is a four colour mode which means that up to four different colours can be shown on the screen at any time. When you enter MODE 5 two "colours" are displayed – white letters on a black background. As you will be aware from earlier chapters the colour of the text can be changed with the COLOUR statement, and since this is a four colour mode you can select from

COLOUR 0 black

COLOUR 1 red

COLOUR 2 yellow

COLOUR 3 white

The same four colours (black, red, yellow and white) may be selected for the background with the commands

COLOUR 128 (128+0) black

COLOUR 129 (128+1) red

COLOUR 130 (128+2) yellow

COLOUR 131 (128+3) white

The COLOUR statement can be used to change the colour of the text foreground and background – but not the colour of any graphics: for that you need to use another caste keywords –

GCOL, which stands for Graphics COLour.

Graphics

For the graphics: when drawing lines and triangles, positions on the screen are given with two numbers (the x and y co-ordinates).

The point A has co-ordinates 600 across, 0 up

The point B is at position 100,500 and C is at 800,%0

The statement

DRAW 800, 800

will draw a line from the last point 'visited' to 800,800. If no point has been visited, the computer will assume that it starts from the point 0,0.

To move without drawing a line use the command MOVE. So to draw a line from 1000,0 to 1000,1000 type

MOVE 1000,0

DRAW 1000,1000

DRAW 100,500 will draw another line, and so on. As well as MOVE and DRAW there are PLOT commands for other effects.

These are described in a later chapter. The statement GCOL is used to change the graphics colour used by the DRAW statement. GCOL is followed by two numbers, the first is normally zero and the second determines the graphics colours e.g.

GCOL 0,0 black lines

GCOL 0,1 red lines

GCOL 0,2 yellow lines

GCOL 0,3 white lines

We’ll consider what happens when the first number is not zero later on (page 167).

As with the text colours, one can change both foreground and background colours. However, before that can be illustrated it will be easier to set up two 'windows’ on the screen – one for text and one for graphics so that you can be quite clear which is which. We will then return to the GCOL statement.

Windows

At the moment the whole screen can be used for text and the whole screen can be used for graphics. In some modes (eg MODE 5) we can restrict each to a specific "window" – or section of the screen. In modes without graphics (MODES 3, 6 and 7) only text windows can be used. Imagine we want to create two windows as shown below – on the left a graphics window; on the right a text window. Suppose that the text window stretches from the top of the screen right to the bottom but the graphics window stops short of the bottom:

a Making a graphics window

Imagine a graphics window which has its edges a, b, c and d 'graphics units’ away from the bottom left hand corner of the screen (which is always the starting point for graphics).

The statement VDU 24 is used (with some numbers after it) to set up a graphics window (VDU stands for Visual Display Unit). For the window shown above the full statement is

VDU 24,a;b;c;d;

Note: the comma after 24 and the semi colon after all the other values. The reason for this punctuation is given on page 386. So for our actual graphics window we would put

VDU 24, 0;100;300;1000;

In all screen modes which can support easily defined graphics the range of values for a, b, c and d is always the same; 0-1023 vertically, 0-1279 horizontally.

b Making a text window

Unlike graphics, text ‘starts’ at the top left hand corner of the

screen, so text windows are defined using that point as zero.

Imagine the text window has edges a, b, c and d ‘text units’ away from the top left of the screen, as shown:

The statement VDU 28 is used to setup the window as follows

VDU 28,a,b,c,d

Note: the comma after the 28 and between the other values. There is no comma at the end.

For the text window we wanted to set up, the statement would be

VDU 28,5,31,19,0

To prove that we now have two separate windows try

COLOUR 129

CLS

to fill the text window with red and

GCOL 0,130

CLG

to fill the graphics window with yellow.

Note: In the various different screen modes the number of text characters which can be accommodated along the screen and down the screen is also different. This affects the range of values for the horizontal distances a and c as follows:

MODES 0 and 3 (which support 80 characters to the line) 0 to 79

MODES 1, 4, 6 and 7 (which support 40 characters to the line.)

0 to 39

MODES 2 and 5 (which support 20 characters to the line) 0 to 19

Similarly the values of b and d depend on the mode.

MODES 0,1,2,4 and 5 have 32 lines (0 to 31)

MODES 3,6 and 7 have 25 lines (0 to 24)

To recap, to set up the windows press BREAK then type the following – with RETURN at the end of each line. You are working in command mode rather than writing a program, so the computer acts on each instruction as you press RETURN. It also means that pressing BREAK in the middle of what follows would destroy the text and graphics windows and send the computer back to MODE 7.

MODE 5

VDU 24,0;100;300;1000;

VDU 28,5,31,19,0

CLS

The command CLS clears the text from the screen. Now try typing the following lines

DRAW 0,1000

DRAW 100,1000

DRAW 0,0

DRAW 1000,1000

You will find that text is now only appearing in the text window and that graphics are only appearing in the graphics window. If you want to clear the text only, type CLS. It you want to clear the graphics only, type CLG. (Normally CLS clears the whole screen, but where independent text and graphics areas are defined, CLS only clears the text.) You will also notice that although some of the commands have told the computer to draw in areas of the screen outside the graphics window it has not done so visibly.

Windows may overlap – in fact when you change MODE both the text and graphic windows fill the whole screen, and you can move windows without destroying what is on the screen, although changing story does clear the screen. To reset both text and graphics windows to the whole screen, e.g, in the middle of a program, use VDU 26.

VDU 5 enables text to be drawn at any position inside a graphics window – see pages 49, 74 and 379.

Changing the colours of text and graphics

Now back to text and graphic colours. Let us define the text background to be red and the graphics background to be yellow.

COLOUR 129 red text background

GCOL 0,130 yellow graphics background,

and then clear the text and graphics areas to their background colours.

CLS clear text area

CLG clear graphics area

Now to select the foreground colours for the two areas – for example to obtain yellow letters (text foreground) type

COLOUR 2 and to get black graphics lines type

GCOL 0,0

Test this out by typing

DRAW 150,500

Although you start up (in MODE 5) with the four colours set to black, red, yellow and white, you can select other colours (still of course only 4 at a time) by using VDU 19, as we saw on page 10. See page 382 for mare details of VDU 19.

So far we have been working in command mode. Next try typing in this program. You can use MODE 7 to type the program in but nothing will happen until you run the program. So, press BREAK and then the following

10 MODE 5

20 VDU 24, 0; 0; 500; 1000;

30 VDU 28,10,20,19,5

40 COLOUR 129

50 COLOUR 2

60 GCOL 0,130

70 CLS : CLG

80 FOR N=1 TO 1000

90 PRINT "LINE"; N

100 GCOL 0, RND (4)

110 DRAW RND(500), RND(1000)

120 NEXT N

RUN

You might like to try saving this program on cassette as described in section 5.

9 More on variables

In an earlier section the idea of ‘variables’ was introduced. Variables are a fundamental concept in computing, and it is not possible to go far without understanding them.

As we have seen, it is possible try say

LET X=12

or just

X=12

and the computer knows that it must label a ‘box’ in its memory with the name X and that the current value of X is l2. With a variable it is possible to alter the value of what is in the 'box’ but not the name of the 'box’ itself. The statement

X=14

simply changes the value of X from 12 to 14. Similarly we can say

X=X+1

which looks rather odd – like an equation which does not balance. In fact all that this is redoing is saying to the computer – whatever the value inside your box 'X’, make it increase by 1 from now on.

So far we have considered only 'numeric’ variables – that is, variables which contain numbers and on which arithmetic can be carried out. But the computer has letters and .symbols of various kinds on its keyboard – what about them?

Numbers and characters

Although we can talk of the ‘number’ 22, we can also consider 22 as a pair of characters – in the same way as A, B, C, ?, $ are characters. In computing it is important to be able to distinguish between numbers and characters. Arithmetic can be carried out on numbers but not on characters. To give you

an example to show that this is not such an esoteric idea, consider 22. We can divide 22 by 2 and get 11 if 22 is taken to be a ‘number’. But if we talked about a train leaving 'Platform 22’, the 22 here would be a pair of characters. You cannot, with a great deal of meaning„divide Platform 22’ by 2 and get 'Platform 11’.

Next it's important to have a look at the other major kind of variable used in computing – one which can hold characters, not numbers. This is called a ‘string’ variable.

String variables

String variables are used to store "strings of character" e.g. words. They can be recognised easily because they always end with a dollar sign. Here are a few examples of string variables containing various strings of characters. Note that these strings mist be enclosed by quotation marks.

X$="HELLO"

DAY$= "SUNDAY 3RD JANUARY"

NAME$="ALEX"

In the first example X$ is called a string variable and HELLO is called a string. Once X$ has been set to contain HELLO we can use statements like

PRINT X$

in just the same way as we said on page 24.

Z=5

PRINT Z

String variables can be used to hold any number of characters between zero (empty) and 255 (full)

X$="" will empty X$

X$="A" will set X$ to contain 1 character

Of course you cannot use ordinary arithmetic on string variables. For example

NAME$="SUSAN"

PRINT NAME$ / 10

does not make sense. You can’t divide Susan's name into 10 parts. Whilst you can add, subtract, multiply and divide using

numeric variables the only similar operation that can be carried out on a string variables is that of "addition". Thus

10 A$ = "TODAY IS"

20 B$ = "SUNDAY"

30 C$ = A$+B$

40 PRINT C$

>RUN

TODAY IS SUNDAY

The importance of understanding string variables cannot be over-emphasized. Later sections develop the idea.

How numbers and letters are stored in the computer's memory

Each memory location in the computer can be used to store any number between, and including, 0 and 255, and yet some way has to he found to store letters and also very large numbers. A number of codes are used in the computer in much the same way that different groups of people have used different codes to count. Thus the number 1982 can also he written as

MCMLXXXII in Roman numerals

or 1982 in decimal Arabic numerals

or 7BE in hexadecimal Arabic

or 11110111110 in binary.

The need to transmit and store letters has produced another set of codes. The letter "J" is coded in various ways thus

.--- in Morse

1001010 in ASCII binary

4A in ASCII hexadecimal

74 in ASCII decimal.

The ASCII (American Standard Code for Information Interchange), is by far the most common code used by computers to represent characters. A complete code table is given on page 490.

When you tell the computer

A$ = "HELLO"

it stores the ASCII codes for the letters in the word HELLO in successive memory locations. The fact that they are stored as

ASCII codes is really irrelevant – as far as the user is concerned, it just works. However, there are times when the user needs to know about the ASCII codes and two functions are provided to convert between "characters" and ASCII codes.

The function ASC converts a character into its ASCII code. Thus

PRINT ASC("J")

would print 74.

The reverse function, of converting an ASCII code into a character, is performed by CHR$.

Thus PRINT CHR$(74) would print the letter J. In fact, one quite often needs to use PRINT CHR$, so there is a further shortened version of that statement. It is VDU. So VDU 74 would also print the letter J.

Those doing more complicated programming will need to know the exact way that the computer stores strings and numerics in memory. Full information is given at the end of section 39.

Real and Integer Variables

The numeric variables you have met so far are technically known as "real variables". They can be used to store any number between

200 000 000 000 000 000 000 000 000 000 000 000 000 (2 x 10³⁸) and 0.000 000 000 000 000 000 000 000 000 000 000 000 002 (2 x 10^-39), and can include a decimal point. Of course a similar range of negative numbers can be stored too. The problem with real numbers is that they are only stored to 9 figure accuracy, nonetheless this is quite accurate enough for most purposes. Another type of numeric variable is an 'integer' variable.

Integer variable names are distinguished by having a percent sign as the last character of the variable name. They can only store whole numbers between – 2,147,483,648 and

2, 147,483, 647.

On the other hand integer variables are held with complete accuracy – so accounting problems can be dealt with to the nearest penny in £2M. Arithmetic calculations with integer variables are significantly faster than with real variables. (See section 32 further suggestions for speeding up programs).

The two integer operators MOD and DIV are described on page 130

The variables A% to Z% are special in that they are permanently allocated space in memory. Typing RUN or NEW does not destroy them. As a result the variables A% to Z% can be set in one program and then used in another program later on without losing their values. Of course the values will be lost if the machine is switched off but otherwise they will remain, even if BREAK is pressed. The WELCOME cassette uses the variable M%, to inform each of the individual programs whether or not the user’s cassette recorder has got automatic motor control.

The variables A% to Z% are called the Resident Integer Variables.

Summary

Three main types of variables are supported in this version of BASIC: they are Integer, real and string.

All variable names can contain as many characters as required and all characters are used to identify the variable. Variable names may contain capital letters, lower case letters and numbers and the underline character. Variable names must start with a letter and must not start with a BASIC keyword.

10 PRINT formatting and cursor control

This section describes the PRINT statement which is used to put text on the screen or to a printer. It assumes that you understand that a variable (such as X) can be used to hold a number and that a string variable (such as A$) can be used to hold a line of text.

The following program will help to illustrate some of the ideas. Press BREAK and then type in the following program.

10 X=8

20 A$="HELLO"

30 PRINT X, X, X

When this is run it produces this:

>RUN

8 8 8

This shows that commas separating items in the print list (the print list is the list of things to be printed – X,X,X in this case) will force items to be printed in columns or ‘fields’ ten characters wide. Numbers are printed at the right hand side of each column whereas words are printed on the left hand side. You can see the difference if we add some lines to the program.

10 X=8

20 A$="HELLO"

30 PRINT X,X/2,X/4

40 PRINT AS,A$,A$

>RUN

8 4 2

HELLO HELLO HELLO

? field ?

width

Field widths in different screen modes

As we said above, the width of each ‘field' is automatically set to ten characters when the computer is switched on.

Since the computer can operate in different screen modes, displaying either 20 or 40 or 80 characters to the line, clearly the number of fields which can be displayed on the screen will differ depending on the mode. So try typing in a new line and re running the program above.

5 MODE 5

or, if you have a MODEL B machine

5 MODE 0

Note: the widths of the fields can be altered by the use of a special command @% (see page 70).

So commas between items in the print list always put things in columns or ‘fields'. On the other hand semi-colons between items in the print list cause items to be printed next to each other, without spaces:

10 X=8

20 A$="HELLO"

30 PRINT A$; X; A$; X; X

>RUN

HELLO8HELLO88

Of course if the first item is a number it will be printed to the right of a ‘field' unless it is preceded by a semi colon.

10 X=8

20 A$="HELLO"

30 PRINT X; A$; A$

>RUN

8HELLOHELLO

or

10 X=8

20 A$="HELLO"

30 PRINT ;X;A$;A$

>RUN

8HELLOHELLO

As well as printing variables and string variables as shown above the computer can print any characters placed in between pairs of inverted commas exactly as they have been typed in, providing they are in a print statement. The next program asks for your name and remembers it in the string variable N$.

10 PRINT "WHAT IS YOUR NAME ";

20 INPUT N$

30 PRINT "HELLO ";N$;". HOW ARE YOU?"

>RUN

WHAT IS YOUR NAME ?JOHN

HELLO JOHN. HOW ARE YOU?

Notice the semi-colon at the end of line 10 that makes the computer stay on the same line while it waits for you to provide it with a value for N$. Without the semi-colon this happens:

>RUN

WHAT IS YOUR NAME

?JOHN

HELLO JOHN. HOW ARE YOU?

Note also the space after the word HELLO and before the word HOW in line 30. Without these spaces the words run together to produce.

HELLOJOHN.HOW ARE YOU?

It is quite legitimate to do calculations in a print list – for example

10 X=4.5

20 PRINT X,X+2,X/3,X*X

>RUN

>

4.5 6.5 1.5 20.25

but look what happens if instead of X = 4.5 we put X = 7

10 X=7

20 PRINT X,X+2,X/3,X*X

>RUN

7 92.33333333 49

because x/3 is 2.33333333 it makes the number move left in the field until it immediately follows the previous field which contains a 9 and appears to give a result 92.33333333, which is misleading. For this reason, amongst others, the next section is important if you want to print out a lot of numbers.

Altering the width of the field and the way in which numbers are printed

It is often useful to be able to specify the width of the field when printing columns of figures or words and also to be able to specify the number of decimal places to which numbers will be printed.

On the BBC Microcomputer this can be done by setting a special 'variable' (called @%) in a particular way. For the moment this must be treated as a bit of ‘magic' but, for example, if we write

@%=&20209

then this statement tells the computer to print in a field 9 characters wide, and that numbers will be printed with a fixed number of decimal places – in this case, to 2 decimal places. The following program shows this being used:

5 @%=820209

10 X=7

20 PRINT X,X+2,X/3,X*X

>RUN

7.00 9.00 2.33 49.00

For the more technically minded

@% is made up of a number of parts

@%=&20309 would give Format 2, 3 decimal places and field width of 9 characters.

5 @%=&20309

10 X=7

20 PRINT X,X+2,X/3,X*X

>RUN

7.000 9.000 2.333 49.000

If you want 4 decimal places and a field width of 12 you would put the following

5 @%=&2040C

10 X=7

20 PRINT X,X+2,X/3,X*X

>RUN

7.0000 9.0000 2.3333 49.0000

The & tells the computer that the numbers which follow are 'hexadecimal’ numbers – that is, numbers based not on 10s but on 16s. For the sake of completeness, here is a list of hexadecimal numbers (which include the letters A to F)

A few points:

1. The maximum number of significant figures is 9

2. Format 1 gives Figures as exponential values

Format 2 gives figures to a fixed number of decimal places

Format 0 is the 'normal' configuration

1. To set the print format back to its normal value (Format 0 and field width 10), set @% =10

TAB(X)

As well as controlling the print layout by using the comma and semi-colon one can use the TAB statement to start printing at a particular place on the screen. You will remember that there can be 20,40 or 80 characters to the line depending on the MODE. MODE 7 has 40 characters. Try this:

10 PRINT "012345678901234567890"

20 F=16

30 REPEAT

40 PRINT TAB(10);F;TAB(15);2*F

50 F=F+1

60 UNTIL F=18

>

>RUN

012345678901234567890

16. 32

17. 34

TAB(10) prints the value of F ten spaces from the left and then TAB(15) prints the value of 2*F fifteen spaces from the left, on the same line. Note the semi-colon after TAB(10) – this causes the computer to begin printing at that point.

Be sure to place an open bracket immediately after the word TAB. If you leave a space between them, thus: TAB (10) the computer will not understand and will report

No such variable.

If you are beyond the place that you tell the computer to TAB to, for example in position 15 with a request to TAB(10), then the computer moves to the next line and then tabs ten spaces.

Type in this replacement line

40PRINT TAB(15);F;TAB(10);2*F

>RUN

012345678901234567890

16

32

17

34

TAB(X,Y)

A useful extension of the TAB statement allows print to be placed at any specific character location anywhere on the screen. You will remember that in MODE 7 the text co-ordinates are

This program counts to 1000, printing as it goes

5 CLS

10 Q=1

Z0 REPEAT

30 PRINT TAB(18,5);Q

40 Q=Q+1

50 UNTIL Q=1000

The two numbers in the brackets after TAB represent the X and Y text co-ordinates where printing should start (see also the program on page 132).

Advanced print positioning

Using PRINT TAB(X,Y) allows text etc to be printed in any character 'cell' in the appropriate MODE. In MODE 5 there are 20 cells across the screen and 32 cells (lines) down the

screen. Sometimes it is useful to be able to position characters on a much finer grid. The statement VDU 5 enables text to be printed at the exact position of the graphics cursor. The statement MOVE can be used to position text. Note that this will not work in MODE 7. You will remember that the graphics screen is addressed thus

in all modes except MODE 7.

A few sums will show that each character cell is 32 graphic units high and, in a 40 character mode such as MODE 4, 32 units wide. Suppose we want to subscript a letter to produce for example the chemical formula H₂ this can he done as follows

10 MODE 4

20 VDU 5

30 MOVE 500,500

40 PRINT "H"

50 MOVE 532,484

60 PRINT "2"

70 VDU 4

Note that the letter H is positioned with its top left corner at 500,500. The 2 is then printed one character to the right (532) and half a character down (484). Again the top left of 2 is at 532,484.

A neater way of achieving the same effect is to replace line 50 with

PLOT 0,0,–16

One further feature of the BBC computer which is not normally available on "personal" computers is the ability to superimpose

characters. One obvious use of this facility is to generate special effects such as accents and true underlining. The short program below prints the word role with the accent correctly placed.

10 MODE 4

20 VDU 5

30 X=500

40 Y=500

50 MOVE X,Y

60 PRINT "role"

70 MOVE X+32,Y+16

80 PRINT"^"

90 VDU 4

Once in VDU 5 mode the screen will not scroll up if you reach the bottom of the page, instead the writing will start from the top of the screen again. In addition characters will be superimposed on those already on the screen. When in VDU 5 mode you can only print things in the graphics window and not in the text window, and colour is selected with the GCOL statement. VDU 5 will not work in text-only modes such as MODES 3, 6 and 7.

Cursor control

The text cursor is the flashing line on the screen which shows where text will appear if it is typed in on the keyboard. The text cursor also indicates where text will he printed on the screen by a PRINT statement. The cursor can be moved around the screen by a number of special "control codes" amongst which are

code effect

8 move cursor left

9 move cursor right

10 move cursor down

11 move cursor up

These code numbers can be used either with the VDU command e.g. to move left four spaces, use either

VDU 8,8,8,8

or

PRINT CHR$(8);CHR$(8);CHR$(8);CHR$(8)

clearly the VDU command is simpler to type in in most cases.

In addition to the codes shown above the user can use the PRINT TAB(X,Y) statement to move the cursor directly to any character position on the screen. As we’ve seen in MODE 7 the screen can contain up to 25 lines (numbered 0 to 24) of up to 40 characters per line.

The position marked on the diagram above is 18 positions across and 6 lines down. The cursor could be moved directly there with the statement

PRINT TAB(18,6);

Note that the opening bracket must immediately follow the word TAB thus TAB( and not TAB (.

Exactly the same effect can be obtained with the statement

VDU 31,18,6

The cursor can be moved to the "home" position at the top left of the screen with the statement

VDU 30

If the user wishes to clear the screen as well as move the cursor to the home position then he or she can use the statement

VDU 12

The last of the VDU commands directly to do with cursor control is

VDU 127 which moves the cursor left and deletes the character there. If you wish to delete the next four characters

and then return the cursor to its initial place you could use

VDU 9,9,9,9,127,127,127,127

Cursor ON/OFF

In some applications the flashing cursor can be a distraction. It can be turned off with the statement

VDU 23;8202;0;0;0;

and can be turned back on with the MODE statement

Note; In version 1.0 of the operating system

VDU 23,1,0;0;0;0; will turn the cursor off

VDU 23,1,1;0;0;0; will turn the cursor back on

11 Input

The previous section showed how to get information out of the computer and on to the screen. This section deals with getting things from the keyboard into the computer. When a program is running there will often be a need for it to request some information from the person at the keyboard.

10 PRINT "HOW OLD ARE YOU"

20 INPUT AGE

30 IF AGE<18 THEN PRINT "YOU ARE TOO YOUNG AT ";

40 IF AGE=18 THEN PRINT "CONGRATULATIONS ON BEING

50 IF AGE >18 THEN PRINT "YOU ARE PAST IT IF YOU ARE ";

70 PRINT ;AGE

>RUN

HOW OLD ARE YOU

?22

YOU ARE PAST IT IF YOU ARE 22

Line 20 of the above program prints a question mark on the screen and then takes in everything that is typed on the keyboard until RETURN is pressed. Line 20 says INPUT AGE so the computer is expecting a number since AGE is a numeric variable rather than a string variable (see section 9). If words are supplied instead of numbers then the computer assumes that the number is zero.

>RUN

HOW OLD ARE YOU

?I DON'T KNOW

YOU ARE TOO YOUNG AT 0

Because line 20 said INPUT AGE a number was expected. If you want to INPUT a string (word or group of words) then you must place a string variable (e.g. NAME$) on the input line.

10 PRINT "WHAT IS YOUR NAME"

20 INPUT NAME$

30 PRINT "HELLO ";NAME$;" HOW ARE YOU?"

>RUN

WHAT IS YOUR NAME

?JOHN

HELLO JOHN HOW ARE YOU?

You must follow the word INPUT with a numeric variable if you are expecting a number and with a string variable if you are expecting a string.

As you will have seen from the examples above you usually need to print a question on the screen to tell the person at the keyboard what you are waiting for. In the last example the question was "What is your name". Instead of placing this in a separate PRINT statement you can include the question on the INPUT statement.

20 INPUT "WHAT IS YOUR NAME ",NAME$

30 PRINT "HELLO ";NAME$;" NOW ARE YOU?"

>RUN

WHAT IS YOUR NAME ?SUSAN

HELLO SUSAN HOW ARE YOU?

Notice the punctuation between the question "What is your name" and the string variable NAME$. It is a comma. Notice also that the computer printed a question mark after the question when the program was run. It always prints a question mark on an INPUT statement if a comma is used to separate the question from the string variable. If you leave the comma out of the program the computer will leave the question mark out when the program is RUN.

20 INPUT "WHAT IS YOUR NAME " NAME$

30 PRINT "HELLO ";NAME$;" HOW ARE YOU?"

>RUN

WHAT IS YOUR NAME STEPHEN ALLEN

HELLO STEPHEN ALLEN HOW ARE YOU?

The INPUT statement, which we have explored above, requires that the user presses the RETURN key after he or she has entered the reply. Until the RETURN key is pressed the user can delete errors with the DELETE key or delete the whole entry so far with CTRL U.

Several inputs can be requested at one time. If you type

10 INPUT A,B

20 PRINT A,B

two numbers will be expected by the computer. They can either be typed in separated by commas, or both can be followed by RETURN.

The INPUT statement will ignore leading spaces and anything after a comma unless the reply is inside quotation marks.

10 INPUT A$

20 PRINT A$

>RUN

?ABC,DEF

ABC

The INPUT LINE statement can be used in the same way as INPUT, but it will accept everything that is typed, including leading spaces and commas. Replace line 10 by

10 INPUT LINE A$

>RUN

?ABC,DEF

ABC,DEF

Of course if you make the program

10 INPUT A$,B$

20 PRINT A$,B$

you will get

>RUN

"ABC,DEF

ABC DEF

because now two different inputs are needed in line 10

12 GET, INKEY

Sometimes it is useful to be able to detect a key as soon as it is pressed without having to wait for the RETURN key to be pressed. For example most games react immediately a key is pressed. There are a group of four functions which respond to single keystrokes:

GET

GET$

INKEY

INKEY$

The GET and GET$ functions wait until a key is pressed whereas the INKEY and INKEY$ pair give up after a while if no key is pressed.

100 A$ = GET$

will wait (for ever) until a key is pressed whereas

100 A$=INKEY$(200)

will wait for only 2 seconds (200 hundredths of a second). If no key is pressed within 2 seconds then the computer will move on to the next line of the program and A$ will be empty. If a key was pressed after say one second then the computer will immediately move on to the next line of the program and will put the "character typed" into A$.

100 PRINT "DO YOU WANT TO GO ON"

110 PRINT "YOU HAVE 2 SECONDS To REPLY"

120 A$=INKEY$(200)

130 IF A$="" THEN PRINT "TOO LATE YOU MISSED IT"

140 IF A$="Y" THEN PRINT "COURAGEOUS FOOL!"

150 IF A$="N" THEN PRINT "COWARD"

One of the most common uses of GET$ is to wait at the bottom of a page for a person to press any key when they are ready to go on

100 A$=GET$

GET and INKEY are very similar to GET$ and INKEY$ but instead of returning a character which can be put into a string variable they return a number which is the ASCII code of the character. The ASCII code of "Y" is 89 and the ASCII code of "N" is 78, so the last program could be re-written as

100 PRINT "DO YOU WANT TO GO ON"

110 PRINT "YOU HAVE 2 SECONDS TO REPLY"

120 A=INKEY(200)

130 IF A=– 1 THEN PRINT "TOO LATE YOU MISSED IT"

140 IF A=89 THEN PRINT "COURAGEOUS FOOL!"

150 IF A=78 THEN PRINT "COWARD"

You will see that "no reply" returns the value –1 when using INKEY and returns an empty string when using INKEY$.

Advanced features

Another important use of INKEY and GET is with the group of four direction keys at the top of the keyboard. Normally these are used for editing but a special statement can make these keys produce ASCII codes like all the other keys on the keyboard. They can then be used by a program for some special purpose – for example to move a point around the screen. The statement *FX 4,1 makes the editing keys produce ASCII codes and the statement *FX 4,0 returns the keys to their editing function. The keys produce the following codes

COPY 135 or (&87)

¬ 136 or (&88)

® 137 or (&89)

¯ 138 or (&8A)

­ 139 or (&8B)

For example:

10 *FX 4,1

20 MODE 4

30 X=500

40 Y=500

50 REPEAT

60 PLOT 69,X,Y

70 K=GET

80 IF K=136 THEN X=X-4

90 IF K=137 THEN X=X+4

100 IF K=138 THEN Y=Y-4

110 IF K=139 THEN Y=Y+4

120 UNTIL Y=0

130 *FX 4,0

This program waits at line 70 for a key to be pressed. The program shown above would often be part of a much larger program in which case one would not want everything to stop until a key is pressed. Here it would be better to use

K=INKEY(0) at line 70 which will let the computer have a quick look to see if a key has been pressed but not wait at all.

10 *FX 4, 1

20 MODE 4

30 X=500

40 Y=500

50 REPEAT

60 PLOT 69,X,Y

70 K=INKEY(0)

80 IF K=136 THEN X=X-4

90 IF K=137 THEN X=X+4

100 IF K=138 THEN Y=Y-4

110 IF K=139 THEN Y=Y+4

120 UNTIL Y=0

130 *FX 4,0

13 TIME, RND

TIME

The BBC computer contains an 'elapsed time’ clock. That means that the clock ticks away at a hundred ticks per second but it does not know the real time. However, you can set it and read it. Once set it will stay running until you turn the power off or you do a 'hard reset’ (see page 142). It can be set to any value, for example 0,

TIME = 0

This program will print a running stopwatch in the middle of the screen:

5 CLS

10 T = TIME

20 PRINT TAB(10,12);(TIME-7)/100;

30 GOTO 20

There is a program to print a 24 hour clock on page 131.

RND

When writing games (and simulations), we very often want the computer to make a random choice – or to pick a random number. The most useful function for this is RND(X) which picks a random number between 1 and X. The program below prints out a new random number between 1 and 6 every time a key is pressed: rather like throwing a dice.

10 PRINT RND(6)

20 G=GET

30 GOTO 10

and this program draws random triangles in random colours

10 MODES

20 PLOT 85,RND(1200),RND(1000)

30 GCOL 0,RND(3)

40 GOTO 20

Sometimes it is useful to be able to re-set the random number generator to a known value. That may sound a bit strange but when testing a program it is sometimes convenient to have a predictable set of "random numbers"! To do this the number in brackets after the RND must be a negative number. Thus X=RND(-8) will ensure that the number sequence resulting from RND(6) is repeatable.

Structure within BASIC

When building a house there are a number of options: one can chop trees down and tie them together to form a hut, one could use straw and mud if one had the skill to deal with those materials or one can use 'building, blocks’ like windows, doors and bricks. Whichever materials one selects the planning and construction is made much easier if one has a clear understanding of the available structures.

The same type of argument applies when writing a computer program to solve a particular problem. A number of program structures are available and it is well worth while learning what each can do. If you are attempting a trivial job (making an orange box or adding up a set of numbers) then little or no planning is needed. On the other hand, building an extension to your house or writing a computer program to play a game does require planning if it is not going to 'crash’ without warning. This planning will involve the use of a number of ‘structures’.

Here are the main structures available on the BBC computer.

REPEAT...UNTIL

FOR...NEXT

IF...THEN...ELSE

PROCEDURES

FUNCTIONS

GOSUB

ON...GOTO

ON...GOSUB

14 REPEAT, UNTIL, TRUE, FALSE

Computers are fundamentally pretty stupid things but their power comes from their ability to repeat things many times – sometimes many millions of times in one second. In this version of BASIC two types of repeating loops can be used. They are called REPEAT...UNTIL and FOR...NEXT loops. This section explains REPEAT...UNTIL loops and the next chapter deals with FOR...NEXT loops.

Do you remember the story about a man starting with one grain of rice and doubling it each time he won a bet? How many times would he have to double his grains of rice to own more than a million grains? In the following program C is a counter showing how many times the number of grains has doubled and X represents the number of grains of rice.

10 X=1

20 C=0

30 REPEAT

40 X=X*2

50 C=C+1

60 UNTIL X>1000000

70 PRINT C,X

>RUN

20 1048576

Lines 30 to 60 are called a REPEAT...UNTIL loop and everything within the loop is repeated until X is greater than one million.

The "terminating condition" in this program is that X is greater than 1000000.

The next program terminates after 15 seconds. Line 40 reads the starting time and the program repeats until the present

time minus the starting time is greater than 1500 hundredth of a second – the internal clock ticks a hundred times a second.

10 PRINT "SEE HOW MANY SUMS YOU"

20 PRINT "CAN DO IN 15 SECONDS"

30 PRINT

40 STARTTIME=TIME

50 REPEAT

60 F=RND(12)

70 G=RND(12)

80 PRINT "WHAT IS ";F;" TIMES "G;

90 INPUT H

100 IF H=F*G THEN PRINT "CORRECT" ELSE PRINT "WRONG"

110 PRINT

120 UNTIL TIME-STARTTIME>1500

130 PRINT "TIME UP"

RUN

SEE HOW MANY SUMS YOU

CAN DO IN 15 SECONDS

WHAT IS 6 TIMES 9?72

WRONG

WHAT IS 1 TIMES 4?4

CORRECT

WHAT IS 9 TIMES 8?72

CORRECT

TIME UP

REPEAT. . .UNTIL loops are very useful and should be used frequently. The next program selects random letters (line 20) and times how long it takes you to find and press the appropriate key. It uses two REPEAT . . .UNTIL loops. One of them is used to wait for a particular key to be pressed on the keyboard.

10 REPEAT

20 Z=RND(26)+64

30 PRINT

40 PRINT "PRESS THE KEY MARKED ";CHR$(Z)

50 T=TIME

60 REPEAT UNTIL GET=2

70 PRINT "THAT TOOK YOU"(TIME-T)/100" SECONDS"

80 UNTIL Z=0

>RUN

PRESS THE KEY MARKED Y

THAT TOOK YOU 1.1 SECONDS

PRESS THE KEY MARKED G

THAT TOOK YOU 1.03 SECONDS

Lines 10 and 80 are the main loop and line 60 is a single line REPEAT...UNTIL loop.

Look at line 80. This will stop the REPEAT...UNTIL loop if Z=0. However Z is calculated in line 20 and will have a value between 65 and 90. It will never equal zero, so the program will never stop of its own accord – you have to press the ESCAPE key.

Line 80 says

80 UNTIL Z=0

Z = 0 will never be "true". Z = 0 will always be "false", so line 80 can be replaced with

80 UNTIL FALSE

which just means "go on for ever". This is a far better way of doing things than using Z=0 because you might decide to change Z next time you looked at the program. It is also better to use REPEAT...UNTIL loops in this way than to put at line 80

80 GOTO 20

Using REPEAT...UNTIL keeps this section of the program

neatly together. See page 117 for a comment on GOTO.

If you delete line 10, then the computer will meet an UNTIL statement at line 80 with no idea of where the loop is meant to start

>RUN

PRESS THE KEY MARKED A

THAT TOOK YOU 2.09 SECONDS

No REPEAT at line 80

In summary REPEAT...UNTIL should be used for loops which must terminate on some specific condition.

15 FOR... NEXT

This structure makes the computer repeat a number of statements a fixed number of times. Try the following

10 FOR X=8 TO 20

20 PRINT X, X+X

30 NEXT X

>RUN

8 16

9 18

10 20

11 22

12 24

13 26

14 28

15 30

16 32

17 34

18 36

19 38

20 40

You can see that the computer looped through line 20 with X taking on the value 8, then 9, then 10 etc up to 20. Each time around, the loop X increased by 1. The "step size" can be changed easily.

10 FOR X= 8 TO 20 STEP 2.5

20 PRINT X, X+X

30 NEXT X

>RUN

8 16

10.5 21

13 26

15.5 31

18 36

In the two previous examples the value of X (which is called the "control variable") increased each time around the loop. The "control variable" can be made to decrease by using a negative step size.

10 FOR S= 100 TO 90 STEP –1

20 PRINT S,S/2, S/5

30 NEXT

>RUN

100 50 20

99 49.5 19.8

98 49 19.6

97 48.5 19.4

96 48 19.2

95 47.5 19

94 47 18.8

93 46.5 18.6

92 46 18.4

91 45.5 18.2

90 45 18

Here is a program which uses several FOR...NEXT loops. Some are 'nested' within each other in the way that one

REPEAT...UNTIL loop was included within another.

10 FOR ROW = 1 TO 6

20 FOR STAR = 1 TO 10

30 PRINT"*";

40 NEXT STAR

50 FOR STRIPE = 1 TO 20

60 PRINT "=";

70 NEXT STRIPE

75 PRINT

80 NEXT ROW

100 FOR ROW = 1 TO 5

110 FOR STRIPE= 1 TO 30

120 PRINT"=";

130 NEXT STRIPE

140 PRINT

150 NEXT ROW

>RUN

**********====================

**********====================

**********====================

**********====================

**********====================

**********====================

==============================

==============================

==============================

==============================

==============================

The listing shown above is not very easy to follow – try typing

LISTO 7

and then re-listing the program.

>LISTO 7

>

>LIST

10 FOR ROW = 1 TO 6

20 FOR STAR = 1 TO 10

30 PRINT"*";

40 NEXT STAR

50 FOR STRIPE = 1 TO 20

60 PRINT "=";

70 NEXT STRIPE

80 PRINT

90 NEXT ROW

100 FOR ROW=1 TO 10

110 FOR STRIPE= 1 TO 30

120 PRINT"=";

130 NEXT STRIPE

140 PRINT

150 NEXT ROW

This causes each of the "nested" FOR...NEXT loops to be indented which can make it easier to follow.

Lines 20 to 40 print out 10 stars

Lines 50 to 70 print out 20 equal signs

and Lines 10 and 90 ensure that the above are repeated 6 times. Lines 100 to 150 print out 5 rows of 30 equal signs.

(With apologies to the USA for modifying their flag!)

A note on LISTO

LISTO stands for LIST Option and it is followed by a number in the range 0 to 7. Each number has a special effect and details are given on page 290. However, the two most useful values are 0 and 7.

LISTO 0 lists the program exactly as it is stored in memory

LISTO 1 lists the program with one space after each line number. Many programs in this book have been listed like this.

LISTO 7 lists the program with one space after the line number, and two extra spaces every time a FOR...NEXT loop or a REPEAT...UNTIL loop is detected.

If you are using the screen editor then make sure that you list the program with LISTO0 or else you will copy all those extra spaces into the line!

A few points to watch when using FOR...NEXT loops

1. The loop always executes at least once

10 FOR X= 20 TO 0

20 PRINT X

30 NEXT

>RUN

20

The loop finishes with the "control variable" larger than the terminating value. In the next two examples the terminating value is 10.

10 FOR Z= 0 TO 10 STEP 3

20 PRINT Z

30 NEXT

40 PRINT "OUT OF LOOP"

50 PRINT Z

>

>RUN

0

3

6

9

OUT OF LOOP

12

10 FOR Z= 0 TO 10 STEP 5

20 PRINT Z

30 NEXT

40 PRINT "OUT OF LOOP"

50 PRINT Z

>

>RUN

0

5

10

OUT OF LOOP

15

Note that it is not necessary to say NEXT Z in line 30: it is optional, though it could be argued that it is clearer to put the Z in.

1. You should NEVER jump out of a FOR...NEXT loop. It is well accepted that this is poor style. If you do this your programs will become extremely difficult to follow – there are always better alternatives usually involving the use of a procedure, or setting the control variable to a value greater than the terminating value for example.

10 FOR X= 0 TO 1000

15 PRINT

20 PRINT "TYPE IN A SMALL NUMBER"

30 PRINT "OR ENTER -1 TO STOP THE PROGRAM"

40 INPUT J

50 IF J=-1 THEN X= 2000

60 PRINT "12 TIMES ";J;" IS "; 12*J

70 NEXT X

>

>RUN

TYPE IN A SMALL NUMBER

OR ENTER -1 TO STOP THE PROGRAM

?32

12 TIMES 32 IS 384

TYPE IN A SMALL NUMBER

OR ENTER -1 TO STOP THE PROGRAM

?456

12 TIMES 456 IS 5472

TYPE IN A SMALL NUMBER

OR ENTER -1 TO STOP THE PROGRAM

?-1

12 TIMES -1 IS -12

The REPEAT...UNTIL loop provides a much better way of dealing with this sort of problem.

1. If you omit the FOR statement an error will be generated. First a correct program:

10 FOR X=1 TO 5

20 PRINT "HELLO"

30 NEXT

>RUN

HELLO

HELLO

HELLO

HELLO

HELLO

and then the program with line 10 deleted

20 PRINT "HELLO"

30 NEXT

>RUN

HELLO

No FOR at line 30

1. Every FOR statement should have a matching NEXT statement. This can be easily checked by using LISTO 7 (list option 7). If the FOR...NEXT loops are correctly nested then the END in line 50 will line up with the FOR in line 5.

5 FOR H= 1 TO 4

10 FOR X=1 TO 2

20 PRINT "HELLO" ,H,X

30 NEXT X

40 NEXT H

50 END

>LISTO 7

>LIST

5 FOR H= 1 TO 4

10 FOR X=1 TO 2

20 PRINT "HELLO", H,X

30 NEXT X

40 NEXT H

50 END

>RUN

HELLO 1 1

HELLO 1 2

HELLO 2 1

HELLO 2 2

HELLO 3 1

HELLO 3 2

HELLO 4 1

HELLO 4 2

If the NEXT X in line 30 is deleted the computer does its best to make sense of the program.

5 FOR H= 1 TO 4

10 FOR X=1 TO 2

20 PRINT "HELLO", H,X

40 NEXT H

50 END

>RUN

HELLO 1 1

HELLO 2 1

HELLO 3 1

HELLO 4 1

This is not the way to write programs! Mis-nested FOR...NEXT loops will cause problems.

1. In summary FOR...NEXT loops should be used when you wish to go around a loop a fixed number of times.

16 IF... THEN...ELSE More on TRUE and FALSE

The IF...THEN statement has been used in several of the programs earlier in this book – for example, in the program on page 88 which checked your multiplication. Line 100 was:

IF H=F*G THEN PRINT "CORRECT" ELSE PRINT "WRONG"

As you will realise, this type of statement enables the computer to make a choice as it is working its way through the program. The actual choice that it makes will depend on the value of H, F and G at the time. As a result, the same program can behave in quite different ways in different circumstances.

Multiple line statements

It was explained earlier (page 54) that you cm put more than one statement on a line and this can be particularly useful with the IF...THEN statement. Take, for example,

10 X=4 : Y=6: PRINT "HELLO"

20 PRINT X + Y: X=X+Y: PRINT X+Y

>RUN HELLO

10

16

which is just the same as

10 X=4

20 Y=6

30 PRINT "HELLO"

40 PRINT X+Y

50 X=X+Y

60 PRINT X+Y

This helps to understand how the computer treats multiple statement lines using the IF...THEN statement. In the first example which follows, K=6 and therefore the computer obeys everything after the word THEN until the word ELSE. Note that a colon only separates statements – the word ELSE must be found if you want the other course of action to follow.

10 K=6

20 IF K=6 THEN K=9: PRINT "K WAS 6" ELSE PRINT "K WAS NOT 6": PRINT "END OF LINE"

>RUN

K WAS 6

(Note that line 20 was so long that it overflowed on the printer but it is all part of line 20.)

Changing line 10 to K=7 causes the computer to execute everything after the ELSE and as a result it prints

K WAS NOT 6

END OF LINE

IF...THEN is often used with more complicated conditions involving the words AND, OR and NOT for example

IF X=5 AND Y=6 THEN PRINT "GOOD"

IF X=5 OR Y=6 THEN PRINT "TOO LARGE"

The word NOT reverses the effect of a condition, thus

IF NOT (X=6) THEN PRINT "X NOT 6"

These are powerful features which are easy to use.

For the slightly more advanced

It was explained above that you can use multiple statement lines with IF...THEN but this leads to messy programs. It is far better to use procedures if you want a whole lot of things to occur. Thus:

100 IF H=F*G THEN PROCGOOD ELSE PROCBAD

This helps to keep the program readable which is very important, not just from an aesthetic point of view but from the very practical point that a readable program is much easier to get right!

More on TRUE and FALSE

On page 89 the concept of TRUE and FALSE was introduced. A variable can have a numeric value (e.g. 6 or 15) or it can be

TRUE or FALSE. In fact this is just playing with words (or perhaps we should say numbers) since the computer understands TRUE to have the value -1 and FALSE to have the value 0.

10 IF 6=6 THEN PRINT "YES" ELSE PRINT "NO"

>RUN

YES

This prints YES because 6=6 is TRUE

5 H=-1

10 IF H THEN PRINT "YES" ELSE PRINT "NO"

>RUN

YES

The above program prints YES because H is TRUE since it has the value -1.

5 H=0

10 IF H THEN PRINT "YES" ELSE PRINT

"NO"

>RUN

NO

This program sets H = FALSE at line 5 and so the program prints NO. –1 implies TRUE and 0 implies FALSE. What about other values of H? In fact all non-zero values are regarded as

TRUE as the following shows.

5 H=-55

10 IF H THEN PRINT "YES" ELSE PRINT "NO"

>RUN

YES

Here are some other peculiar examples

10 G= (6=6)

20 PRINT G

>RUN

-1

because (6=6) is TRUE

10 IF 5–6 THEN PRINT "TRUE"

>RUN

TRUE

This works because (5-6) is –1 which is TRUE

These tricks are more than academic. They can be very useful – not least sometimes in trying to fathom out what on earth the computer thinks it is doing!

17 Procedures

The BBC computer has a very complete version of BASIC – often called "Extended BASIC and in addition it includes the ability to define and use procedures and functions. It is probably the first version of BASIC in the world to allow full procedure and function handling. These extremely powerful features enable the user to structure his or her programs easily and in addition provide a real introduction to other computer languages like PASCAL.

A procedure is a group of waste statements which can be "called by name" from any part of a program.

10 REM REACT

20 REM JOHN A COLL

30 REM BASED ON AN IDEA BY THEO BARRY, OUNDLE

40 REM VERSION 1 / 16 NOV 81

50 @%=&2020A

60 ON ERROR GOTO 470

70 MODE7

80

90 PROCINTRO

100 REPEAT

110 PROCFIRE

120 PROCSCORE

130 UNTIL FNSTOP

140 END

150

160 DEF PROCINTRO

170 PRINT "This program tests your reactions"

180 PRINT

190 PRINT "Press the space bar to continue"

200 REPEAT UNTIL GET=32

210 CLS

220 ENDPROC

230

240 DEF PROCFIRE

250 CLS

260 PRINT "Press the space bar"

270 PRINT "as soon as a cross appears"

280 T=TIME

290 R=RND(200)+100

300 REPEAT UNTIL TIME>T+R

310 PRINT TAB(17, 10);"+"

320 *FX 15,1

330 REPEAT UNTIL GET=32

340 DELAY=TIME-T-R

350 ENDPROC

360

370 DEF PROCSCORE

380 PRINT TAB(0, 22);

390 PRINT "You took "; DELAY/100;"

seconds"

400 ENDPROC

410

420 DEF FNSTOP

430 PRINT"Do you want another go?"

440 REPLY$=GET$

450 = (REPLY$="N") OR (REPLY$="n")

460

470 @%=10

The program above shows how named procedures and functions can be used. The main program is between line 90 and line 140

90 PROCINTRO

100 REPEAT

110 PROCFIRE

120 PROCSCORE

130 UNTIL FNSTOP

140 END

The program tests a person's reactions by measuring how long it takes him to notice a cross on the screen. As you will see from the section above line 90 calls a procedure which gives an

introduction. The procedure is called PROCINTRO and it produces the following on the screen.

This program tests your reactions

Press the space bar to continue

Then the program repeats PROCFIRE and PROCSCORE until the user indicates that he or she does not wish to continue.

PROCFIRE produces this

Press the space bar

as soon as a cross appears

+

and PROCSCORE produces this

You took 2.03 seconds

It all seems very straightforward and logical – and so it is. Using procedures enables you to split a problem up into a number of small manageable sections and to use (or call) those sections with a sensible name. The main section of most programs should be just a number of procedure calls as are lines 90 to 140. The procedures themselves should be in a separate section – after the END statement.

Let us examine PROCINTRO more closely

160 DEF PROCINTRO

170 PRINT "This program tests your reactions"

180 PRINT

190 PRINT "Press the space bar to continue"

200 REPEAT UNTIL GET=32

210 CLS

220 ENDPROC

Notice how it is defined: line 160 is the start of the definition and the procedure ends at line 220 between those lines are normal BASIC statements. Lines 170, 180 and 190 just print messages on the screen. Line 200 waits until the space-bar is pressed, after which line 210 clears the screen.

There are a number of more complex things that can be done with procedures and another program will illustrate the use of parameters – variables passed to the procedure from the main program.

10 REM HYPNO

20 REM TIM DOBSON / ACORN COMPUTERS

30 REM VERSION 2 / 16 NOV 81

40 MODE 5

50 VDU29,640;512;

60

70 FOR X=510 to 4 STEP -7

80 GCOL0,X

90 PROCBOX(X)

100 NEXT

110

120 REPEAT

130 GCOL RND(4),RND(4)

140 FOR K=0 TO 500 STEP 8

150 PROCBOX(K)

160 NEXT K

170 GCOL RND(4),RND(4)

180 FOR K=500 TO 0 STEP -9

190 PROCBOX(K)

200 NEXT K

210 UNTIL FALSE

220 END

230

240 DEF PROCBOX(J)

250 MOVE -J,-J

260 DRAW -J,J

270 DRAW J,J

280 DRAW J,-J

290 DRAW -J,-J

300 ENDPROC

The program uses a procedure called PROCBOX which draws a box. The size of the box is determined by the parameter J in the procedure. However you will see that in line 90 the procedure is called with the statement PROCBOX(X). The initial value of X will be 510 because that is the starting value of the FOR loop at line 70. This value of X (510) will be passed to the parameter J in the procedure. As a result the procedure PROCBOX will draw a box of "size" 510. J is called the "formal parameter" for the procedure since it is used in the procedure itself. However the X in line 90 and the K in line 150 are referred to as actual parameters. Whatever value K has in line 150 will be transferred to the formal parameter J.

A procedure may have any number of parameters but there must be exactly the same number of actual parameters when the procedure is called as there are formal parameters in the procedure definition. Thus if a procedure was defined like this

1000 DEF PROCSWITCH(A,B,C$)

1040 ENDPROC

it could not be called with a statement like

150 PROCSWITCH(X,Y)

but this would be acceptable

150 PROCSWITCH(length, height, NAME$)

Local variables in procedures

10 J=25

20 FOR X=1 TO 5

30 PROCNUM(X)

40 PRINT "OUT OF PROCEDURE J= ";J

50 NEXT X

60 END

70 DEF PROCNUM(J)

80 PRINT "IN PROCEDURE J= ";J

90 ENDPROC

>RUN

IN PROCEDURE J= 1

OUT OF PROCEDURE J= 25

IN PROCEDURE J= 2

OUT OF PROCEDURE J= 25

IN PROCEDURE J= 3

OUT OF PROCEDURE J= 25

IN PROCEDURE J= 4

OUT OF PROCEDURE J= 25 IN PROCEDURE J= 5

OUT OF PROCEDURE J= 25

In the program above the variable J is used in two ways. The main program starts at line 10 and ends at line 60. The

procedure is defined between lines 70 and 90. Line 10 declares that J has the value 25 and the value of J is not changed in the main program. However J is used as the formal parameter in the procedure. All formal parameters are LOCAL to the procedure which means that their value is not known to the rest at the program. Inside the procedure, J takes on the value of the actual parameter X, but outside the procedure it has a different value. The distinction is made between GLOBAL variables and LOCAL variables. Global variables are known to the whole program, including procedures, whereas local variables are only known to those procedures in which they are defined and to procedures within that procedure.

In the program above, X is a global variable and it looks as if J is global too, since it is defined in line 10 of the main program. In fact that J is global but the use of the parameter J in the procedure creates another variable J which is local to the procedure. If a different parameter had been used in the procedure definition then J would have remained global. Thus in the print-out below the formal parameter has been changed to K in line 70, which leaves J as a global variable.

10 J=25

20 FOR X=1 TO 5

30 PROCNUM(X)

40 PRINT "OUT OF PROCEDURE J= ";J

50 NEXT X

60 END

70 DEF PROCNUM(K)

80 PRINT "IN PROCEDURE J= ";J

90 ENDPROC

>RUN

IN PROCEDURE J= 25

OUT OF PROCEDURE J= 25

IN PROCEDURE J= 25

OUT OF PROCEDURE J= 25

IN PROCEDURE J= 25

OUT OF PROCEDURE J= 25

IN PROCEDURE J= 25

OUT OF PROCEDURE J= 25

IN PROCEDURE J= 25

OUT OF PROCEDURE J= 25

The program is pretty pointless in its present form for several reasons – not least because it doesn’t actually do anything with K in the procedure!

Now that J is global its value could be altered anywhere – including inside the procedure. Line 75 increases J by 10:

10 J=25

20 FOR X=1 TO 5

30 PROCNUM(X)

40 PRINT "OUT OF PROCEDURE J= ";J

50 NEXT X

60 END

70 DEF PROCNUM(K)

75 J=J+10

80 PRINT "IN PROCEDURE J= ";J

90 ENDPROC

>RUN

IN PROCEDURE J= 35

OUT OF PROCEDURE J= 35

IN PROCEDURE J= 45

OUT OF PROCEDURE J= 45

IN PROCEDURE J= 55

OUT OF PROCEDURE J= 55

IN PROCEDURE J= 65

OUT OF PROCEDURE J= 65

IN PROCEDURE J= 75

OUT OF PROCEDURE J= 75

It has been pointed out that all formal parameters are local to the procedure in which they are defined (and to inner procedures) but other variables can be declared as LOCAL if required. We very often use the variable X as a counter for a FOR...NEXT loop and as a result you have to be careful not to use it twice in the same section of a program. Declaring X as local to a procedure ensures that its use locally will not affect the value of X outside the procedure.

10 J=25

20 FOR X=1 TO 5

30 PROCNUM(X)

40 PRINT "OUT OF PROCEDURE J= ";J

50 NEXT X

60 END

70 DEF PROCNUM(K)

72 LOCAL X

75 FOR X= 1 TO 10

80 J=J + J/X

85 NEXT X

90 ENDPROC

>RUN

OUT OF PROCEDURE J= 275

OUT OF PROCEDURE J= 3025

OUT OF PROCEDURE J= 33275

OUT OF PROCEDURE J= 366025

OUT OF PROCEDURE J= 4026275

In the program above, X is used twice – once in the main program (lines 20 to 50) and secondly, and quite separately, as a LOCAL variable in the procedure. J remains global.

It is wise to declare variables as LOCAL in procedures and functions wherever possible (except when the variable is a formal parameter).

18 Functions

Functions are in many ways similar to procedures but there is one major difference – they always calculate a result which may be a number or a string. BASIC already contains a number of functions. For example the function SQR returns the square root of a number. The square root of 16 is 4 so the statements

Y=SQR(16)

and

PRINT SQR(16)

make sense. The first example calculates the square root of 16 and places the result in Y. Compare this to a procedure – for example the one above, to draw a box. The procedure makes things happen (a box appears on the screen) but it does not produce a numeric or a string value. Functions always produce a numeric or string result.

If you have a reasonable understanding of procedures and parameters then you can probably cope with this example of a function:

10 PRINT "GIVE ME THREE NUMBERS ";

20 INPUT A,B,C

30 PRINT "THE SUM OF THE NUMBERS IS ";

40 PRINT FNSUM(A,B,C)

50 END

100 DEF FNSUM(X,Y,Z)

105 LOCAL K

110 K=X+Y+Z

120 =K

GIVE ME THREE NUMBERS ?2,4,4

THE SUN OF THE NUMBERS IS 10

Again this program is not of much use – we are using a sledge hammer to crack a nut – but we had better learn to walk before we run!

The function is defined in lines 100 to 120 and three parameters are passed to the function. A, B and C are the actual parameters and the numbers in A, B and C are passed to formal parameters X, Y and Z. For the sake of illustration a local variable K has been used. Line 110 sets K equal to the sum of X, Y and Z. Line 120 shows the way in which a function is ended. It says that the function FNSUM has the value of K.

The example above was spread out to show how a function can be constructed – it could have been compressed to

10 PRINT "GIVE ME THREE NUMBERS ";

20 INPUT A,B,C

30 PRINT "THE SUM OF THE NUMBERS IS ";

40 PRINT FNSUM(A,B,C)

50 END

100 DEF FNSUM(X,Y,Z)

120 = X+Y+Z

or even to the single line function shown below

10 PRINT "GIVE ME THREE NUMBERS ";

20 INPUT A,B,C

30 PRINT "THE SUN OF THE NUMBERS IS ";

40 PRINT FNSUM(A,B,C)

50 END

100 DEF FNSUM(X,Y,Z) = X+Y+Z

Of course we could have managed without a function at all...

10 PRINT "GIVE ME THREE NUMBERS ";

20 INPUT A,B,C

30 PRINT "THE SUM OF THE NUMBERS IS ";

40 PRINT A+B+C

50 END

...and clearly that would have been the right thing to do in this case. However as soon as your programs reach 40 or 50

lines you should be using procedures extensively and functions occasionally.

As mentioned at the start of this section, functions can be used to calculate a numeric or a string result. The function which follows returns the middle letter of a string. The string is passed as a parameter

100 DEF FNMID(A$)

110 LOCAL L

120 L=LEN(A$)

140 =MID$(A$,L/2,1)

Again, the function is terminated by a statement starting with an equal sign. To use the above function type in the following additional lines

10 INPUT Z$

20 PRINT FNMID(Z$)

30 END

Notice that the function is placed beyond the END statement where it will not be executed except by being called by name.

19 GOSUB

This statement allows the program temporarily to divert to another section. Think about the process of writing a letter. In essence it is quite straightforward – but in practice while the main aim is to write the letter there are often quite a few diversions like the need to get another sheet of paper or answer the phone. These small "sub-tasks" are essential but if we write a description of every single thing that occurred while writing a letter the reader would probably be so confused that he or she wouldn't realise what the overall aim was. However if the job is described as a series of subroutines or procedures then the main task will emerge more clearly. The "subroutine" and the GOSUB statement were introduced some years ago to help those writing BASIC programs to break their programs up into recognizable modules. In recent years more flexible and more easily used tools have become available – namely Procedures and Functions – and these two should be used in preference to GOSUB. None the less, BBC BASIC maintains the GOSUB statement for compatibility with other versions of BASIC.

A temperature scale conversion program is shown in two forms below. Both produce exactly the same output on the computer screen but one has been written using GOSUB and GOTO and the other using procedures.

First with GOSUB and GOTO

10 REM TEMPERATURE CONVERSION

20 REM WITHOUT STRUCTURED BASIC

30 REM THIS IS NOT THE WAY TO WRITE PROGRAMS!

40 REM JOHN A COLL

50 REM VERSION 1.0 /22 NOV 81

60 MODE 7

70 @%=&2020A

80 PRINT "ENTER THE TEMPERATURE FOLLOWED BY"

90 PRINT "THE FIRST LETTER OF THE TEMPERATURE"

100 PRINT "SCALE. e.g. 100C or 72F or 320K"

110 PRINT

120 PRINT "Enter the temperature ";

130 INPUT REPLY$

140 TEMP=VAL(REPLY$)

150 SCALE$=RIGHT$(REPLY$,1)

160 GOODSCALE=FALSE

170 IF SCALE$="C" THEN GOSUB 370

180 IF SCALE$="F" THEN GOSUB 390

190 IF SCALE$="K" THEN GOSUB 430

200 IF NOT ( GOODSCALE AND TEMP>=-273.16) GOTO 260

210 PRINT''

220 PRINT TEMP; " Celsius"

230 PRINT TEMP+273.16; " Kelvin"

240 PRINT TENP*9/5 + 32; " Fahrenheit"

250 PRINT

260 IF GOODSCALE THEN 310

270 CLS

280 PRINT "You must follow the temperature with"

290 PRINT "the letter ""C"", ""F"" or ""K"" "

300 PRINT "and nothing else"

310 IF TEMP>=-273.16 THEN 360

320 CLS

330 PRINT "The temperature you have given is"

340 PRINT "too cold for this universe! Try again"

350 PRINT

360 GOTO 110

370 GOODSCALE=TRUE

380 GOTO 460

390 REM CONVERT TO CELSIUS

400 TEMP=(TEMP-32)*5/9

410 GOODSCALE=TRUE

420 GOTO460

430 REM CONVERT TO CELSIUS

440 TEMP=TEMP-273.16

450 GOODSCALE=TRUE

460 RETURN

Lines 430 to 460 are referred to as a "subroutine", and these lines of the program can be called from line 190 by the Statement GOSUB 430. Notice that this statement does not give the reader any idea of the purpose of the subroutine. The statement RETURN at the end of the subroutine returns it to the statement after the original GOSUB statement.

Compare the last program with the one that follows

10 REM TEMPERATURE CONVERSION

20 REM JOHN A COLL

30 REM VERSION 1.0 /22 NOV 81

40 MODE 7

50 @%=&2020A

60 PRINT "ENTER THE TEMPERATURE FOLLOWED BY"

70 PRINT "THE FIRST LETTER OF THE TEMPERATURE"

80 PRINT "SCALE. e.g. 100C or 72F or 320K"

90 REPEAT

100 PRINT

110 PRINT "Enter the temperature ";

120 INPUT REPLY$

130 TEMP = VAL(REPLY$)

140 SCALE$=RIGHT$(REPLY$,1)

150 GOODSCALE=FALSE

160 IF SCALE$="C" THEN PROCCENT

170 IF SCALE$="F" THEN PROCFAHR

180 IF SCALE$="K" THEN PROCKELVIN

190 PROCEND

200 UNTIL FALSE

210 END

220

230 DEF PROCCENT

240 GOODSCALE=TRUE

250 ENDPROC

260

270 DEF PROCFAHR

280 REM CONVERT TO CELSIUS

290 TEMP=(TEMP-32)*5/9

300 GOODSCALE=TRUE

310 ENDPROC

320

330 DEF PROCKELVIN

340 REM CONVERT TO CELSIUS

350 TEMP=TEMP-273.16

360 GOODSCALE=TRUE

370 ENDPROC

380

390 DEF PROCEND

400 IF GOODSCALE AND TEMP>=-273.16 THEN PROCRESULTS

410 IF NOT GOODSCALE THEN PROCILLEGAL

_SCALE

420 IF TEMP< -273.16 THEN PROCILLEGAL

_TEMP

430 ENDPROC

440

450 DEF PROCRESULTS

460 PRINT''

470 PRINT TEMP; " Celsius"

480 PRINT TEMP+273.16; " Kelvin"

490 PRINT TEMP*9/5 + 32; " Fahrenheit"

500 PRINT

510 ENDPROC

520

530 DEF PROCILLEGAL_SCALE

540 CLS

550 PRINT "You must follow the temperature with"

560 PRINT "the letter ""C"", ""F"" or ""K"" "

570 PRINT "and nothing else"

580 ENDPROC

590

600 DEF PROCILLEGAL_TEMP

610 CLS

620 PRINT "The temperature you have given is"

630 PRINT "too cold for this universe! Try again"

640 PRINT

650 ENDPROC

Certainly the second version is long (about a third longer) but it is much more understandable and this is of crucial importance for medium and large programs.

GOTO

You may have noticed the use of the GOTO statement in many of the examples above. GOTO is a very useful statement which tells the computer to skip to a particular line number. Beginners in programming find it easy to use. However, it should be used with care because it can lead to what some people call ‘spaghetti' programming, a tangle of loops backwards and forwards which makes it very difficult indeed to follow what is going on. The example on page 32 shows this in an extreme form.

If you are writing short programs then by all means use GOTO.

For example, the following program prints out the ASCII code of any key which is pressed – useful if you can't find an ASCII code sheet:

10 PRINT GET

20 GOTO 10

It would be taking things too far to expect people to write

10 REPEAT

20 PRINT GET

30 UNTIL FALSE

However, when you write programs of more than, say, 50 lines it is a very good idea to try to use the "structure" provided instead of GOTO statements. It is generally accepted that it is still useful to use GOTO statements as a last resort when handling error conditions. Use whatever techniques make your program (a) work and (b) easy to follow.

20 ON GOTO, ON GOSUB

There is often a need, in a computer program, to proceed in one of a number of directions. For example your program might present a "menu" of 8 options for the user to choose from. When the user has made the choice your program will need to branch off in the appropriate direction. There are a number of ways of doing this. Here is one in part of a program

100 MODE 7

110 PROCINTRO

120 REPEAT

130 PROCMENU

140 IF M=1 THEN PROCOscar7

150 IF M=2 THEN PROCOscar8

160 IF M=3 THEN PROCUOSAT

170 IF M=4 THEN PROCorbit

180 IF M=5 THEN PROCtransmit

190 IF M=6 THEN PROCshowfigs

200 IF M=7 THEN PROCMercator

210 IF M=8 THEN PROCLocator

220 IF M=9 THEN PROCgetdatetime

230 UNTIL M=-1

240 END

Lines 140 to 220 provide exits to a number of procedures all of which will automatically return to the main program. Which procedure is selected depends on the value of M as selected by the user during the procedure PROCMENU.

The above method is easy to understand and is recommended but there are other methods which have their place. The statement ON...GOTO also provides a number of exits.

100 ON M GOTO 1000,1200,1250,1600

would provide an exit to line 1000 of the BASIC program if M =

1. If M=2 then control will pass to line 1200 and so on.

An alternative format is

100 ON M GOSUB 1000,1200,1350

In this case control is passed to the subroutines indicated and then return to the next line.

Both these techniques are widely used but are less clear than the use of procedures as indicated at the beginning of this section.

21 Yet more on variables

Arrays

Quite often we use the computer to store and manipulate sets of data rather than just a single value. For example, we might want to calculate wages for a group of people or sort a group of 20 numbers into order. The 20 numbers might well be associated with 20 names. Arrays make it a lot easier to deal with groups of names and numbers. To get to a more manageable example let's consider working with five names and their associated year of birth. We could store the five names in five variables like this:

N1$ = "SARDESON"

N2$ = "MATTINSON"

N3$ = "MOIR"

N4$ = "ALLEN"

N5$ = "MOUNT"

That is quite reasonable and it works. If you say

PRINT N2$

the computer will then print out MATTINSON.

However, you cannot tell it to print out the 5th entry or the fourth entry. The computer doesn't have any way of knowing that N5$ is the 5th entry. Using arrays, though, we can pick out the 5th entry in a long list and that is very useful.

The first thing we have to do is to tell the computer how large an array we are going to use. This is done with a DIM statement – e.g.

DIM N$(5)

this creates an array (a table) and we can then say

N$(1) = "SARDESON"

N$(2) = "MATTINSON"

N$(3) = "MOIR"

N$(4) = "ALLEN"

N$(5) = "MOUNT"

If we follow that with

X = 1

and then say

PRINT N$(X)

the computer will print "SARDESON".

Note that the X was a variable which, in this case, had the value of 1.

Here is a complete program – as far as we have got.

10 DIM N$(5)

20 N$(1)="SARDESON"

30 N$(2)="MATTINSON"

40 N$(3)="MOIR"

50 N$(4)="ALLEN"

60 N$(5)="MOUNT"

70 PRINT "WHICH ENTRY DO YOU WANT"

80 INPUT X

90 PRINT N$(X)

100 GOTO 70

We could also define an array to contain the five years of birth

200 DIM Y(5)

210 Y(1)=1964

220 Y(2)=1960

230 Y(3)=1950

240 Y(4)=1959

250 Y(5)=1962

It would be easy to add lines to this program to make the computer search for various things. Of course with only 5 entries it would undoubtedly be quickest to do the whole thing manually – but with a hundred, a thousand or a million entries the computer would be faster – and certainly more accurate. A few examples of extra lines will make the use of these arrays clearer.

To print out everyone born before 1963

300 FOR X=1 TO 5

310 IF Y(X)<1963 THEN PRINT N$(X)

320 NEXT X

or to print out everyone whose name contains more than 5 letters

400 FOR X=1 TO 5

410 J$=N$(X)

420 IF LEN (J$)>5 THEN PRINT J$

430 NEXT

or print out every one whose name begins with M,

500 FOR X=1 TO 5

510 J$=N$(X)

520 IF LEFT$(J$,1)="M" THEN PRINT J$

530 NEXT

All these things can only be done if the computer is able to select a position in a list and it can only do this with arrays.

Note: for an explanation of how the last examples worked, see section 22.

You will have noticed that we used the array N$(X) to store strings (the names of the people), and array Y(X) to store numbers (the year of birth). Each element of the array N$(X) can store as long a name as you want (up to 255 characters) and you can DIMension N$ to have as many entries as you want. For example, DIM N$(1000) would create a string array with space for 1000 different names. N$(X) is called a "string array" since it is used to store strings.

The array Y(X) is called a "numeric array" and again it can have as many elements (entries) as you need – e.g. DIM

Y(2000). You can also have "integer numeric arrays" like DIM J%(100).

As usual on the BBC computer the story doesn't finish there! There is another whole group of arrays which we haven’t met yet. The arrays we have met (both string and numeric) are all "single dimension arrays" and could be illustrated by this diagram.

Y(1) Y(2) Y(3) Y(4) Y(5)

1964 1960 1950 1959 1962

Now suppose we wanted to store the day and month of the birthday as well as the year. We need more boxes.

21 12 4 24 19

2 2 2 10 12

1964 1960 1950 1959 1962

A set of data like that is called a "5 by 3 array" and the (empty) boxes can be set up by the statement

10 DIM Y(5,3)

The array could then be filled with the statements

20 Y(1,1)=21

30 Y(1,2)=2

40 Y(1,3)=1964

50 Y(2,1)=12

60 Y(2,2)=2

70 Y(2,3)=1960 etc.

In practice it would involve a lot less typing, and make the program shorter, if all the figures were held in DATA statements. You may well need to skip this section at first and return to it when you have understood section 22 which deals with the keywords READ, DATA and RESTORE

If you use READ and DATA to fill the above 5x3 array the program could look like this

10 DIM Y(5,3)

20 FOR COLUMN=1 TO 5

30 FOR ROW=1 TO 3

40 READ Y(COLUMN,ROW)

50 NEXT ROW

60 NEXT COLUMN

500 DATA 21,2,1964

510 DATA 12,2,1960

520 DATA 4,2,1950

530 DATA 24,10,1959

540 DATA 19,12,1962

The program above takes successive numbers from the DATA statements and inserts them into the array. Once this program has been run the array will be set up – full of the figures – and other sections of the program (not shown above), could search the array as required. The array above is a "two-dimensional array" used to store numbers. The phrase "two dimensional" refers to the fact that there are 5 entries in one dimension and 3 entries in another dimension – a total of 15 entries. A three dimensional array could be defined with the statement

DIM W(4,5,6)

and for a four dimensional array with

DIM T(2,2,5,3)

This last array would have 2x2x5x3 (60) individual entries. Actually, array elements can be numbered from zero instead of, so an array declared with

DIM V(3)

has, in fact, got 4 elements which are V(0), V(1), V(2), and V(3). Similarly the array T(2,2,5,3) has 3x3x6x4 (216) elements and will take up over 1000 bytes of memory. Multi-dimension arrays are voracious memory eaters – only use them when needed and, if at all possible, use every element that you set up. There is no limit, other than lack of memory, on the number of dimensions in an array.

At the start of this section we set up a string array with the statement DIM N$(5).

This contains 6 elements N$(0) to N$(5). The length of each string element is limited to the usual 255 characters but you can have as many elements as you wish and as many dimensions – just as for numeric arrays. String arrays are even more ravenous for memory than numeric arrays – use them sparingly!

Just to make sure that the various possibilities are clear, here is a program to set up a string array with first names as well as last names. The program reads names and dates into two arrays:

10 DIM Y(4,2)

20 DIM N$(4,2)

30 FOR COLUMN=0 TO 4

40 FOR ROW=0 TO 2

50 READ Y(COLUMN, ROW)

60 NEXT ROW

70 FOR ROW=0 TO 2

80 READ N$(COLUMN, ROW)

90 NEXT ROW

100 NEXT COLUMN

500 DATA 21,2,1964, JAMES,C,SARDESON

510 DATA 12,2,1960, A, MICHAEL, MATTINSON

520 DATA 4,12,1960, CHARLES,C,MOIR

530 DATA 24,10,1959, STEPHEN, R, ALLEN

540 DATA 19,12,1962, GAVIN,,MOUNT

22 READ, DATA, RESTORE

One very common way of storing a whole set of information along with the computer program is to use DATA

statements. You will remember that computer programs can be stored on cassette and sets of data can be stored in the program as well. For example it might be necessary in a program to convert the month given as a number into a name. The program below stores the names of the month as DATA

5 REPEAT

10 PRINT "GIVE THE MONTH AS A NUMBER"

20 INPUT M

30 UNTIL M>0 AND M<13

40 FOR X=1 TO M

50 READ A$

60 NEXT X

70 PRINT "THE MONTH IS ";A$

100 DATA JANUARY, FEBRUARY, MARCH, APRIL

110 DATA MAY, JUNE, JULY, AUGUST, SEPTEMBER

120 DATA OCTOBER, NOVEMBER, DECEMBER

>RUN

GIVE THE MONTH AS A NUMBER

?6

THE MONTH IS JUNE

Lines 10 to 30 repeat until a sensible value (or M is entered) – it must be between 1 and 12. In the example run a value of 6 was given to M. In this case the FOR...NEXT loop between lines 40 and 60 will go round 6 times. Each time it goes around it READs the next piece of DATA into A$ until finally A$ will be

left containing JUNE. It might make it clearer if an extra line is temporarily inserted at line 55 to print out the value of A$ and X each time around the loop.

>55PRINT A$,X

>

>LIST

5 REPEAT

10 PRINT "GIVE THE MONTH AS A NUMBER"

20 INPUT M

30 UNTIL M>0 AND N<13

40 FOR X=1 TO M

50 READ AS

55 PRINT A$,X

60 NEXT X

70 PRINT "THE MONTH IS ";A$

100 DATA JANUARY, FEBRUARY, MARCH, APRIL

110 DATA MAY, JUNE, JULY, AUGUST, SEPTEMBER

120 DATA OCTOBER, NOVEMBER, DECEMBER

>

>RUN

GIVE THE MONTH AS A NUMBER

?6

JANUARY 1

FEBRUARY 2

MARCH 3

APRIL 4

MAY 5

JUNE 6

THE MONTH IS JUNE

This is quite a neat way of getting to the (say) sixth element of a list but there is another way using an array.

Sometimes there is more than one set of data and it is useful to be able to set the 'data pointer’ to a selected set of data. The next program has two sets of data each containing a set of prices and car names. One set of data refers to British Leyland cars and the other to Lotus cars.

10 REPEAT

20 PRINT "DO YOU PREFER BL OR LOTUS CARS? ";

30 A$=GET$

40 PRINT A$

50 IF A$="B" THEN RESTORE 170 ELSE RESTORE 340

60 INPUT "HOW MANY POUNDS CAN YOU AFFORD ",P

80 PRINT "YOU CAN AFFORD THESE THEN:"

90 FOR X=1 TO 15

100 READ NAME$

110 READ PRICE

120 IF PRICE <P THEN PRINT PRICE,TAB(15);NAME$

130 NEXT X

140 PRINT

150 UNTIL FALSE

160

170 REM BRITISH LEYLAND CARS

180 DATA MINI 1000 CITY, 2898

190 DATA METRO HLE, 4198

200 DATA DOLOMITE 1300,4351

210 DATA SPITFIRE 1500, 4696

220 DATA TRIUMPH ACCLAIM HLS, 4988

230 DATA ALLEGRO 31.3 HLS, 5095

240 DATA DOLOMITE 1500HL, 5225

250 DATA PRINCESS 2 HL, 5899

260 DATA DOLOMITE SPRINT, 7118

270 DATA TR7 FIXEDHEAD, 7258

280 DATA ROVER 2300, 7450

290 DATA DAIMLER SOVEREIGN 4.2, 16259

300 DATA JAGUAR XJ6 4.2,16279

310 DATA DAIMLER VANDEN PLAS 4.2, 21419

320 DATA DAIMLER LIMOUSINE, 26998

330

340 REN LOTUS CARS

350 DATA ESPRIT S3, 13513

360 DATA ECLAT SERIES 2.2, 14857

370 DATA TURBO ESPRIT, 16982

380 RATA ELITE SERIES 2.2, 17206

>RUN

DO YOU PREFER BL OR LOTUS CARS? B

HOW MANY POUNDS CAN YOU AFFORD ?10000

YOU CAN AFFORD THESE THEN:

2898 MINI 1000 CITY

4198 METRO HLE

4351 DOLOMITE 1300

4696 SPITFIRE 1500

4988 TRIUMPH ACCLAIM HLS

5095 ALLEGRO 31.5 HLS

5225 DOLOMITE 1500HL

5899 PRINCESS 2 HL

7118 DOLOMITE SPRINT

7258 TR7 FIXEDHEAD

7450 ROVER 2300

DO YOU PREFER BL OR LOTUS CARS? L

HOW MANY POUNDS CAN YOU AFFORD ?1700

YOU CAN AFFORD THESE THEN:

Out of DATA at Line 100

You will notice that line 50 uses the RESTORE statement to set the data ‘pointer’ to either line 170 where BL, data is stored or to line 340 where Lotus data is stored. This ensures that data is read from the correct list.

Lines 90 to 130 attempt to read off 15 sets of data from the data lists but fails when Lotus data is selected as only 4 sets of data are provided. The message

Out of DATA at Line 100

indicates the failure to kind enough entries in the data table. Methods of overcoming the problem are given in section 27 which deals with error handling.

23 Integer handling

Two special arithmetical functions are provided which produce integer (i.e., whole number) results. These integer functions are DIV and MOD. (DIVision and MODulus)

The result of a normal division has two parts – the whole number part and the remainder. Normally the remainder is quoted as a decimal fraction. Thus

4=2.75 or 2¾

However the functions DIV and MOD enable the whole number part and the remainder to be calculated separately.

Thus

11 DIV 4 = 2

(i.e., 4 goes into 11 two times) and

11 MOD 4 = 3

(i.e., the remainder is 3)

A simple division test shows how they can be used.

5 CLS

10 PRINT "Division test!"

20 PRINT "Answer with a whole number, and a" ' "remainder"

30 REPEAT

40 X=RND(100)

50 Y=RND(10)

60 PRINT ' "What is ";X;" divided by ";Y

70 INPUT A

80 INPUT "Remainder? "B

90 IF A=Y DIV Y AND B=X MOD Y THEN PRINT "That's correct" ELSE PRINT "That's wrong"

100 PRINT ' "Press any key to continue"

110 T=GET

120 UNTIL FALSE

DIV and MOD are used whenever you are trying to convert units – for example seconds into minutes. Thus 500 seconds is 500 DIV 60 minutes and 500 MOD 60 seconds that is 8 minutes 20 seconds

For example this program prints a 24 hour clock

5 PRINT "Please input the time"

10 INPUT "Hours ",H

20 INPUT "Minutes ",M

30 TIME=H* 360000 + M* 6000

40 CLS

50 REPEAT

60 SEC=(TIME DIV 100) MOD 60

70 MIN=(TIME DIV 6000) MOD 60

80 HR=(TIME DIV 360000) MOD 24

90 PRINT TAB(7,12) HR;";";MIN;":";SEC

100 UNTIL FALSE

The clock is improved if you type VDU 23; 8202; 0; 0; 0; which switches off the flashing cursor (sec page 77).

The next program would keep time to the end of the century if you left the computer switched on that long!

10 lastminute=0

20 MODE7

30 PROCOFF

40 PROCgetdatetime

50 CLS

60 REPEAT

70 PROCshowtime

80 UNTIL FALSE

90 END

100

110 DEF PROCgetdatetime

120 CLS

130 PRINT"Please supply the day, month and year"

140 PRINT "as numbers e.g. 24 12 1982"

150 PRINT

160

170 REPEAT

180 PRINT TAB(5,10);"Day ";

190 INPUT TAB(12,10) "" day

200 UNTIL day>0 AND day<32

210

220 REPEAT

230 PRINT TAB(5,12);"Month ","

240 INPUT TAB(12,12) "" month

250 UNTIL month>0 AND month<13

260

270 REPEAT

280 PRINT TAB(5,14);"Year";

290 INPUT TAB(12,14) "" year

300 UNTIL year>1799 AND year<2500 OR year>0 AND year<99

310 IF year<99 THEN year=year+1900

320

330 CLS

340 PRINT "and now the time please"

350 PRINT "using a 24 hour clock"

360

370 REPEAT