;	Receive Sony IR Remote Control Codes with Atmel AT90S1200
;
;	Charles R. Ott
;	June 22, 1998

.nolist				;Suppress listing of include file
.include "2313def.inc"		;Define chip particulars
.list

;	Global register variables
.def	wreg	=R16		;General use working register
.def	devcode	=R17		;IR device code
.def	irfunc	=R18		;IR function code
.def	gotir	=R19		;Flag to indicate IR has been decoded
.def	timeout	=R20		;Delay time passed to subroutine
.def	bitcnt	=R21		;Received character bit counter
.def	startb	=R22
.def	last4	=R23
.def	count	=R24
.def	last	=R25
.def	longtime=R26
.def	temp	=R27

;	Timer/Counter prescaler values
.equ	TSTOP	=0		;Stop Timer/Counter
.equ	TCK64	=3		;Timer/Counter runs from CK / 64

.cseg

;	Interrupt vectors
.org	0
	rjmp	reset		;Reset Vector
.org	INT0addr		;External Interrupt0 Vector
	rjmp	readir
.org	OVF0addr		;Overflow0 Interrupt Vector
	reti
.org	ACIaddr			;Analog Comparator Interrupt Vector
	reti

;	Main program entry point on reset
reset:
	ldi	wreg,RAMEND	;Init Stack Pointer
	out	SPL,wreg
	ldi	wreg,0xFF	;Turn off all LEDs
	out	PORTB,wreg
	ldi	wreg,0xFF	;Make port B pins all outputs
	out	DDRB,wreg
	out	PORTD,wreg	;Put power on all port D pins
	ldi	wreg,0b11111011	;Make PD2 an input, all others outputs
	out	DDRD,wreg
	ldi	wreg,1<<INT0	;Enable external interrupt 0
	out	GIMSK,wreg
	ldi	wreg,1<<ISC01	;Use falling edge for interrupt
	out	MCUCR,wreg
	clr	startb
	clr	count
	clr	last
	clr	gotir

main:     
	sei			;Enable interrupts
	tst	gotir		;See if anything received yet
	breq	main		;Wait until something available
	cli			;Disable interrupts
	clr	gotir		;Clear status flag
	cp	last,irfunc	;See if same as last
	breq	irsame
	clr	count
	mov	last,irfunc
	rjmp	main
irsame:
	inc	count
	cpi	count,1
	brne	main
	com	devcode
	out	PORTB,devcode
	rcall	ldelay
	com	irfunc
	out	PORTB,irfunc
irclear:
	clr	last
	clr	count
	rjmp	main		;Loop forever

ldelay:
	ldi	longtime,255
lwait:
	ldi	timeout,255
	rcall	delay
	dec	longtime
	brne	lwait
	ret

;	Interrupt service routine for IR input
readir:
	in	R0,SREG		;Save status register
	tst	startb
	brne	readnext	;If T flag is set start flag has been found
	ldi	timeout,141	;Delay to 3.5 T to qualify start bit
	rcall	delay
	sbic	PIND,2		;Pin should still be low
	rjmp	readexit	;Otherwise exit ISR
	ldi	timeout,36	;Delay 1 T to qualify space after start bit
	rcall	delay
	sbis	PIND,2		;Pin should now be high
	rjmp	readexit	;Otherwise exit ISR
	ser	startb
	ldi	bitcnt,12	;Set counter to get 12 bits
	clr	devcode		;Clear received bytes and flags
	clr	irfunc
	clr	gotir
	clr	last4
	rjmp	readexit	;Exit ISR
readnext:
	ldi	timeout,16	;Delay to center of this bit
	rcall	delay
	sbic	PIND,2		;Should still be low here
	rjmp	readbad		;Otherwise bail out
	ldi	timeout,38	;Delay 1T to check for a 1 or 0
	rcall	delay
	clc			;Assume next bit is a zero
	sbis	PIND,2		;Read next bit from receiver
	sec			;Set carry if it was a 1
	ror	devcode		;Shift received bit into registers
	ror	irfunc
	dec	bitcnt		;Count down number of bits
	brne	readexit
	swap	devcode
	mov	temp,devcode
	andi	devcode,0x0f
	swap	irfunc
	andi	temp,0xf0
	or	irfunc,temp
	ldi	gotir,255	;Tell everyone we are done
readbad:
	clr	startb
readexit:
	out	SREG,R0		;Restore status register
	reti

;	Delay n*16 microseconds using timer 0, delay time passed in timeout
delay:
	clr	wreg
	sub	wreg,timeout
	out	TCNT0,wreg
	ldi	wreg,TCK64	;Timer 0 prescaler, CK / 64
	out	TCCR0,wreg	;Run timer
dwait:
	in	wreg,TIFR	;Check timer interrupt flags
	sbrs	wreg,TOV0	;Wait for timer to overflow
	rjmp	dwait
	sbr	wreg,1<<TOV0	;Set bit to clear it
	out	TIFR,wreg
	ldi	wreg,TSTOP	;Timer 0 off
	out	TCCR0,wreg	;Stop timer
	ret