Here is an HSPICE circuit I developed for measuring capacitance vs. voltage.
It sweeps the voltage on the DUT at a specified slope up and down, measures
the
current at given voltages on both ramps (rising and falling) and calculates
the
capacitance from the delta between the current readings. This is based on
the
equation
dV
I=C----
dt
which solved for C looks like this
dt
C=I----.
dV
The idea is that on a rising slope the capcitance of the DUT is charged and
on
the falling edge it is discharged, so the two current readings at a given
voltage on these ramps are going to be different if the DUT is capacitive.
Delta I is twice the current that is shown in the capacitance equation
above.
The cpacitance values are in variable "CAP". Plot them against variable
"CapV"
from the .MT0 file. This circuit worked well for me.
Arpad Muranyi
Intel Corporation
-------------------------------------- cut
------------------------------------
Capacitance meter circuit
***************************************************************************
.OPTIONS POST=1 ACCURATE NUMDGT=8
.TRAN 0.01ns '2*dt' SWEEP CapV LIN 'Points+1' CapV1 CapV2
***************************************************************************
.PARAM CapV1 = 0.0V $ starting voltage of the sweep
.PARAM CapV2 = 5.0V $ Ending voltage of the sweep
.PARAM Points = 40 $ Resolution of output plot
.PARAM dt = 10.0ns $ Ramp rate across the voltage range
***************************************************************************
.PARAM dV = 'CapV2-CapV1'
.PARAM Ovh = 0.1 $ The sweep range needs a little overhead
.PARAM CapV = 0.0V $ This is the voltage at which current is
* measured for each iteration
***************************************************************************
.MEAS TRAN Sw_I1 FIND PAR('I(Vsw)') WHEN V(Sweep)=CapV Rise=1
.MEAS TRAN Sw_I2 FIND PAR('I(Vsw)') WHEN V(Sweep)=CapV Fall=1
.MEAS TRAN CAP PARAM='abs((Sw_I1-Sw_I2)/2*(dt/(dV+2*dV*Ovh)))'
***************************************************************************
Vsw Sweep 0 PWL
+ 0ns 'CapV1-dV*Ovh'
+ dt 'CapV2+dV*Ovh'
+ '2*dt' 'CapV1-dV*Ovh'
***************************************************************************
*C1 Sweep 0 C=10.0pF $ To test the simulation
X1 Sweep 0 0 0 N_MOSFET M=50 $ Put your DUT here
***************************************************************************
.END
============================================================================
===
Hi,
How can i measure, in HSPICE, the capacitance of a mos transistor,
connected as a capacitor, as a function of the voltage across its
terminals..?
thanks in advance, yehuda
-- ---------------------------------------------------------------------------- - God put me on earth to accomplish a certain number of things Right now I am so far behind I will never die ---------------------------------------------------------------------------- - Yehuda D. YizraeliZoran Microelectronics Ltd. E-mail: [email protected] Advanced Technology Center Direct Tel: 972-4-8545795 P.O.B. 2495, Haifa 31204, Israel Operator : 972-4-8545777 http://www.zoran.com Fax : 972-4-8551550 -------------------------------------------------------------------