;	Receive Sony IR Remote Control Codes with Atmel AT90S1200
;
;	Charles R. Ott
;	June 22, 1998

.nolist				;Suppress listing of include file
.include "2313def.inc"		;Define chip particulars
.list

;	Global register variables
.def	relays	=R15		;Input port pins for toggling
.def	wreg	=R16		;General use working register
.def	devcode	=R17		;IR device code
.def	irfunc	=R18		;IR function code
.def	flags	=R19		;Bit variables
.def	timeout	=R20		;Delay time passed to subroutine
.def	bitcnt	=R21		;Received character bit counter
.def	count	=R22		;Count of IR functions received
.def	last	=R23		;Last code received
.def	longtime=R24		;Long delay counter

;	Flag definitions
.equ	gotir	=0
.equ	startb	=1

;	Timer/Counter prescaler values
.equ	TSTOP	=0		;Stop Timer/Counter
.equ	TCK64	=3		;Timer/Counter runs from CK / 64

.cseg

;	Interrupt vectors
.org	0
	rjmp	reset		;Reset Vector
.org	INT0addr		;External Interrupt0 Vector
	rjmp	readir

;	Main program entry point on reset
reset:
	ldi	wreg,RAMEND	;Init Stack Pointer
	out	SPL,wreg
	ldi	wreg,0xFF	;Turn off all LEDs
	out	PORTB,wreg
	ldi	wreg,0xFF	;Make port B pins all outputs
	out	DDRB,wreg
	out	PORTD,wreg	;Put power on all port D pins
	ldi	wreg,0b11111011	;Make PD2 an input, all others outputs
	out	DDRD,wreg
	ldi	wreg,1<<INT0	;Enable external interrupt 0
	out	GIMSK,wreg
	ldi	wreg,1<<ISC01	;Use falling edge for interrupt
	out	MCUCR,wreg
	clr	flags
	clr	count
	clr	last

main:     
	sei			;Enable interrupts
	sbrs	flags,gotir	;See if anything received yet
	rjmp	main		;Wait until something available
	cli			;Disable interrupts
	cbr	flags,1<<gotir	;Clear status flag
	andi	irfunc,0x7f	;Eighth bit set on some?
	cpi	devcode,0x05	;Verify device code
	brne	patch
	cp	last,irfunc	;See if same as last
	breq	irsame
	clr	count
	mov	last,irfunc
	rjmp	main
irsame:
	inc	count
	cpi	count,2
	brne	main
	cli			;Disable interrupts
	cpi	irfunc,0x15	;Check "power" key pressed
	brne	chkplay
	cbi	PORTB,4
	rcall	ldelay
	sbi	PORTB,4
	rjmp	irclear
chkplay:
	cpi	irfunc,0x1a	;Check "play" key pressed
	brne	chkstop
	cbi	PORTB,5
	rcall	ldelay
	sbi	PORTB,5
	rjmp	irclear
chkstop:
	cpi	irfunc,0x18	;Check "stop" key pressed
	brne	chkpause
	cbi	PORTB,6
	rcall	ldelay
	sbi	PORTB,6
	rjmp	irclear
chkpause:
	cpi	irfunc,0x19	;Check "pause" key pressed
	brne	chk0
	cbi	PORTB,7
	rcall	ldelay
	sbi	PORTB,7
	rjmp	irclear
chk0:
	cpi	irfunc,0x09	;Check "0" key pressed
	brne	chk1
	ldi	wreg,0xff
	out	PORTB,wreg
	rjmp	irclear
chk1:
	cpi	irfunc,0x00	;Check "1" key pressed
	brne	chk2
	in	relays,PORTB
	ldi	wreg,1
	eor	relays,wreg
	out	PORTB,relays
patch:
	rjmp	irclear
chk2:
	cpi	irfunc,0x01	;Check "2" key pressed
	brne	chk3
	in	relays,PORTB
	ldi	wreg,2
	eor	relays,wreg
	out	PORTB,relays
	rjmp	irclear
