;	Receive Sony IR Remote Control Codes with Atmel AT90S2313
;	Read key presses and output port b pins 0 - 7
;	This one's for you Randall
;
;	Charles R. Ott
;	July 11, 1998

.nolist				;Suppress listing of include file
.include "2313def.inc"		;Define chip particulars
.list

;	Function code definitions
;	f0 - f7 indicate IR code for port b 0 - 7 outputs
;	Change the values for desired key presses
;	For example chan+ = 0x10 and chan- = 0x11
;	  or vol+ = 0x12 and vol- = 0x13
;	See Sony IR code chart for others
.equ	f0	=0x00		;Function key 0 = "1"
.equ	f1	=0x01		;Function key 1 = "2"
.equ	f2	=0x02		;Function key 2	= "3"
.equ	f3	=0x03		;Function key 3 = "4"
.equ	f4	=0x12		;Function key 4	= "vol+"
.equ	f5	=0x13		;Function key 5	= "vol-"
.equ	f6	=0x10		;Function key 6 = "chan+"
.equ	f7	=0x11		;Function key 7 = "chan-"

;	Constant 'downt' specifies length of time each port pin
;	is held high for each key press
.equ	downt	=150		;Function output debounce time in mS

;	Constant 'which' specifies device code (i.e. 0x05 is VCR)
.equ	which	=0x05		;Sony VCR device code

;	Global register variables
.def	irsaver	=R12		;Save SREG in IR ISR
.def	saver	=R13		;Save SREG in T1 ISR
.def	last	=R14		;Last code received
.def	relays	=R15		;Input port pins for toggling
.def	wreg	=R16		;General use working register
.def	devcode	=R17		;IR device code
.def	irfunc	=R18		;IR function code
.def	flags	=R19		;Bit variables
.def	timeout	=R20		;Delay time passed to subroutine
.def	bitcnt	=R21		;Received character bit counter
.def	count	=R22		;Count of IR functions received
.def	temp	=R23		;Temp storage in timer 1 ISR
.def	ftime0	=R24		;Function output timers
.def	ftime1	=R25
.def	ftime2	=R26
.def	ftime3	=R27
.def	ftime4	=R28
.def	ftime5	=R29
.def	ftime6	=R30
.def	ftime7	=R31

;	Flag definitions
.equ	gotir	=0
.equ	startb	=1

;	Timer/Counter prescaler values
.equ	TSTOP	=0		;Stop Timer/Counter
.equ	TCK64	=3		;Timer/Counter runs from CK / 64
.equ	TCK256	=4		;Timer/Counter runs from CK / 256
.equ	TCK1024 =5		;Timer/Counter runs from CK / 1024
.equ	T1VAL	=-4		;Timer 1 reload value

.cseg

;	Interrupt vectors
.org	0		;Reset Vector Address
	rjmp	reset
.org	INT0addr	;External Interrupt0 Vector Address
	rjmp	readir
.org	INT1addr	;External Interrupt1 Vector Address
	reti
.org	ICP1addr	;Input Capture1 Interrupt Vector Address
	reti
.org	OC1addr 	;Output Compare1 Interrupt Vector Address
	reti
.org	OVF1addr	;Overflow1 Interrupt Vector Address
	rjmp	timer1
.org	OVF0addr	;Overflow0 Interrupt Vector Address
	reti
.org	URXCaddr	;UART Receive Complete Interrupt Vector Address
	reti
.org	UDREaddr	;UART Data Register Empty Interrupt Vector Address
	reti
.org	UTXCaddr	;UART Transmit Complete Interrupt Vector Address
	reti
.org	ACIaddr 	;Analog Comparator Interrupt Vector Address
	reti

;	Main program entry point on reset
reset:
	ldi	wreg,RAMEND	;Init Stack Pointer
	out	SPL,wreg
	ldi	wreg,0x00	;Turn off all function outputs
	out	PORTB,wreg
	ldi	wreg,0xFF	;Make port B pins all outputs
	out	DDRB,wreg
	out	PORTD,wreg	;Put power on all port D pins
	ldi	wreg,0b11111011	;Make PD2 an input, all others outputs
	out	DDRD,wreg
	ldi	wreg,1<<ISC01	;Use falling edge for interrupt
	out	MCUCR,wreg
	ldi	wreg,TSTOP	;Timer 1 off (just in case)
	out	TCCR1B,wreg	;Stop timer
	ldi	wreg,0b10000000	;Enable Timer 1 interrupt
	out	TIMSK,wreg
	ldi	wreg,TCK1024	;Load timer 1 prescaler
	out	TCCR1B,wreg
	ldi	wreg,HIGH(T1VAL);Load timer 1
	out	TCNT1H,wreg
	ldi	wreg,LOW(T1VAL)
	out	TCNT1L,wreg
	clr	flags
	clr	count
	clr	last
	clr	ftime0
	clr	ftime1
	clr	ftime2
	clr	ftime3
	clr	ftime4
	clr	ftime5
	clr	ftime6
	clr	ftime7
	ldi	wreg,1<<INT0	;Enable external interrupt 0
	out	GIMSK,wreg
	sei			;Enable interrupts

