[SI-LIST] : eye diagram demo from Avanti

Scott McMorrow ([email protected])
Mon, 19 Jul 1999 15:57:22 -0700

Here is the example from the Hspice demo directory.



* Eye Diagrams
* This type of diagram is to reduce a large amount of data to
* one frame. Data from a fixed period is superimposed upon
* itself.
* An e source is setup to create a sawtooth.
* The sawtooth period is the window to be plotted, eyewidth. i.e. if
* you are looking at a periodic signal and want to know if the
* period or amplitude drifts over a large time, then the
* eyewidth is set to the period of the data to be plotted and
* superimposed.
* In this example, Y is a damped sin wave at 1 Mhz. X is a 5 Mhz
* sin wave. The eyewidth is set to 2 Mhz. (Look at the difference
* between 2Mhz and 1Mhz as an experiment).
* To view output in Meta-Waves, place signal T on the x axis and plot either
* X or Y on the y axis. For the damped sin wave, notice that the
* frequency is constant but that the amplitude obviously decays.
* This is a view of all periods super-imposed on each other.
* Plot X, Y vs Time,
* X, or Y vs T
* Only 4 lines are needed to add eye diagrams to a circuit:
* Here they are:
* .Param EyeWidth = 2.0x $ Bandwidth
* eT T 0 Vol='(TIME*EyeWidth)-int((TIME*EyeWidth))'
* rT T 0 1k
* .Option Post

.Param EyeWidth = 2.0x $ Bandwidth

* a clever alternative here is to set .Param Eyewidth = '1/<clock_period>'

vX X 0 Sin ( 0v 1v 1xHz )
vY Y 0 Sin ( 0v 1v 1xHz 0s 500k )

* Simple time manipulation to create a sawtooth pattern
eT T 0 Vol='(TIME*EyeWidth)-int((TIME*EyeWidth))'

rX X 0 1k
rY Y 0 1k
rT T 0 1k

.Tran 10ns 10us
.Option Post=2

**** To unsubscribe from si-list: send e-mail to [email protected] In the BODY of message put: UNSUBSCRIBE si-list, for more help, put HELP. si-list archives are accessible at http://www.qsl.net/wb6tpu/si-list ****