chk3:
	cpi	irfunc,0x02	;Check "3" key pressed
	brne	chk4
	in	relays,PORTB
	ldi	wreg,4
	eor	relays,wreg
	out	PORTB,relays
	rjmp	irclear
chk4:
	cpi	irfunc,0x03	;Check "4" key pressed
	brne	chk9
	in	relays,PORTB
	ldi	wreg,8
	eor	relays,wreg
	out	PORTB,relays
	rjmp	irclear
chk9:
	cpi	irfunc,0x08	;Check "9" key pressed
	brne	irclear
	ldi	wreg,0xf0
	out	PORTB,wreg
irclear:
	clr	last
	clr	count
	rcall	ldelay
	rjmp	main		;Loop forever

;	Delay for a long time
ldelay:
	ldi	longtime,128
lwait:
	ldi	timeout,0
	rcall	delay
	dec	longtime
	brne	lwait
	ret

;	Interrupt service routine for IR input
;	Entered on falling edge of IR receiver
readir:
	cbi	PORTD,1		;Indicator for debugging
	in	R0,SREG		;Save status register
	sbrc	flags,startb
	rjmp	readnext	;If startb is set, start flag has been found
	ldi	timeout,141	;Delay to 3.5 T to qualify start bit
	rcall	delay
	sbic	PIND,2		;Pin should still be low
	rjmp	readexit	;Otherwise exit ISR
	ldi	timeout,36	;Delay 1 T to qualify space after start bit
	rcall	delay
	sbis	PIND,2		;Pin should now be high
	rjmp	readexit	;Otherwise exit ISR
	sbr	flags,1<<startb	;Set 'start bit found' flag
	ldi	bitcnt,12	;Set counter to get 12 bits
	clr	devcode		;Clear received bytes and flags
	clr	irfunc
	cbr	flags,1<<gotir
	rjmp	readexit	;Exit ISR
readnext:
	ldi	timeout,16	;Delay to center of this bit
	rcall	delay
	sbic	PIND,2		;Should still be low here
	rjmp	readbad		;Otherwise bail out
	ldi	timeout,38	;Delay 1T to check for a 1 or 0
	rcall	delay
	clc			;Assume next bit is a zero
	sbis	PIND,2		;Read next bit from receiver
	sec			;Set carry if it was a 1
	ror	devcode		;Shift received bit into registers
	ror	irfunc
	dec	bitcnt		;Count down number of bits
	brne	readexit
	swap	devcode		;Rearrange nibbles in proper order
	mov	wreg,devcode
	andi	devcode,0x0f
	swap	irfunc
	andi	wreg,0xf0
	or	irfunc,wreg
	sbr	flags,1<<gotir	;Tell everyone we have a valid code
readbad:
	cbr	flags,1<<startb	;Clear 'start bit found' flag
readexit:
	out	SREG,R0		;Restore status register
	sbi	PORTD,1		;Indicator for debugging
	reti

;	Delay n*16 microseconds using timer 0, delay time passed in timeout
;	Overhead, due to call and return, not taken into account
delay:
	cbi	PORTD,0		;Indicator for debugging
	clr	wreg
	sub	wreg,timeout	;Convert count down into count up
	out	TCNT0,wreg	;Put count up time into counter
	ldi	wreg,TCK64	;Timer 0 prescaler, CK / 64
	out	TCCR0,wreg	;Run timer
dwait:
	in	wreg,TIFR	;Check timer interrupt flags
	sbrs	wreg,TOV0	;Wait for timer to overflow
	rjmp	dwait
	sbr	wreg,1<<TOV0	;Set bit to clear it (huh?)
	out	TIFR,wreg
	ldi	wreg,TSTOP	;Timer 0 off
	out	TCCR0,wreg	;Stop timer
	sbi	PORTD,0		;Indicator for debugging
	ret