main:    
	tst	ftime0		;Check counter
	breq	m0off		;If zero, turn off port pin
	sbi	PORTB,0		;Otherwise, turn on port pin
	rjmp	m1		;Check next counter
m0off:
	cbi	PORTB,0		;Turn off port pin
m1:
	tst	ftime1		;Check counter
	breq	m1off		;If zero, turn off port pin
	sbi	PORTB,1		;Otherwise, turn on port pin
	rjmp	m2		;Check next counter
m1off:
	cbi	PORTB,1		;Turn off port pin
m2:
	tst	ftime2		;Check counter
	breq	m2off		;If zero, turn off port pin
	sbi	PORTB,2		;Otherwise, turn on port pin
	rjmp	m3		;Check next counter
m2off:
	cbi	PORTB,2		;Turn off port pin
m3:
	tst	ftime3		;Check counter
	breq	m3off		;If zero, turn off port pin
	sbi	PORTB,3		;Otherwise, turn on port pin
	rjmp	m4		;Check next counter
m3off:
	cbi	PORTB,3		;Turn off port pin
m4:
	tst	ftime4		;Check counter
	breq	m4off		;If zero, turn off port pin
	sbi	PORTB,4		;Otherwise, turn on port pin
	rjmp	m5		;Check next counter
m4off:
	cbi	PORTB,4		;Turn off port pin
m5:
	tst	ftime5		;Check counter
	breq	m5off		;If zero, turn off port pin
	sbi	PORTB,5		;Otherwise, turn on port pin
	rjmp	m6		;Check next counter
m5off:
	cbi	PORTB,5		;Turn off port pin
m6:
	tst	ftime6		;Check counter
	breq	m6off		;If zero, turn off port pin
	sbi	PORTB,6		;Otherwise, turn on port pin
	rjmp	m7		;Check next counter
m6off:
	cbi	PORTB,6		;Turn off port pin
m7:
	tst	ftime7		;Check counter
	breq	m7off		;If zero, turn off port pin
	sbi	PORTB,7		;Otherwise, turn on port pin
	rjmp	m8		;Check next counter
m7off:
	cbi	PORTB,7		;Turn off port pin
m8:
	sbrs	flags,gotir	;See if anything received yet
	rjmp	main		;Wait until something available
	cbr	flags,1<<gotir	;Clear status flag
	andi	irfunc,0x7f	;Eighth bit set on some?
	cpi	devcode,which	;Verify device code
	brne	main
	cp	last,irfunc	;See if same as last
	breq	irsame
	clr	count
	mov	last,irfunc
	rjmp	main
irsame:
	inc	count
	cpi	count,2
	breq	countok
	rjmp	main
countok:
	clr	wreg
	out	GIMSK,wreg	;Disable IR interrupts
	cpi	irfunc,f0	;Check function 0 key pressed
	brne	chk1
	ldi	ftime0,downt
	rjmp	irclear
chk1:
	cpi	irfunc,f1	;Check function 1 key pressed
	brne	chk2
	ldi	ftime1,downt
	rjmp	irclear
chk2:
	cpi	irfunc,f2	;Check function 2 key pressed
	brne	chk3
	ldi	ftime2,downt
	rjmp	irclear
chk3:
	cpi	irfunc,f3	;Check function 3 key pressed
	brne	chk4
	ldi	ftime3,downt
	rjmp	irclear
chk4:
	cpi	irfunc,f4	;Check function 4 key pressed
	brne	chk5
	ldi	ftime4,downt
	rjmp	irclear
chk5:
	cpi	irfunc,f5	;Check function 5 key pressed
	brne	chk6
	ldi	ftime5,downt
	rjmp	irclear
chk6:
	cpi	irfunc,f6	;Check function 6 key pressed
	brne	chk7
	ldi	ftime6,downt
	rjmp	irclear
chk7:
	cpi	irfunc,f7	;Check function 7 key pressed
	brne	irclear
	ldi	ftime7,downt
irclear:
	clr	last
	clr	count
	ldi	wreg,1<<INT0	;Enable external interrupt 0
	out	GIMSK,wreg
	rjmp	main		;Loop forever

;	Interrupt service routine for IR input
;	Entered on falling edge of IR receiver
readir:
	in	irsaver,SREG	;Save SREG
	sbrc	flags,startb
	rjmp	readnext	;If startb is set, start flag has been found
	ldi	timeout,141	;Delay to 3.5 T to qualify start bit
	rcall	delay
	sbic	PIND,2		;Pin should still be low
	rjmp	readexit	;Otherwise exit ISR
	ldi	timeout,36	;Delay 1 T to qualify space after start bit
	rcall	delay
	sbis	PIND,2		;Pin should now be high
	rjmp	readexit	;Otherwise exit ISR
	sbr	flags,1<<startb	;Set 'start bit found' flag
	ldi	bitcnt,12	;Set counter to get 12 bits
	clr	devcode		;Clear received bytes and flags
	clr	irfunc
	cbr	flags,1<<gotir
	rjmp	readexit	;Exit ISR
readnext:
	ldi	timeout,16	;Delay to center of this bit
	rcall	delay
	sbic	PIND,2		;Should still be low here
	rjmp	readbad		;Otherwise bail out
	ldi	timeout,38	;Delay 1T to check for a 1 or 0
	rcall	delay
	clc			;Assume next bit is a zero
	sbis	PIND,2		;Read next bit from receiver
	sec			;Set carry if it was a 1
	ror	devcode		;Shift received bit into registers
	ror	irfunc
	dec	bitcnt		;Count down number of bits
	brne	readexit
	swap	devcode		;Rearrange nibbles in proper order
	mov	wreg,devcode
	andi	devcode,0x0f
	swap	irfunc
	andi	wreg,0xf0
	or	irfunc,wreg
	sbr	flags,1<<gotir	;Tell everyone we have a valid code
readbad:
	cbr	flags,1<<startb	;Clear 'start bit found' flag
readexit:
	out	SREG,irsaver	;Restore SREG
	reti

;	Delay n*16 microseconds using timer 0, delay time passed in timeout
;	Overhead, due to call and return, not taken into account
delay:
	clr	wreg
	sub	wreg,timeout	;Convert count down into count up
	out	TCNT0,wreg	;Put count up time into counter
	ldi	wreg,TCK64	;Timer 0 prescaler, CK / 64
	out	TCCR0,wreg	;Run timer
dwait:
	in	wreg,TIFR	;Check timer interrupt flags
	sbrs	wreg,TOV0	;Wait for timer to overflow
	rjmp	dwait
	clr	wreg
	sbr	wreg,1<<TOV0	;Set bit to clear it (huh?)
	out	TIFR,wreg
	ldi	wreg,TSTOP	;Timer 0 off
	out	TCCR0,wreg	;Stop timer
	ret

;	Timer 1 interrupt service routine
timer1:
	sei			;Re-enable interrupts for IR reciever
	in	saver,sreg
	ldi	temp,HIGH(T1VAL);Reload timer 1
	out	TCNT1H,temp
	ldi	temp,LOW(T1VAL)
	out	TCNT1L,temp
	tst	ftime0		;See if count has elapsed
	breq	t11		;If not, check next
	dec	ftime0		;Decrement count
t11:
	tst	ftime1		;See if count has elapsed
	breq	t12		;If not, check next
	dec	ftime1		;Decrement count
t12:
	tst	ftime2		;See if count has elapsed
	breq	t13		;If not, check next
	dec	ftime2		;Decrement count
t13:
	tst	ftime3		;See if count has elapsed
	breq	t14		;If not, check next
	dec	ftime3		;Decrement count
t14:
	tst	ftime4		;See if count has elapsed
	breq	t15		;If not, check next
	dec	ftime4		;Decrement count
t15:
	tst	ftime5		;See if count has elapsed
	breq	t16		;If not, check next
	dec	ftime5		;Decrement count
t16:
	tst	ftime6		;See if count has elapsed
	breq	t17		;If not, check next
	dec	ftime6		;Decrement count
t17:
	tst	ftime7		;See if count has elapsed
	breq	t18		;If not, check next
	dec	ftime7		;Decrement count
t18:
	out	sreg,saver
	reti